Google Sheets: Chart counting combinations - arrays

Question

In the following Google spreadsheet
Description
No. of participants
Severity
Problem 1
2
Minor
Problem 2
2
Major
Problem 3
1
Minor
Problem 4
1
Minor
Problem 5
2
Major
I would like to create a chart that has the No. of participants as x-axis, the Severity as y-axis and counts the number of combinations.
The example above would look like this:
1
2
Minor
2
1
Major
0
2
Also, I would like to list all items in the column description according to their combination of No. of participants and severity like this:
1
2
Minor
Problem 3
Problem 1
Minor
Problem 4
Major
Problem 2
Major
Problem 5
How can I get this chart extracted from the table in Google Sheets?
Thanks to #player0 the first part is answered. He also suggested something for the second part that does not quite work out yet:
To get the basic table:
=QUERY(A2:C6; "select C, max(A) where A is not null group by C pivot B order by C desc")
To display several items in one cell:
=MAP(B2:B6; C2:C6; LAMBDA(x; y; TEXTJOIN(CONCATENATE(CHAR(10);CHAR(10)); 1; FILTER(A2:A6; B2:B6=x; C2:C6=y))))
Unfortunately, combining both does not work out:
=QUERY((MAP(B2:B6; C2:C6; LAMBDA(x; y; TEXTJOIN(CONCATENATE(CHAR(10);CHAR(10)); 1; FILTER(A2:A6; B2:B6=x; C2:C6=y)))); B2:C6); "select C,max(A) where A is not null group by C pivot B order by C desc")
Nor does this one work:
=QUERY((MAP(B2:B6; C2:C6; LAMBDA(x; y; TEXTJOIN(CONCATENATE(CHAR(10);CHAR(10)); 1; FILTER(A2:A6; B2:B6=x; C2:C6=y)))); B2:C6); "select Col1,max(Col1) where Col1 is not null group by Col3 pivot Col2 order by Col3 desc")

Answer 1

use:
=QUERY(A2:C; "select C,count(A) where A is not null group by C pivot B order by C desc")
update:
=QUERY({MAP(B2:B, C2:C, LAMBDA(x, y, TEXTJOIN(", ", 1, FILTER(A2:A, B2:B=x, C2:C=y)))), B2:C},
"select Col3,max(Col1) where Col1 is not null group by Col3 pivot Col2 order by Col3 desc")