Leave Rows before Outputting Array Results - arrays

Question

I would like to create a summary sheet that draws from arrays in two work sheets. I would like the summary sheet (Result) contains two filtered arrays, one below the other (see the attached Desired Summary Page
This works well if the number of rows output by the array does not overlap with the formula for the second array. However, as the arrays are both dynamic the length changes depending on the filter criteria producing an Error (see attached)Overlapping Array Error
Is there any way to count the rows numbers produced by the first array and then get the second array to start after it is complete, so the two don't overlap - i.e. the output from the second array formula may need to be mapped to a remote cell (not containing the formula).
Here is an example spreadsheet
https://docs.google.com/spreadsheets/d/1Rt-Pp4gUYu8jGnXOQn0f2xpEKxoi_74Fqh5WSS-uF7A/edit?usp=sharing
I have tried adding blank rows to the second Array by using Flatten however this overwrites the results of the first Array. I have also tried a query function, but my knowledge of the syntax is not sufficient.
Any suggestions would be welcome.

Answer 1

Combine you two filtered result into one array. Try-
={filter('Sheet 1'!A3:D25,'Sheet 1'!D3:D25=TRUE);SPLIT(REPT(" |",4),"|");filter(Sheet2!A3:D25,Sheet2!D3:D25=TRUE)}
SPLIT(REPT(" |",4),"|") this part is for blank row between two filtered result.

Answer 2

You can stack the data with {} in googlesheet as long as they have the same array-length.
the filters are named as FILTER1 and FILTER2 with LAMBDA(),
added a title line to both filter with QUERY(),
get the 1st row of FILTER1 by INDEX(),
get the length of a row of data by COUNTA(),
set an array with specified rows and cols by MAKEARRAY and name it EMPTYROW,
stack the data created above with {} and ;.
=LAMBDA(FILTER1,FILTER2,
LAMBDA(ROWLEN,
LAMBDA(EMPTYROW,
{
FILTER1;
EMPTYROW;
FILTER2
}
)(MAKEARRAY(1,ROWLEN,LAMBDA(ROW,COL,"")))
)(COUNTA(INDEX(FILTER1,1,)))
)(
QUERY(filter('Sheet 1'!A3:D25,'Sheet 1'!D3:D25=TRUE),
"LABEL Col1'SHEET 1',Col2'',Col3'',Col4''"
),
QUERY(filter('Sheet 2'!A3:D25,'Sheet 2'!D3:D25=TRUE),
"LABEL Col1'SHEET 2',Col2'',Col3'',Col4''"
)
)