For loop function for single line in batch? - batch-file

Question

I have a txt file which contains some animal and fruit names. * contain fruits and # contain animal. Just like below:-
* apple
# cat
* banana
# dog
* mango
# lion
* graps
I want to sort down list and write like a table which given below:-
* apple # cat
* banana # dog
* mango # lion
I'm using a for loop for this:
for /f "useback eol=* tokens=1-5 delims= " %%a in ("my text.txt") do (
for /f "useback eol=# tokens=1-5 delims= " %%c in ("my text.txt") do (
Echo %%a %%b
))
But it echoes duplicates.

Answer 1

Please note that tokens are parts of a single line. For the first line, Token1=*, token2=apple, token3 to 5 are not defined. Same for each other line. For your example, tokeins=1,2 would be fine, but I decided to use 1,* to take account of animals or fruits whose names are two (or more) words (like dragon fly)
for /f "usebackq tokens=1,*" %%a in ("my text.txt") do (
if "%%a" == "*" (
<nul set /p "=%%a %%b "
) else (
echo %%a %%b
)
)
echo\
This uses a special trick to write a string without a linefeed in case the line starts with *
(<nul set /p "=string")
Of course, this depends on alternating * and # lines in the source textfile.

Answer 2

This can be done in cmd or a batch-file using the following. If you are on a supported Windows system, PowerShell is available.
This code get the entire file contents into memory, the splits it into an array on the * character. The first, empty, array element is skipped. Then, the NewLine between the * and # lines is replaced with a few SPACE characters.
powershell.exe -NoLogo -NoProfile -Command ^
"(Get-Content -Path '.\fruit-animal.txt' -Raw) -split '\*' | Select-Object -Skip 1 | %{ '* ' + $_ -replace [Environment]::NewLine, ' '}"
Here is the data file and example execution.
C:>TYPE .\fruit-animal.txt
* apple
# cat
* banana
# dog
* mango
# lion
* graps
C:>powershell.exe -NoLogo -NoProfile -Command ^
More? "(Get-Content -Path '.\fruit-animal.txt' -Raw) -split '\*' | Select-Object -Skip 1 | %{ $_ -replace [Environment]::NewLine, ' '}"
apple # cat
banana # dog
mango # lion
graps
This will likely work well for you unless you have a -large- file.
If PowerShell Core http://github.com/PowerShell/Powershell is used (recommended), change it to:
pwsh.exe -NoLogo -NoProfile -Command ^
"(Get-Content -Path '.\fruit-animal.txt' -Raw) -split '\*' | Select-Object -Skip 1 | %{ '* ' + $_ -replace [Environment]::NewLine, ' '}"

Answer 3

