How to make a variable that holds multiple lines by reading from a text file in batch or cmd [closed] - batch-file

Question

Closed. This question needs details or clarity. It is not currently accepting answers.
Want to improve this question? Add details and clarify the problem by editing this post.
Closed 7 days ago.
Improve this question
I have this text file containing multiple lines of text (message.txt) and I wanted my variable have the value of it.
set /p message=<message.txt
this will only take the first line
type message.txt
will read the full text but i wasn't able to set is as a variable

Answer 1

Simplest way
for /f "tokens=1delims==" %%b in ('set message') do set "%%b="
for /f "tokens=1*delims=:" %%b in ('findstr /n /R ".*" message.txt') do set "message%%b=%%c"
set message
for /f "tokens=1*delims==" %%b in ('set message') do echo %%c
The first for line clears all the message variables.
The second for line reads the data from the file; the set shows the values read
The third for line shows the values of the message variables.
Note that this simple method is limited to 9 lines (beyond that, you need to actually program the retrievel of the message variables) and will delete any leading : in any line of message.txt

Answer 2

Here is an example using an array in batch to store multiple lines of text read from a file.
#echo off
setlocal enabledelayedexpansion
set idx=0
for /f "usebackq delims=" %%i in ("message.txt") do (
set /a idx+=1
set "line[!idx!]=%%i"
)
echo Number of lines: %idx%
for /l %%j in (1,1,%idx%) do (
echo Line %%j: !line[%%j]!
)
pause
This code uses a for loop to read each line of the message.txt file and store each line in a separate element of the line array.
The variable idx is used to keep track of the number of lines read from the file.
After reading the file, the code outputs the number of lines and then uses another for loop to output each line stored in the line array.
Note the use of setlocal enabledelayedexpansion to enable delayed expansion, which allows the use of variables within a block of code even if their values are changed within the block.

Answer 3

The usual method to read a file is load each line in a different array element.. However, if you want to load all lines in the same variable, you can do it this way:
#echo off
setlocal EnableDelayedExpansion
call :readLines message=<message.txt
rem Standard expansion expands just the first line:
echo %message%
rem Delayed expansion expands all lines:
echo !message!
goto :EOF
:readLines variable < file
set /P "%1="
:nextLine
set "line="
set /P "line="
if not defined line exit /B
set ^"%1=!%1!^
%Don't remove this line%
%line%^"
goto nextLine