Combining Ranges in Excel Functions with out helper cells - arrays

Question

I am having difficulty figuring out how to get the correct data type evaluated as a single array passed to the first argument of the Small() in this function. My overall goal is (completely without the use of helper cells) to combine two sets of ranges passed to Small() as arrays into a 2-dimensional array output. The formulas work correctly when placed separately in ranges, but when combined in a Let() I get type inconsistency caused #VALUE! errors as the output.
Here is the LET() function ...
=LET(
A1v, SEQUENCE(1,10,1,0),
A2v, SEQUENCE(1,10,2,0),
SMALL((A1v,A2v),SEQUENCE(2,COLUMNS(A1v)))
)
When the Let() formula is broken into pieces and placed into separate ranges as described below it produces the desired output in A3:J4 (A3#) as shown in this
Range A1 formula:
=SEQUENCE(1,10,1,0)
Range A2 formula:
=SEQUENCE(1,10,2,0)
Range A3 formula:
=SMALL((A1#,A2#),SEQUENCE(2,COLUMNS(A1#)))
I am aware that there are other function constructs that can be used to combine ranges. I am not looking for alternatives to using Small(). I am looking for answers that will help further my understanding of constructing arrays from and to be used as inputs to the new array functions in Excel. Thanks to everyone in advance!

Answer 1

The reason your Let function fails is the (A1v,A2v) parameter to Small. That construct is the Union Operator for Ranges. A1v and A2v are arrays, not ranges.
This can be seen in the Formula Evaluator dialog
In contrast (A1#,A2#) works because A1# and A2# are ranges.
FWIW, Small itself can accept either ranges or arrays
To solve this you'll need a general purpose solution to getting the Union of two data sets, whether they be Ranges or Arrays. This can be achieved using a Lambda function.
Add a Workbook scoped Name to the Name Manager, lets call it Union
In the Refers To section insert
=LAMBDA(tabl1, tabl2,
LET(rowindex, SEQUENCE(ROWS(tabl1)+ROWS(tabl2)),
colindex, SEQUENCE(1,COLUMNS(tabl1)),
IF(rowindex<=ROWS(tabl1),
INDEX(tabl1,rowindex,colindex),
INDEX(tabl2,rowindex-ROWS(tabl1),colindex)
)
)
)
Union is now available to use as a stand alone function, or imbedded in another function
Your Formula now becomes
=LET(
A1v, SEQUENCE(1,10,1,0),
A2v, SEQUENCE(1,10,2,0),
SMALL(Union(A1v,A2v),SEQUENCE(2,COLUMNS(A1v)))
)
Or without Lambda
=LET(
A1v, SEQUENCE(1,10,1,0),
A2v, SEQUENCE(1,10,2,0),
rowindex, SEQUENCE(ROWS(A1v)+ROWS(A2v)),
colindex, SEQUENCE(1,COLUMNS(A1v)),
Av, IF(rowindex<=ROWS(A1v),
INDEX(A1v,rowindex,colindex),
INDEX(A2v,rowindex-ROWS(A1v),colindex),
SMALL(Av,SEQUENCE(2,COLUMNS(A1v))) )
)
Untested, so you might have to tweak it a bit