Array to a range where the range has missed columns - arrays

Question

I want to output an array to a range, however I want the range to be made up of several parts. My example code is below with the expected output.
Sub test()
a = Array(1, 2, 3, 4, 5)
Range("A2:B2,D2:F2") = a
End Sub
Output I Get:
A-B-C-D-E-F
1-2---1-2-3
Output I Want:
A-B-C-D-E-F
1-2---3-4-5
How do I achieve the output I need from the array? As you can see the output skips column C correctly but starts to output the array from the start again and not continue as I expected.

Answer 1

This isn't possible, sadly. You'll need to write code to write to a discontinuous Range the way you want. This has been discussed before on another site: https://www.mrexcel.com/board/threads/filling-a-non-contiguous-range-with-an-array-with-vba.763467/
This won't be valid for all situations of course, but if you know the sizes of the discontinuous ranges beforehand, you could store your info in multiple arrays that are appropriately sized, and then write to each range the data in the respective array. This way, you avoid the problem entirely.
If that's not possible, I would create a Sub that takes an array and all of the ranges as inputs, splits the array into as many appropriately-sized arrays as needed, and then write each of those arrays to the respective ranges.

Answer 2

Actually it does exactly what is expected.
If you want to fill non-continous ranges you need to do it with each area:
Sub test()
Dim Area1 As Variant
Area1 = Array(1, 2)
Range("A2:B2") = Area1
Dim Area2 As Variant
Area2 = Array(3, 4, 5)
Range("D2:F2") = Area2
End Sub

Answer 3

Late extension to the valid answers above allowing to automate the assignment of partial array values to a non-contiguous range; as said it is not possible to do this by a single assignment:
a) Automate assigning partial values
Sub testSlice()
'1. Define array values
Dim arr As Variant
arr = Array(1, 2, 3, 4, 5)
'2. Assign sliced array values to each range area
With Sheet1.Range("A2:B2,D2:F2") ' non contiguous range
Dim i As Long, col As Long
For i = 1 To .Areas.Count ' loop through each area
Dim cols As Long: cols = .Areas(i).Columns.Count
'Assign partial array
.Areas(i) = Slice(arr, col + 1, cols) ' << aux. function
col = col + cols ' provide for next col
Next i
End With
End Sub
Function Slice()
Slices the given array values into partial arrays according to the individual areas via Application.Index():
Function Slice(arr, ByVal startCol As Long, ByVal columnCount As Long)
'Purp: slice "flat" 1-dim array
'Note: Sequence function assumes vers. MS 365 !!
' (Index function returns 1-based values)
Slice = Application.Index(arr, Application.Sequence(1, columnCount, startCol))
End Function
Instead of Sequence() you can use a column evaluation for prior versions:
Function Slice(arr, ByVal startCol As Long, ByVal columnCount As Long)
'Purp: slice "flat" 1-dim array for non-365 versions
Slice = Application.Index(arr, Evaluate("Row(" & startCol & ":" & (startCol + columnCount - 1) & ")"))
Slice = Application.Transpose(Slice)
End Function
b) Alternative with single cell assignments
Sub test2()
Dim arr As Variant
arr = Array(10, 20, 30, 40, 50)
'non contiguous range (assumes a one-row range as in OP!)
Dim rng As Range
Set rng = Sheet1.Range("A2:B2,D2:F2")
Dim cell As Range, i As Long
For Each cell In rng
cell = arr(i) ' assign array vals to cell
i = i + 1 ' increment 0-based arr index
Next cell
End Sub