Batch command to select multiple file and output it as single line - batch-file

Question

I tried to find a many way to finish this but still no hope ( tried with array etc ...)
Is there a way that I can select part of the file listed in the dir and output it as below
for example if I input 0-2, it output as
00000\.MTS+00001.MTS+00002.MTS
same , if I input 3-5,
00003\.MTS+00004.MTS+00005.MTS
EXAMPLE FOLDER LIST
2022-03-24 00:14 \<DIR\> .
2022-03-24 00:14 \<DIR\> ..
2022-03-23 15:47 5,025,792 00000.MTS
2022-03-23 15:47 4,958,208 00001.MTS
2022-03-23 15:47 3,938,304 00002.MTS
2022-03-23 15:47 9,185,280 00003.MTS
2022-03-23 15:48 9,179,136 00004.MTS
2022-03-23 15:48 3,028,992 00005.MTS
The reason I try to do this it is because I would like to join the MTS files without typing in one by one in the command. The original command is like
copy /b 00000.MTS+00001.MTS+00002.MTS+00003.MTS+00004.MTS+00005.MTS "C:\\Users\\Desktop\\1.MTS"
Hope I can use the batch command
1st : 0-2
copy /b 00000.MTS+00001.MTS+00002.MTS "C:\\Users\\Desktop\\1.MTS"
2nd : 3-5
copy /b 00003.MTS+00004.MTS+00005.MTS "C:\\Users\\Desktop\\2.MTS"
Is it possible to complete this in bat ?
I did try with the for loop to gen the file list,
setlocal enabledelayedexpansion
set /P "mts1=MTS SET 1 : "
for %%n in (%mts1%) do (
echo !FILE_LIST\[%%n\]!+
)
but seem it only show all and also every file uses a new line, cannot be use in copy /b

Answer 1

#ECHO Off
SETLOCAL ENABLEDELAYEDEXPANSION
rem The following settings for the source directory and destination directory are names
rem that I use for testing and deliberately include names which include spaces to make sure
rem that the process works using such names. These will need to be changed to suit your situation.
SET "sourcedir=u:\your files\t w o"
SET "destdir=%sourcedir%"
:: Do we have 2 arguments?
IF "%~2" equ "" ECHO need 2 arguments&GOTO :eof
:: calculate the destination filename
SET /a destfile=0
:destloop
SET /a destfile+=1
IF EXIST "%destdir%\%destfile%.MTS" GOTO destloop
:: change to source directory
PUSHD "%sourcedir%"
:: then build the list of files to concatenate
SET "sourcelist="
:again
FOR /f "tokens=1*delims=" %%b IN ('dir /b /a-d /on 0*.MTS ') DO (
SET "candidate="
SET /a candidate=1%%~nb 2>NUL
IF DEFINED candidate (
SET /a serial=candidate -100000
IF !serial! geq %1 IF !serial! leq %2 SET "sourcelist=!sourcelist!+%%~nxb"
IF !SERIAL! GEQ %2 IF "%3" NEQ "" SHIFT&SHIFT&GOTO AGAIN
)
)
IF DEFINED sourcelist COPY %sourcelist:~1% "%destdir%\%destfile%.MTS" >nul
:: back to original directory
POPD
GOTO :EOF
First step: get the destination filename by incrementing a counter and seeing whether that filename already exists.
Next: scan a basic directory list of the .MTS filenames that start 0. For each candidate found, set candidate to empty then attempt to user an arithmetic set (set /a) string 1 in front so that the number becomes, eg 100000. This is because numbers that start 0 are considered as octal by cmd. If the resultant string is not numeric, the set /a will fail, an error message will be produced (the 2>nul suppresses the error message) and candidate will remain set to empty, ie. undefined.
If candidate is defined, then subtract the 100000 that was added in, and check whether the result is greater than or equal to the first parameter AND less than or equal to the second parameter. If so, build sourcelist with the new name preceded by +.
Finally, do the copy using substringing to drop the leading + from sourcelist.
Run the batch with two parameters, the start and end numbers, eg. thisbatch 3 7
Amendment in response to comment:
Insert the label :again and add the extra line IF !serial! geq %2...
When the first range is ended, set serial to the current 3rd argument. If serial is now defined, shift out the first two arguments and start over, with sourcelist already part-built.
Note that this allows any pairs to be used, so thisbatch 12 15 3 6 is valid, as is thisbatch 12 14 3 7 6 11
--- Small revision
#ECHO Off
SETLOCAL ENABLEDELAYEDEXPANSION
rem The following settings for the source directory and destination directory are names
rem that I use for testing and deliberately include names which include spaces to make sure
rem that the process works using such names. These will need to be changed to suit your situation.
SET "sourcedir=u:\your files\t w o"
SET "destdir=%sourcedir%"
:: Do we have 2 arguments?
IF "%~2" equ "" ECHO need 2 arguments&GOTO :eof
:restart
:: calculate the destination filename
SET /a destfile=0
:destloop
SET /a destfile+=1
IF EXIST "%destdir%\%destfile%.MTS" GOTO destloop
:: change to source directory
PUSHD "%sourcedir%"
:: then build the list of files to concatenate
SET "sourcelist="
:again
IF /i "%1"=="E" GOTO docopy
FOR /f "tokens=1*delims=" %%b IN ('dir /b /a-d /on 0*.MTS ') DO (
SET "candidate="
SET /a candidate=1%%~nb 2>NUL
IF DEFINED candidate (
SET /a serial=candidate -100000
IF !serial! geq %1 IF !serial! leq %2 SET "sourcelist=!sourcelist!+%%~nxb"
IF !SERIAL! GEQ %2 IF "%3" NEQ "" SHIFT&SHIFT&GOTO AGAIN
)
)
:docopy
IF DEFINED sourcelist COPY %sourcelist:~1% "%destdir%\%destfile%.MTS" >nul
:: back to original directory
POPD
IF /i "%1"=="E" shift&GOTO restart
GOTO :EOF
This gives you the best of both worlds.
If you have a command line thisbatch 3 6 0 2 then it will generate 1 new file with 3+4+5+6+0+1+2.
If you have a command line thisbatch 3 6 0 2 E 12 15 0 2 E 1 4 then it will generate 3 new files with 3+4+5+6+0+1+2, 12+13+14+15+0+1+2 and 1+2+3+4.
The names for each number-pair are concatenated as before. If the next "start number" is E (either case) then the copy command is executed, the E is shifted out and the entire process restarted with arguments of whatever was beyond the E by returning to the label with the bizarre name :restart.

