BATCH FILE - create folders with every WORKING DAY (no saturday and sunday) - batch-file

Question

I would like to edit the following batch code in order to create a folder with every working day of the year and skip saturday and sunday (i guess it should create 5 consecutive days and skip the next 2)
I would also like the batch file to
skip creating folders for each month(a january folder, a february folder etc) and have all days of the year in the same folder.
add two extra folders in each day folder with 'morning' and 'afternoon'
Ex:
C:\Users\alex\Desktop\2022\1 Jan\Morning
C:\Users\alex\Desktop\2022\1 Jan\Afternoon
all the way to
C:\Users\alex\Desktop\2022\31 Dec\Morning
C:\Users\alex\Desktop\2022\31 Dec\Afternoon
(it would not create 31 dec folder because thats a saturday)
#ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "sourcedir=U:\years"
SET /p year=### Enter Year [e.g. 2014]:
IF NOT DEFINED year GOTO :EOF
SET year=%year:,=%
IF %year% lss 100 SET /a year=2000+year
IF %year% gtr 1901 IF %year% lss 2099 GOTO generate
ECHO year entered out of range 1901..2099
GOTO :eof
:generate
MD "%sourcedir%"
SET /a feb=year %% 4
IF %feb%==0 (SET "feb=02,February,29") ELSE (SET "feb=02,February,28")
PUSHD "%sourcedir%"
MKDIR %year%
CD %year%
FOR %%a IN ("01,January,31" "%feb%" "03,March,31" "04,April,30" "05,May,31" "06,June,30" "07,July,31" "08,August,31" "09,September,30" "10,October,31" "11,November,30" "12,December,31") DO (
FOR /f "tokens=1-3delims=," %%b IN (%%a) DO (
SET "month=%%c"
SET "month=!month:~0,3!"
MKDIR %%b_%%c
pushd %%b_%%c
FOR /l %%q IN (1,1,%%d) DO MD %%q-!month!-%year%
popd
)
)
popd
GOTO :EOF

Answer 1

This is a very simple task when you use the right method and formulae:
#echo off
setlocal EnableDelayedExpansion
set "i=0"
for %%a in (Mon Tue Wed Thu Fri Sat Sun) do (
set "DayOfWeek[!i!]=%%a"
set /A i+=1
)
set /P "Year=Enter year: "
set /A "leap=28+^!(Year%%4)*^!^!(Year%%400)"
set "MonthNameDays=Jan:31 Feb:%leap% Mar:31 Apr:30 May:31 Jun:30 Jul:31 Aug:31 Sep:30 Oct:31 Nov:30 Dec:31"
rem Get Julian Day Number of Jan/01 of given year
rem adjusted as multiple of day of week: JDN % 7 = 0..6 for Mon..Sun
rem Reference: http://www.hermetic.ch/cal_stud/jdn.htm#comp
set /A "JDN=(1461*(Year+4799))/4+4037/12-(3*((Year+4899)/100))/4-1, MM=100"
for %%a in (%MonthNameDays%) do for /F "tokens=1,2 delims=:" %%x in ("%%a") do (
set /A MM+=1
ECHO md "!MM:~1! %%x"
ECHO pushd "!MM:~1! %%x"
for /L %%d in (1,1,%%y) do (
set /A "JDN+=1, DOW=JDN%%7, DD=100+%%d"
if !DOW! lss 5 (
for %%w in (!DOW!) do (
ECHO md "!DD:~-2! !DayOfWeek[%%w]!"
)
)
)
ECHO popd
)
I focused on the core point of generate folders for Mon..Fri days of week, so I not included some minor details, like generate Morning/Afternoon folders. Also, I just echoed the "MD" commands...

Answer 2

As per my earlier comment, the following batch file gets the assistance of PowerShell:
#Echo Off
SetLocal EnableExtensions
:AskYear
ClS
Set "YYYY="
Set /P "YYYY=Please enter a four digit year from 1900 to 2099 incl.>"
Set YYYY 2>NUL|%SystemRoot%\System32\findstr.exe /R^
"^YYYY=19[0123456789][0123456789]$ ^YYYY=20[0123456789][0123456789]$" 1>NUL || GoTo AskYear
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoProfile^
"$beginningOfYear = Get-Date -Year %YYYY% -Month 1 -Day 1 -Hour 0 -Minute 0 -Second 0;"^
"$endOfYear = ($beginningOfYear).AddYears(1).AddSeconds(-1);"^
"While ($beginningOfYear -LE $endOfYear) {"^
" $beginningOfYear = ($beginningOfYear).AddDays(1);"^
" If ($beginningOfYear.DayOfWeek -GT 0) {"^
" If ($beginningOfYear.DayOfWeek -LT 6) {"^
" $children=#('Morning','Afternoon');"^
" ForEach ($i In $children) {"^
" md \"$($beginningOfYear.ToString('yyyy\\d MMM'))\$i\"}}}}"
The above example assumes that your culture/locale settings use the first day of the week 0 as the last day of the weekend, and the 6 as the first day of the weekend. If your culture/locale settings use 6 and 5 for those two days respectively, then you'd simply change the code accordingly:
#Echo Off
SetLocal EnableExtensions
:AskYear
ClS
Set "YYYY="
Set /P "YYYY=Please enter a four digit year from 1900 to 2099 incl.>"
Set YYYY 2>NUL|%SystemRoot%\System32\findstr.exe /R^
"^YYYY=19[0123456789][0123456789]$ ^YYYY=20[0123456789][0123456789]$" 1>NUL || GoTo AskYear
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoProfile^
"$beginningOfYear = Get-Date -Year %YYYY% -Month 1 -Day 1 -Hour 0 -Minute 0 -Second 0;"^
"$endOfYear = ($beginningOfYear).AddYears(1).AddSeconds(-1);"^
"While ($beginningOfYear -LE $endOfYear) {"^
" $beginningOfYear = ($beginningOfYear).AddDays(1);"^
" If ($beginningOfYear.DayOfWeek -LT 5) {"^
" $children=#('Morning','Afternoon');"^
" ForEach ($i In $children) {"^
" md \"$($beginningOfYear.ToString('yyyy\\d MMM'))\$i\"}}}"

Answer 3

Not pure batch, but you can use powershell to help a bit.
#echo off
set "sourcedir=U:\years"
set /p year=### Enter Year [e.g. 2014]:
echo 0..365 ^| %% { $date = Get-Date "%year%-01-01";$date = $date.AddDays($_).ToString("dddd dd MMMM yyyy");Write-Host $date"" }>tmp.ps1
for /F "tokens=1-4*" %%a in ('powershell .\tmp.ps1') do (
if "%%~d" == "2022" if not "%%a" == "Saturday" if not "%%a" == "Sunday" (
echo mkdir "%sourcedir%\%%c %%d\%%a %%b\Morning"
echo mkdir "%sourcedir%\%%c %%d\%%a %%b\Afternoon"
)
)
del /Q tmp.ps1
PS!! you don't have to use the temp file at all, I just don't have the time now to do all the escaping of special characters, but it will help you in the right direction, if you can use hybrids.
You can move the year/month/days around as you please. If you want short Month and Day (Dec, Mon instead of December Monday) change the format in the powershell portion:
echo 0..365 ^| %% { $date = Get-Date "%year%-01-01";$date = $date.AddDays($_).ToString("ddd dd MMM yyyy");Write-Host $date"" }>tmp.ps1
Result: