Excell VBA For Each Loop and Add Array cell adress - arrays

Question

Can u help me please.
I have a one problem.
My VBA Code
Sub ercan()
Dim ws As Worksheet
Set ws = Worksheets("Sayfa1")
For Each gunadi In ws.Range("D1:AH1")
If gunadi.Text = "CUMARTESİ" Then 'CUMARTESİ DAY NAME = Saturday
gunadi.Interior.Color = RGB(146, 208, 80)
gunadi.Offset(1, 0).Interior.Color = RGB(146, 208, 80)
ElseIf gunadi.Text = "PAZAR" Then 'PAZAR DAY NAME = Sunday
gunadi.Interior.Color = RGB(0, 176, 80)
gunadi.Offset(1, 0).Interior.Color = RGB(0, 176, 80)
Else
gunadi.Interior.ColorIndex = 0
gunadi.Offset(1, 0).Interior.ColorIndex = 0
End If
Next
For Each haftaici In ws.Range("D4:AH4")
If haftaici.Offset(-3, 0).Text = "PAZAR" Then
MsgBox haftaici.Address(False, False)
addr = haftaici.Address(False, False)
End If
'afterrrrr do
ws.Range("AK4").Value = "=" & addr
Next
End Sub
enter image description here
I want select range -3 == pazar (Sunday) add array cell address and after used this string.
H4 O4 V4 AC4 <= msgbox . I need add array foreach loop
I WANT =H4+O4+V4+AC4 THIS FORMAT DEBUG
I want to collect Sundays in "AK4" cell but value type =cell+cell+cell
how can i do i need your help?

Answer 1

Try this: you only need one loop.
Sub ercan()
Dim ws As Worksheet, c As Range, addr, sep
Set ws = Worksheets("Sayfa1")
For Each c In ws.Range("D1:AH1").Cells
Select Case c.Text
Case "CUMARTESI" 'Sat
c.Interior.Color = RGB(146, 208, 80)
c.Offset(1, 0).Interior.Color = RGB(146, 208, 80)
Case "PAZAR" 'Sun
c.Interior.Color = RGB(0, 176, 80)
c.Offset(1, 0).Interior.Color = RGB(0, 176, 80)
addr = addr & sep & c.Offset(3).Address(False, False) 'address from row 4
sep = "," 'add comma after first sunday
Case Else
c.Interior.ColorIndex = 0
c.Offset(1, 0).Interior.ColorIndex = 0
End Select
Next
If Len(addr) > 0 Then 'any Sundays?
ws.Range("AK4").Formula = "=SUM(" & addr & ")"
End If
End Sub