Array.Exists for boolean comparison in integer array (converted from string) - arrays

Question

I'm trying to find if certain values in a given string of numbers are less than a numeric value.
I'm trying to create a new integer array and iterate through the string array to fill it. Then I'm trying to use Array.Exists(arr, predicate), but I don't think I'm using it correctly.
I wasn't able to simply do Array.Exists(larr, element => element <=16) because my compiler required I have parentheses like Array().Exists(larr, element...) or Array(larr).Exists(lar, element...).
What would you recommend changing in my code so that I can transform a string into an array of numbers or some other data structure that will allow me to check if any value within it is <=some value?
Dim orgnameB As Range
Dim orgList As Range
Set orgList = Worksheets("Org List").Range("B3:B10")
sites = Worksheets("Org List").Cells(orgnameB.row, "E")
max_num = Evaluate("Max(" & sites & ")")
sarr = Split(sites, ", ")
Dim ArrayLen As Integer
ArrayLen = UBound(sarr) - LBound(sarr) + 1 'this was causing issues, unsure how to do this
Dim larr(ArrayLen) As Integer
Set result = Worksheets("Org List").Cells(orgnameB.row, "O")
'Loop through str array to convert to int array
For i = LBound(sarr) To UBound(sarr)
larr(i) = CInt(sarr(i))
Next i
For Each orgnameB In orgList
If IsEmpty(orgnameB) = True Then
Exit For
End If
If max_num >= 1 And max_num <= 15 Then
result.Value = "YES"
ElseIf max_num >= 16 And max_num <= 50 Then
If Array(larr).Exists(larr, element => element <= 16) = True Then
result.Value = "YES"
End If
ElseIf max_num >= 51 And max_num <= 250 Then
If Array(larr).Exists(larr, element => element <= 51) = True Then
result.Value = "YES"
End If
ElseIf max_num >= 251 And max_num <= 1000 Then
If Array(larr).Exists(larr, element => element <= 250) = True Then
result.Value = "YES"
End If
ElseIf max_num >= 1001 Then
If Array(larr).Exists(larr, element => element <= 1000) = True Then
result.Value = "YES"
End If
End If
Next
End Sub

Answer 1

FilterXML() as VBA simulation of Array.Exists():
Of course Excel VBA cannot apply specific .Net or C syntax.
Therefore the following example demonstrates how to rebuild a similar functionality (returning True for existant array findings) via the FilterXML() function which allows to specify multiple conditions.
It offers the extra benefit, however that it doesn't return only a boolean value, but that it returns all found (numeric) elements as 0-based 1-dim output array
which can be analyzed and/or reused easily eventually.
Example call
Dim InArray() As Variant, limits() As Variant, OutArray() As Variant
InArray = Array(10, 11, 12, 13, 14, 15)
limits = Array(9) ' find elements <= 9
Debug.Print "Array exists: " & ArrExists(InArray, limits, OutArray), UBound(OutArray) + 1 & " Element(s) ~> " & Join(OutArray, ",")
' Array exists: False 0 Element(s) ~>
limits = Array(13) ' find elements <= 13
Debug.Print "Array exists: " & ArrExists(InArray, limits, OutArray), UBound(OutArray) + 1 & " Element(s) ~> " & Join(OutArray, ",")
' Array exists: True 4 Element(s) ~> 10,11,12,13
limits = Array(11, 13) ' find elements >=11 and <= 13
Debug.Print "Array exists: " & ArrExists(InArray, limits, OutArray), UBound(OutArray) + 1 & " Element(s) ~> " & Join(OutArray, ",")
' Array exists: True 3 Element(s) ~> 11,12,13
End Sub
Help Function `ArrExists()
The following functions profits from filtering a well formed XML content by
a so called XPath expression, which is available since vers. 2013+.
Note that findings are automatically assigned to a 2-dim array, only non-findings result in an error value.
In order to return results again to a "flat" 1-dim output array, they need to be transposed.
Function ArrExists(InArray, limits, Optional OutArray) As Boolean
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'1. define FILTERXML arguments
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
' a) build Xml content
Dim XmlContent As String
XmlContent = "<items><i>" & Join(InArray, "</i><i>") & "</i></items>"
' b) build XPath expression
Dim XPathExpression As String
If UBound(limits) Then
If limits(1) > limits(0) Then
XPathExpression = "//i[.>=" & limits(0) & "][.<=" & limits(1) & "]"
Else
XPathExpression = "//i[.>=" & limits(1) & "][.<=" & limits(0) & "]"
End If
Else
XPathExpression = "//i[.<=" & limits(0) & "]"
End If
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'2. apply FILTERXML() function
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'a) get results as 2-dim array
Dim results: results = Application.FilterXML(XmlContent, XPathExpression)
'b) check for no result or one result only
If Not IsArray(results) Then
If IsError(results) Then
ReDim results(0 To 0, 1 To 1)
Else
Dim tmp As Variant: tmp = results
ReDim results(1 To 1, 1 To 1)
results(1, 1) = tmp
End If
End If
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'3.Function results
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'a)return existence as boolean value
If LBound(results) Then ArrExists = True
'b)optional: overwrite referenced array
If Not IsMissing(OutArray) Then
If ArrExists Then
OutArray = Application.Transpose(results) ' results now 1-based
ReDim Preserve OutArray(0 To UBound(OutArray) - 1) ' redim as zero-based
Else
ReDim OutArray(-1 To -1)
End If
End If
End Function