How do I make this script? - batch-file

Question

I want a script that uses these options in CMD:
wmic bios get serialnumber
Then ask for a Vendor ie. HP or Dell.
Then the output should be something like vendor-serialnumber from wmic, then add a - in the serialnumber, like this:
YHT3-1234
the "-" should always be before the last 4 digits in the serialnumber,
so the final output would be something like :
HP-YHT3-1234

Answer 1

Here is another way to get it with PowerShell. Unless your organization has banned it, PowerShell is available on all supported Windows systems.
FOR /F "delims=" %A IN ('powershell -NoLogo -NoProfile -Command ^
"$x=Get-CimInstance CIM_BIOSElement;"
"'{0}-{1}-{2}' -f"
"#($x.Manufacturer, $x.SerialNumber.Substring(0,$x.SerialNumber.Length - 4),"
"$x.SerialNumber.Substring($x.SerialNumber.Length - 4))"') DO (SET "RESULT=%A")
ECHO RESULT is %RESULT%
Remember to double the PERCENT SIGN characters if this goes into a .bat/.cmd script.
FOR /F "delims=" %%A IN ('powershell -NoLogo -NoProfile -Command ^
"$x=Get-CimInstance CIM_BIOSElement;"
"'{0}-{1}-{2}' -f"
"#($x.Manufacturer, $x.SerialNumber.Substring(0,$x.SerialNumber.Length - 4),"
"$x.SerialNumber.Substring($x.SerialNumber.Length - 4))"') DO (SET "RESULT=%%A")
ECHO RESULT is %RESULT%

Answer 2

Here's a quick example to show you how to introduce the hyphen/dash into your serial number, together with some additional work to auto detect the Manufacturer, and shorten to an identifier as necessary.
#Echo Off
SetLocal EnableExtensions
Set "Vendor="
Set "Serial="
For /F Tokens^=6^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe BIOS Where "Manufacturer Like '%%Hewlett-Packard%%' Or Manufacturer Like '%%Dell%%' And SerialNumber Is Not NULL" Get Manufacturer^,SerialNumber /Format:MOF 2^>NUL') Do If Not Defined Vendor (Set "Vendor=%%G") Else Set "Serial=%%G"
If Not Defined Vendor GoTo :EOF
If "%Vendor:Dell=%" == "%Vendor%" (Set "Serial=HP-%Serial:~,-4%-%Serial:~-4%") Else Set "Serial=Dell-%Serial:~,-4%-%Serial:~-4%"
Echo %Serial%
Pause
Obviously if there are a lot of Manufacturers then additional work would need to be done.
As an unnecessary courtesy, here is the same methodology, just this time affording end user the opportunity to break the code, or corrupt the result:
#Echo Off
SetLocal EnableExtensions
Set "Serial="
For /F Tokens^=6^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe BIOS Where "SerialNumber Is Not NULL" Get SerialNumber /Format:MOF 2^>NUL') Do Set "Serial=%%G"
If Not Defined Serial GoTo :EOF
Set /P "Vendor=Type the name of the Computer Manufacturer, and press ENTER>"
Echo %Vendor%-%Serial:~,-4%-%Serial:~-4%
Pause
Based upon a very limited test of one HP notebook and the comments by KJ below, the following idea may also be useful:
#Echo Off
SetLocal EnableExtensions
Set "Serial="
Set "Vendor="
For /F Tokens^=2^,4^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe
CSProduct Assoc:List 2^>NUL') Do Set "Serial=%%G" & For /F %%I In ('
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoLogo -NoProfile
"-Join '%%H'.ToUpper()[0..3]"') Do Set "Vendor=%%I"
If Not Defined Serial GoTo :EOF
Echo %Vendor%-%Serial:~,-4%-%Serial:~-4%
Pause
This uses PowerShell just to return up to the first four characters in upper case from the string returned as the Name value from the CSProduct alias of WMIC. So Compaq would return COMP, Dell as DELL, Lenovo as LENO Samsung as SAMS etc. This would then be prefixed to the serial number, (split as before), which in my test was returned as the ComputerSystemProduct IdentifyingNumber.