Batch program closes with Enter even if no option is selected - batch-file

Question

I'm new to stackoverflow!
Straight to it:
PC / Windows 10 x64
Script level: Novice
I've written a basic batch program with selectable menu, however, if Enter is made with nothing from the menu, the batch program closes.
I'm looking for a simple script that will make Enter (with no selection) essentially do nothing, or return to the beginning of the batch program.
Thanks in advance.
Jon
:mainmenu
#echo off
cls
color 1f
echo.
echo =========================================================
echo = R U N A S A D M I N I S T R A T O R =
echo =========================================================
echo.
echo.
echo WINDOWS COMMAND UTILITY (MAIN MENU):
echo ------------------------------------
echo.
echo [1] - BOOT COMMANDS
echo.
echo [2] - WINDOWS HEALTH COMMANDS
echo.
echo [0] - Exit Menu (Closes this window)
echo.
echo.
SET /P M=Enter option [Number] then press ENTER:
IF %M%==1 GOTO bootcommands
IF %M%==2 GOTO winhealth
IF %M%==0 GOTO exit
GOTO exit
:bootcommands
#echo off
cls
color 4e
echo.
echo =========================================================
echo = R U N A S A D M I N I S T R A T O R =
echo =========================================================
echo.
echo.
echo BOOT COMMANDS:
echo --------------
echo.
echo [1] - Windows (Normal Startup)
echo.
echo [2] - Windows Safe Mode (Offline)
echo.
echo [3] - Windows Safe Mode with Networking
echo.
powershell write-host -fore yellow -back red Tampering with the UEFI/Bios may render the PC unbootable!
echo [8] - Boot into UEFI/Bios
echo.
echo [0] - Return to MAIN MENU
echo.
echo.
SET /P M=Enter option [Number] then press ENTER:
IF %M%==1 GOTO normal
IF %M%==2 GOTO safe
IF %M%==3 GOTO safenetwork
If %M%==8 GOTO bootbios
IF %M%==0 GOTO mainmenu
GOTO exit
:normal
bcdedit /deletevalue {default} safeboot
goto reboot
exit
:safe
bcdedit /set {default} safeboot minimal
goto reboot
exit
:safenetwork
bcdedit /set {default} safeboot network
goto reboot
exit
:bootbios
shutdown /r /fw /f /t 2
exit
:reboot
shutdown /f /t 2
:winhealth
#echo off
cls
color 1f
echo.
echo =========================================================
echo = R U N A S A D M I N I S T R A T O R =
echo =========================================================
echo.
echo.
echo WINDOWS HEALTH COMMANDS:
echo ------------------------
echo.
echo [1] - *Create a System Restore Point
echo.
echo [2] - Elevated Command Prompt (Administrator Privileges)
echo.
echo [3] - SFC (Offline) File System Checker
echo.
echo [4] - DISM CheckHealth (Offline) Deployment Image Servicing and Management
echo.
echo [5] - DISM ScanHealth (Offline) Deployment Image Servicing and Management
echo.
powershell write-host -fore red -back yellow Option 6 requires Internet Connection!
echo [6] - DISM RestoreHealth (Online) Deployment Image Servicing and Management
echo.
echo [7] - CHKDSK (Offline) Check Disk checks the file system and file system
echo metadata of a volume for logical and physical errors.
echo.
echo [0] - Return to MAIN MENU
echo.
echo.
SET /P M=Enter option [Number] then press ENTER:
IF %M%==1 GOTO createrestore
IF %M%==2 GOTO cmdadmin
IF %M%==2 GOTO sfc
IF %M%==3 GOTO dismhealth
IF %M%==4 GOTO dismscan
IF %M%==5 GOTO dismrestore
IF %M%==6 GOTO chkdsk
IF %M%==0 GOTO mainmenu
GOTO exit
:createrestore
cls
echo.
echo Creating a System Resore point. Please be patient...
echo.
echo.
wmic.exe /Namespace:\\root\default Path SystemRestore Call CreateRestorePoint "Windows Command Utility", 100, 7
echo.
exit
:cmdadmin
start cmd /k
exit
:sfc
cls
echo.
echo Starting System File Checker. This is a utility in Microsoft Windows
echo that scans for and restores corrupted Windows system files.
cmd /k sfc /scannow
exit
:dismhealth
cls
echo.
echo This is a quick scan and will determine if the image is repairable.
cmd /k DISM /Online /Cleanup-Image /CheckHealth
exit
:dismscan
cls
echo.
echo This is a quick scan and will determine if there are any corruptions detected.
cmd /k DISM /Online /Cleanup-Image /ScanHealth
exit
:dismrestore
cls
echo.
echo Your system will automatically connect to the Windows Update
echo service to download and replace the corrupt files.
cmd /k DISM /Online /Cleanup-Image /RestoreHealth
exit
:chkdsk
cmd /k chkdsk.exe /f /r /x
exit
:exit
exit

