Batch, making a .ini file to read from [duplicate] - batch-file

Question

This question already has answers here:
Shortest Windows batch file code to get first line of a file set to a variable?
(6 answers)
Closed 1 year ago.
I'm trying to make a Borderlands 3 .bat file to remove certain files (it's a no-intro script). I do want to store the path the user input so the next time the game updates and re-download these files you can remove them fast without asking for a path later on.
This is the first code I have:
set BL3=C:\Program Files (x86)\Steam\steamapps\common\Borderlands 3
set /p BL3= Where's the Borderlands 3 folder? (Default: C:\Program Files (x86)\Steam\steamapps\common\Borderlands 3) =
The full code is here:
#echo off
title Borderlands 3 No Intro Script
:inicreator
set BL3=C:\Program Files (x86)\Steam\steamapps\common\Borderlands 3
set /p BL3= Where's the Borderlands 3 folder? (Default: C:\Program Files (x86)\Steam\steamapps\common\Borderlands 3) =
set errorlevel=0
choice /C YN /N /M "Remove the loading screen as well? (Y = Yes | N = No)"
echo If you haven't cached shaders the screen will be
echo black for awhile if you delete the loading screen.
if '%errorlevel%'=='1' (set LD=yes)
if '%errorlevel%'=='2' (set LD=no)
echo.
echo Creating .ini to store the path for future use ...
echo %BL3% >"bl3settings.ini"
if exist "%BL3%\OakGame\Content\Movies\2KLOGO.mp4" del "%BL3%\OakGame\Content\Movies\2KLOGO.mp4"
if exist "%BL3%\OakGame\Content\Movies\AMDLOGO.mp4" del "%BL3%\OakGame\Content\Movies\AMDLOGO.mp4"
if exist "%BL3%\OakGame\Content\Movies\GBXLOGO.mp4" del "%BL3%\OakGame\Content\Movies\GBXLOGO.mp4"
if '%LD%'=='yes' (if exist "%BL3%\OakGame\Content\Movies\Loading.mp4" del "%BL3%\OakGame\Content\Movies\Loading.mp4")
if '%LD%'=='yes' (echo All done! Removed 2KLOGO.mp4, AMDLOGO.mp4, GBXLOGO.mp4 and Loading.mp4)
if '%LD%'=='no' (echo All done! Removed 2KLOGO.mp4, AMDLOGO.mp4 and GBXLOGO.mp4)
echo These will come back after Boderlands 3 updates.
timeout /t 2 /nobreak>nul
The goal is to write the current loation to a file, then read it and make a variable that we can use...

Answer 1

Using the idea mentioned in SomethingDark's comment, here's a quick untested rewrite of my undertsanding of your script:
#Echo Off
SetLocal EnableExtensions
Title Borderlands 3 - No Intro Script
CD /D "%~dp0" 2>NUL || Exit /B
:DefaultLocation
Set "BL3="
If Exist "%~dp0bl3settings.ini" Set /P "BL3=" 0<"%~dp0bl3settings.ini" 2>NUL
If Not Defined BL3 Set "BL3=%ProgramFiles(x86)%\Steam\steamapps\common\Borderlands 3"
PushD "%BL3%\OakGame\Content\Movies" 2>NUL
If Not ErrorLevel 1 GoTo Actions
:GetLocation
Set "BL3="
Set /P "BL3=Where is the Borderlands 3 directory location?>"
If Not Defined BL3 GoTo GetLocation
PushD "%BL3:"=%\OakGame\Content\Movies" 2>NUL
If ErrorLevel 1 GoTo GetLocation
:Actions
Echo(
Echo Creating .ini to store the path for future use ...
CD 1>"%~dp0bl3settings.ini"
Set "StandardList="2KLOGO.mp4", "AMDLOGO.mp4", "GBXLOGO.mp4""
Set "ExtendedList=%StandardList%, "Loading.mp4""
"%SystemRoot%\System32\choice.exe /M "Remove the loading screen as well"
If ErrorLevel 2 (Del /A /F %StandardList% 2>NUL
Echo All done. Removed: %StandardList%
GoTo Finish
)
Echo If you have not cached shaders, the screen will be black for a while...
%SystemRoot%\System32\timeout.exe /T 2 /NoBreak 1>NUL
Del /A /F %ExtendedList% 2>NUL
Echo All done. Removed: %ExtendedList%
:Finish
PopD
Echo These files will come back after Borderlands 3 updates.
%SystemRoot%\System32\timeout.exe /T 2 /NoBreak 1>NUL