How to loop over list items in a macro in sas? - loops

Question

I wanted to perform data calculations with items from a list:
%let list = ("Apple" "Pear" "Grapes")
%macro px(list);
%do k=1 %to dim(&list.);
data data_1;
set output_&item_one.;
(...)
run;
proc sort data = data1;
by &variables.;
run;
data data_2;
set data1;
(...)
run;
proc export data = data_n
outfile= "&input_path.\file_name.xlsx"
dbms=xlsx replace;
sheet = "SUMMARY";
run;
%mend;
%px(list);
So I first take Apple without " do all data calculations and then take Pear etc.
Many thanks!

Answer 1

One way is to use COUNTW and SCAN
A macro list is typically just the items, no parentheses or quoting. However, how the items are utilized when resolved can change you design on what you start with.
However, if the list comes with parentheses and quoted values, you can compress those out.
Example:
%let items = Apple Pear Grapes;
%macro list_each(items=);
%* Many percents = The joy of escapism;
%let items = %sysfunc(compress(&items,%str(%(%"%))));
%local index item;
%do index = 1 %to %sysfunc(countw(&items, %str( )));
%let item = %scan(&items,&index,%str( ));
%put NOTE: &=index &=item;
%end;
%mend;
%list_each (items=&items)
%list_each (items=Alpha Beta Gamma)
%list_each (items=("A" "B" "C"))
Log
### %list_each (items=&items)
NOTE: INDEX=1 ITEM=Apple
NOTE: INDEX=2 ITEM=Pear
NOTE: INDEX=3 ITEM=Grapes
### %list_each (items=Alpha Beta Gamma)
NOTE: INDEX=1 ITEM=Alpha
NOTE: INDEX=2 ITEM=Beta
NOTE: INDEX=3 ITEM=Gamma
### %list_each (items=("A" "B" "C"))
NOTE: INDEX=1 ITEM=A
NOTE: INDEX=2 ITEM=B
NOTE: INDEX=3 ITEM=C

Answer 2

You cannot use a macro to loop over a list directly, but you can do it indirectly. If your list will not contain spaces (i.e. "Delicious Apple"), space-separating is a good way to go. If it will, pipe-separating, |, is the easiest route; however, you can use the Q modifier of %scan() to handle this if you'd like.
We'll do this by using %scan() to pull a single item from the list and loop until the end. We can use %sysfunc(countw()) to count the number of words in the list.
%let list = Apple Pear Grapes;
%macro px(list);
%do i = 1 %to %sysfunc(countw(&list.));
%let k = %scan(&list., &i.);
%put &i. &k.;
%end;
%mend;
%px(&list);
Output:
1 Apple
2 Pear
3 Grapes
If you pipe-separate it, simply add it as an argument to %sysfunc(countw()) and %scan():
%do i = 1 %to %sysfunc(countw(&list., |));
%let k = %scan(&list., &i., |);

Answer 3

To deal with that style of list you could just tell %SCAN() that space and parentheses are the delimiters. To remove the quotes use the DEQUOTE() function.
%macro test(list);
%local i next ;
%do i=1 %to %sysfunc(countw(&list,( ),q));
%let next=%sysfunc(dequote(%scan(&list,&i,( ))));
%put &=i &=next ;
%end;
%mend;
%let list = ("Apple" "Pear" "Grapes");
%test(&list);
Result:
I=1 NEXT=Apple
I=2 NEXT=Pear
I=3 NEXT=Grapes