Answer 1

As per my comment, the fix is to use the correct command utility, choice.exe.
#Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
:mainmenu
ClS
Color 1F
Echo=
Echo =========================================================
Echo = R U N A S A D M I N I S T R A T O R =
Echo =========================================================
Echo=
Echo=
Echo WINDOWS COMMAND UTILITY (MAIN MENU):
Echo ------------------------------------
Echo=
Echo [1] - BOOT COMMANDS
Echo=
Echo [2] - WINDOWS HEALTH COMMANDS
Echo=
Echo [0] - Exit Menu (Closes this program)
Echo=
Echo=
%SystemRoot%\System32\choice.exe /C 120 /N /M "Input option [Number]"
If ErrorLevel 3 Exit /B
If ErrorLevel 2 GoTo winhealth
:bootcommands
ClS
Color 4E
Echo=
Echo =========================================================
Echo = R U N A S A D M I N I S T R A T O R =
Echo =========================================================
Echo=
Echo=
Echo BOOT COMMANDS:
Echo --------------
Echo=
Echo [1] - Windows (Normal Startup)
Echo=
Echo [2] - Windows Safe Mode (Offline)
Echo=
Echo [3] - Windows Safe Mode with Networking
Echo=
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoP "Write-Host -Fore Yellow -Back Red 'Modifying the UEFI/BIOS may render the PC unbootable!'"
Echo [8] - Boot into UEFI/BIOS
Echo=
Echo [0] - Return to MAIN MENU
Echo=
Echo=
%SystemRoot%\System32\choice.exe /C 12380 /N /M "Input option [Number]"
If ErrorLevel 5 GoTo mainmemu
If ErrorLevel 4 GoTo bootbios
If ErrorLevel 3 GoTo safenetwork
If ErrorLevel 2 GoTo safe
:normal
%SystemRoot%\System32\bcdedit.exe /deletevalue {default} safeboot
goto reboot
:safe
%SystemRoot%\System32\bcdedit.exe /set {default} safeboot minimal
goto reboot
:safenetwork
%SystemRoot%\System32\bcdedit.exe /set {default} safeboot network
goto reboot
:bootbios
%SystemRoot%\System32\shutdown.exe /r /fw
Exit /B
:reboot
%SystemRoot%\System32\shutdown.exe /r
Exit /B
:winhealth
ClS
Color 1F
Echo=
Echo =========================================================
Echo = R U N A S A D M I N I S T R A T O R =
Echo =========================================================
Echo=
Echo=
Echo WINDOWS HEALTH COMMANDS:
Echo ------------------------
Echo=
Echo [1] - Create a System Restore Point
Echo=
Echo [2] - Elevated Command Prompt (Administrator Privileges)
Echo=
Echo [3] - SFC (Offline) File System Checker
Echo=
Echo [4] - DISM CheckHealth (Offline) Deployment Image Servicing and Management
Echo=
Echo [5] - DISM ScanHealth (Offline) Deployment Image Servicing and Management
Echo=
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoP "Write-Host -Fore Red -Back Yellow 'Option 6 requires an internet connection!'"
Echo [6] - DISM RestoreHealth (Online) Deployment Image Servicing and Management
Echo=
Echo [7] - CHKDSK (Offline) Check Disk checks the file system and file system
Echo metadata of a volume for logical and physical errors.
Echo=
Echo [0] - Return to MAIN MENU
Echo=
Echo=
%SystemRoot%\System32\choice.exe /C 12345670 /N /M "Input option [Number]"
If ErrorLevel 8 GoTo mainmenu
If ErrorLevel 7 GoTo chkdsk
If ErrorLevel 6 GoTo dismrestore
If ErrorLevel 5 GoTo dismscan
If ErrorLevel 4 GoTo dismhealth
If ErrorLevel 3 GoTo sfc
If ErrorLevel 2 GoTo cmdadmin
:createrestore
Rem Rest of your code, irrelevant to your question, goes here.