How to make items in a ColdFusion array unique? - arrays

Question

I have a shopping cart that is adding products to the checkout page.
As you can see this is how the structure of the cart is set up:
Problem is, I only want unique values to appear, no repeats. Not sure how to make arrays strict so it only contains unique values.

Answer 1

To make sure your cart has always only one position for each article, I'd use structs instead of arrays to have always one position per article in your cart and avoid populating it with multiple copies of the same article.
By using a struct for your cart you can create a struct key (e.g. with the article ID) that is also the unique reference to one unique article in the cart. If you use arrays you only have numbers and you would need to go and look deeper in the data structure to verify if the article is already present in the cart.
Here is just a simplistic example of how I'd make it with the data structure. I'm not adding functionality like adding/removing single units of articles. This is just an example to see how I'd deal with the cart data structure to have it referenced with an unique key, so it can be quickliy accessed and manipulated further on.
<cfscript>
// function to add an article structure to the cart
function addArticleToCart(struct articleCartData required) {
// If the article is not present in the cart, add it as a struct to the cart wirh it's own articleID as the cart struct key:
If(!structKeyExists(cart, arguments.articleCartData.articleID)) {
cart.append({
"#arguments.articleCartData.articleID#": arguments.articleCartData
});
} else {
// Add the quantity of the cart by one unit
cart[arguments.articleCartData.articleID].quantity++
};
};
//Define empty cart
cart = {};
//Define the article that will be added to the cart
articleToAdd = {
articleID: "ART12345",
articleName: "5650R Sheerweave Oyster",
quantity: 1,
unitPrice: 12.99
};
// Call the function to add the article to the cart
addArticleToCart(
articleToAdd
);
writedump(cart);
addArticleToCart(
articleToAdd
);
writedump(cart);
addArticleToCart(
articleToAdd
);
writedump(cart);
</cfscript>

Answer 2

Here's one solution how to make the array items unique.
Code
<cfscript>
cart = [
{
title: "foo"
},
{
title: "bar"
},
{
title: "foo"
},
{
title: "foo"
},
{
title: "bar"
}
];
function makeItemsUnique(array, property) {
return arrayReduce(array, function(reducedArray, item) {
if (not arraySome(reducedArray, function(uniqueItem) { return uniqueItem[property] eq item[property]})) {
arrayAppend(reducedArray, item);
}
return reducedArray;
}, []);
}
writedump(makeItemsUnique(cart, "title"));
</cfscript>
Output
Explanation
The function makeItemsUnique() is responsible for making the items in the cart unique. It's kept general to allow it to work with different kinds of arrays of structs. It is called with the cart array and the property name used to filter it.
In that function the call to arrayReduce() reduces the array to a new one that only contains unique items. It does so by checking whether the new array already has an item with the same title in it. This check is done using arraySome(). If the new array doesn't contain an element with that title yet, it is added via arrayAppend().