Answer 2

This can be used at a cmd prompt or in a batch-file script. The function builds an array of desired numbers. The desired numbers are expressed as a string similar to many applications specifying page numbers (ie: "1-3" or "3-5,7,10-12")
Place the Do-ConcatFiles.bat and Do-ConcatFiles.ps1 script in the same directory. If you are on a supported windows system, PowerShell is available.
=== Do-ConcatFiles.bat
#ECHO OFF
powershell -NoLogo -NoProfile -File "%~dpDo-ConcatFiles.ps1" -PagesList 1-3,12 -Path ".\pageslist.txt"
=== Do-ConcatFiles.ps1
[CmdletBinding()]
param (
[Parameter(Mandatory=$true)]
[string]$PagesList = '1-3,5,7-12'
,[Parameter(Mandatory=$true)]
[string]$Path = 'C:\src\t\pageslist\pageslist.txt'
)
function Get-PagesList([string]$PagesString) {
# Build an array of desired numbers.
$Pages = #()
$PagesString -replace '\s*' -split ',' |
ForEach-Object {
if ($_ -match '(\d*)\-(\d*)') {
for ([int]$i = [int]$Matches[1]; $i -le [int]$Matches[2]; $i++) { $Pages += $i }
} else { $Pages += $_ }
}
return $Pages
}
<# TEST FILE GENERATION
1..20 | ForEach-Object {
$FileName = ('{0:000000}' -f $_) + '.txt'
Set-Content -Path $FileName -Value $FileName -Encoding ascii
}
#>
Write-Verbose "Input PagesList = $PagesList"
Write-Verbose "Input result file is $Path"
$Pages = Get-PagesList($PagesList)
if ($Pages.Count -ne 0) {
if (Test-Path -Path $Path) { Remove-Item -Path $Path }
$Files = Get-ChildItem -Path '[0-9]*.txt'
$Pages |
ForEach-Object {
foreach ($File in $Files) {
if (($File -match '(\d*).txt') -and ([int]$Matches[1] -eq $_)) {
Write-Verbose "Appending file $File to $Path"
Get-Content -Path $File | Out-File -FilePath $Path -Append -Encoding ascii
}
}
}
}