The task description, the example input and output data and the posted code do not match at all. So it is really difficult to understand what the task really is.
The first batch file code below is for reading all non-empty lines from a data file and merge each non-empty odd line with each non-empty even line together and finally replace the source data file with the temporary file containing the merged lines.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "DataFile=Data.txt"
if not exist "%DataFile%" goto MissingFile
set "TempFile=%DataFile%.tmp"
set "LineOdd="
set "LineEven="
(
for /F usebackq^ delims^=^ eol^= %%I in ("%DataFile%") do (
if defined LineOdd (
set "LineEven=%%I"
setlocal EnableDelayedExpansion
echo(!LineOdd! !LineEven!
endlocal
set "LineOdd="
set "LineEven="
) else set "LineOdd=%%I"
)
if defined LineOdd (
setlocal EnableDelayedExpansion
echo(!LineOdd!
endlocal
set "LineOdd="
)
)>"%TempFile%"
if /I not "%~1" == "test" (move /Y "%TempFile%" "%DataFile%") else type %TempFile%"
del "%TempFile%"
exit /B
:MissingFile
echo ERROR: There is no file "%DataFile%" in "%CD%".
echo/
pause
endlocal
It is possible to run this batch file with the string test as parameter to just output the final result instead of overwriting the source data file.
The file Data.txt contains perhaps the following lines:
* apple
# cat
# dog
* banana
* mango
# lion
* grapes
* pear
* plum
# mouse
# canary
# hamster
* cherry
The result of the batch file above is:
* apple # cat
# dog * banana
* mango # lion
* grapes * pear
* plum # mouse
# canary # hamster
* cherry
The second batch file code below really looks on the identifiers * and # at beginning of the lines to determine if the rest of the line should be on left or on right side in the output file. All lines not starting with * and # are ignored by this code.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "DataFile=Data.txt"
if not exist "%DataFile%" goto MissingFile
set "TempFile=%DataFile%.tmp"
set "DataLeft="
set "DataRight="
(
for /F "usebackq tokens=1*" %%I in ("%DataFile%") do (
if "%%I" == "*" (
if not defined DataLeft (
set "DataLeft=%%J"
) else if defined DataRight (
setlocal EnableDelayedExpansion
echo(!DataLeft! !DataRight!
endlocal
set "DataLeft=%%J"
set "DataRight="
) else (
setlocal EnableDelayedExpansion
echo(!DataLeft!
endlocal
set "DataLeft=%%J"
)
) else if "%%I" == "#" (
if not defined DataRight (
set "DataRight=%%J"
) else if defined DataLeft (
setlocal EnableDelayedExpansion
echo(!DataLeft! !DataRight!
endlocal
set "DataRight=%%J"
set "DataLeft="
) else (
setlocal EnableDelayedExpansion
echo( !DataRight!
endlocal
set "DataRIGHT=%%J"
)
)
)
if defined DataLeft (
if defined DataRight (
setlocal EnableDelayedExpansion
echo(!DataLeft! !DataRight!
endlocal
set "DataLeft="
set "DataRight="
) else (
setlocal EnableDelayedExpansion
echo(!DataLeft!
endlocal
set "DataLeft=%%J"
)
)
if defined DataRight (
setlocal EnableDelayedExpansion
echo( !DataRight!
endlocal
set "DataRight="
)
)>"%TempFile%"
if /I not "%~1" == "test" (move /Y "%TempFile%" "%DataFile%") else type "%TempFile%"
del "%TempFile%"
exit /B
:MissingFile
echo ERROR: There is no file "%DataFile%" in "%CD%".
echo/
pause
endlocal
This batch file can be also executed with argument test to just output the final result instead of overwriting the source data file.
The output for the same data file example above is:
apple cat
banana dog
mango lion
grapes
pear
plum mouse
canary
cherry hamster
It can be seen that on left side are the fruits marked with * and on right side the animals marked with # in the data file.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
call /? ... for an explanation of %~1
del /?
echo /?
endlocal /?
exit /?
for /?
goto /?
if /?
move /?
pause /?
set /?
setlocal /?
type /?

Answer 4

It is hard to tell from your specifics what exactly may be the content and layout of your text file, or regarding the output, what exactly you mean by table, and whether empty cells in those tables would be acceptable.
Whilst trying to keep the idea you were using, as much as possible, and based upon the example text file you've submitted, assuming that there will not be two consecutive lines beginning with *, and using a horzontal tab, as a cell separator, line 3 Echo([TAB]%%G, here's a quick example of something which may suit your purposes:
#For /F Delims^=^ EOL^= %%G In ('%SystemRoot%\System32\findstr.exe /BIL "* #"
"S:\ome\Directory\my text.txt" 2^>NUL') Do #(
For /F "EOL=* Delims=" %%H In ("%%G") Do #Echo( %%G
For /F "EOL=# Delims=" %%I In ("%%G") Do #Set /P "=%%G" 0<NUL)
#Echo(& Pause
Example output (with the mis-spelling graps corrected):
* apple # cat
* banana # dog
* mango # lion
* grape
If you didn't want the * and # characters in your resulting output file, i.e.
apple cat
banana dog
mango lion
grape
Then the code would be modified slightly, where line 3 would have Echo([TAB]%%I:
#For /F Delims^=^ EOL^= %%G In ('%SystemRoot%\System32\findstr.exe /BIL "* #"
"S:\ome\Directory\my text.txt" 2^>NUL') Do #(
For /F "EOL=* Tokens=1,*" %%H In ("%%G") Do #Echo( %%I
For /F "EOL=# Tokens=1,*" %%J In ("%%G") Do #Set /P "=%%K" 0<NUL)
#Echo(& Pause