How to custom order week year in power bi? - database

Question

I have issue in custom ordering data.
Here is example
I would like to be sorted first by year and than by week
I want 1 2022 to be at the and of the line.
I have tried adding few things.
Is there a way to sort this out by adding new table with weekYear column and some sortOrder column
which I have to populate with custom values as well?
I prefer solution to be dynamic..
If you have any solution please advice!

Answer 1

I suggest
Create a table from your column names
Split the column by space delimiter
Change column types to number
sort by Year and then by Week
Change column types to text
combine the columns with space delimiter
use this new, sorted list to re-order the original columns
I did this as a custom function:
(tbl as table, optional colsToSort as list) =>
let
colHdrs = if colsToSort=null then Table.ColumnNames(tbl) else colsToSort,
hdrCol = Table.FromList(colHdrs,Splitter.SplitTextByDelimiter(" ")),
//type as number for sorting
typeAsNumber = Table.TransformColumnTypes(hdrCol,{{"Column1", Int64.Type},{"Column2",Int64.Type}}),
sorted = Table.Sort(typeAsNumber,{{"Column2", Order.Ascending}, {"Column1", Order.Ascending}}),
//type as text to combine
typeAsText = Table.TransformColumnTypes(sorted,{{"Column1", Text.Type}, {"Column2", Text.Type}}),
combine = Table.CombineColumns(typeAsText,{"Column1","Column2"},Combiner.CombineTextByDelimiter(" "),"orderHeaders"),
//re-Order the column headers in the original table
newOrder = Table.ReorderColumns(tbl,combine[orderHeaders])
in
newOrder
And you could call it from your original query as:
let
Source = Excel.CurrentWorkbook(){[Name="Table13"]}[Content],
#"Changed Type" = Table.TransformColumnTypes(Source,{
{"41 2021", Int64.Type}, {"42 2021", Int64.Type}, {"43 2021", Int64.Type},
{"46 2021", Int64.Type}, {"1 2022", Int64.Type}, {"48 2021", Int64.Type},
{"50 2021", Int64.Type}, {"49 2021", Int64.Type}, {"51 2021", Int64.Type},
{"52 2021", Int64.Type}}),
//custom function here
sortHdrs = fnSortHeaders(#"Changed Type")
in
sortHdrs
If ALL of your columns are in the format of weeknumber year so that you want to sort ALL of them, it may be simpler to do this without a separate function. The advantage of the separate function is that you can more easily remove the column names you don't want to include in the sort
Here is code that will sort the column headers with no need of a separate function. It uses the same algorithm as above
let
Source = Excel.CurrentWorkbook(){[Name="Table13"]}[Content],
#"Changed Type2" = Table.TransformColumnTypes(Source,{
{"41 2021", Int64.Type}, {"42 2021", Int64.Type}, {"43 2021", Int64.Type},
{"46 2021", Int64.Type}, {"1 2022", Int64.Type}, {"48 2021", Int64.Type},
{"50 2021", Int64.Type}, {"49 2021", Int64.Type}, {"51 2021", Int64.Type},
{"52 2021", Int64.Type}}),
//create header list
//this assumes ALL column headers are to be sorted, but you can make partial lists for the column sorting
hdrs = List.Combine(List.Transform(Table.ColumnNames(#"Changed Type2"), each Text.Split(_," "))),
//split into month and year and put into a table
monthYear = Table.FromColumns({List.Alternate(hdrs,1,1,1),List.Alternate(hdrs,1,1,0)},{"Month","Year"}),
//change data type to number and sort by Year and then Month
#"Changed Type" = Table.TransformColumnTypes(monthYear,{{"Month", Int64.Type}, {"Year", Int64.Type}}),
#"Sorted Rows" = Table.Sort(#"Changed Type",{{"Year", Order.Ascending}, {"Month", Order.Ascending}}),
//change data type to text and join with space delimiter
#"Changed Type1" = Table.TransformColumnTypes(#"Sorted Rows",{{"Month", type text}, {"Year", type text}}),
sortedHeaders = Table.CombineColumns(#"Changed Type1",{"Month", "Year"},
Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"newOrder")[newOrder],
//reOrder the original table
sortedTableColumns= Table.ReorderColumns(#"Changed Type2",sortedHeaders)
in
sortedTableColumns