Creating a diagonal matrix - loops

Question

This is the code I currently have:
forv i = 1/10 {
set obs 10
gen x`i' = (_n-1)*10+`i'
}
How can I make it into a diagonal matrix so that entries are 0 whenever row ad column indexes are not equal?
This is the code I tried but did not work:
forv i=1/10 {
set obs 10
gen x`i' = (_n-1)*10+`i'
foreach j of varlist x1-x10 {
if _n ~= "`i'"
replace `j' = 0
}
}

Answer 1

Your first code block is legal (assuming no more than 10 observations in memory) but doesn't produce any thing close to a diagonal matrix. The command set obs 10 should be executed once before the loop, not every time around the loop.
There are several errors in your inner loop in your second code block, but I won't spell them out. You're guessing wildly, not the way to write code!
You can get a diagonal matrix directly in Stata like this:
. matrix whatever = 7 * I(5)
. matrix list whatever
symmetric whatever[5,5]
c1 c2 c3 c4 c5
r1 7
r2 0 7
r3 0 0 7
r4 0 0 0 7
r5 0 0 0 0 7
If you have reason to hold that as variables, then use svmat. You could create such a matrix as values of several variables in a loop, but it would be somewhat perverse:
clear
set obs 5
forvalues j = 1/5 {
generate x`j' = 7 * (_n == `j')
}
list
+------------------------+
| x1 x2 x3 x4 x5 |
|------------------------|
1. | 7 0 0 0 0 |
2. | 0 7 0 0 0 |
3. | 0 0 7 0 0 |
4. | 0 0 0 7 0 |
5. | 0 0 0 0 7 |
+------------------------+

Answer 2

The solution by #NickCox is also applicable in mata - Stata's matrix programming language:
. mata: A = 7 * I(5)
. mata: A
[symmetric]
1 2 3 4 5
+---------------------+
1 | 7 |
2 | 0 7 |
3 | 0 0 7 |
4 | 0 0 0 7 |
5 | 0 0 0 0 7 |
+---------------------+
One can then get the matrix as variables with the getmata command:
. getmata (A*) = A
. list A*
+------------------------+
| A1 A2 A3 A4 A5 |
|------------------------|
1. | 7 0 0 0 0 |
2. | 0 7 0 0 0 |
3. | 0 0 7 0 0 |
4. | 0 0 0 7 0 |
5. | 0 0 0 0 7 |
+------------------------+