sheet names in an array but not always the same sheets - arrays

Question

I'm trying to create a pdf of the various sheet in the workbook based on certain criteria in VBA
my current code is
Sub ExportAsPDF()
Dim FolderPath As String
FolderPath = "C:\Users\USER1\Desktop\PDF\pdftest"
'sheet names in ""
Sheets(Array("SHEET1","SHEET2","SHEET3")).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, filename:=FolderPath, _
openafterpublish:=False, ignoreprintareas:=False
MsgBox "All PDFs have been successfully exported."
End Sub
the above works but there are more than 9 sheets and sometimes sheet 2 will be needed sometimes it won't. how do I write the array selection to a variable based on criteria?
if a=1 then add sheet 2 to the array kind thing
Thank You for your help!

Answer 1

You can set up an array with the sheet names, then add Sheet2 if required:
Dim arr, test
test = True 'variable which controls adding sheet2....
arr = Array("Sheet1", "Sheet5") 'array without sheet2
'need to add sheet2?
If test Then
ReDim Preserve arr(LBound(arr) To UBound(arr) + 1)
arr(UBound(arr)) = "Sheet2"
End If
ThisWorkbook.Sheets(arr).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"C:\Tester\tempo.pdf", Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=True

Answer 2

Function AvoidWB2() As String()
Dim v() As String, i As Long, wbCount As Long
wbCount = ActiveWorkbook.Sheets.Count
ReDim v(1 To wbCount)
For i = 1 To wbCount
If i = 2 Then
'do something here regarding adding sheet 2.
Else
v(i) = ActiveWorkbook.Sheets(i).Name
End If
Next i
AvoidWB2 = v
End Function
Sub ExportAsPDF()
Dim FolderPath As String, vSheetSelection() as Variant
FolderPath = "C:\Users\USER1\Desktop\PDF\pdftest"
'sheet names in ""
'----| Implement Here|
Sheets(AvoidWB2).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, filename:=FolderPath, _
openafterpublish:=False, ignoreprintareas:=False
MsgBox "All PDFs have been successfully exported."
End Sub

Answer 3

Here is an example based on the described requirements.
This example assumes:
You only want to consider excluding Sheet2 from the pdf.
You deterime if Sheet2 is to be included or not by the value in Cell B1 on Sheet2
I've adapted some If...Then conditioning with a For Each...Next loop to your existing code.
Sub ExportAsPDF()
Dim FolderPath As String
Dim SheetsArray As Variant
Dim TargetSheet As Worksheet
Dim ArrayCounter As Long: ArrayCounter = 0
FolderPath = "C:\Users\USER1\Desktop\PDF\pdftest"
'sheet names in ""
If Sheets("Sheet2").Range("B1").Value = "Yes" Then
ReDim SheetsArray(ThisWorkbook.Worksheets.Count - 1)
For Each TargetSheet In ThisWorkbook.Worksheets
SheetsArray(ArrayCounter) = TargetSheet.Name
ArrayCounter = ArrayCounter + 1
Next TargetSheet
Else
ReDim SheetsArray(ThisWorkbook.Worksheets.Count - 2)
For Each TargetSheet In ThisWorkbook.Worksheets
If Not TargetSheet.Name = "Sheet2" Then
SheetsArray(ArrayCounter) = TargetSheet.Name
ArrayCounter = ArrayCounter + 1
End If
Next TargetSheet
End If
ThisWorkbook.Sheets(SheetsArray).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FolderPath, _
openafterpublish:=False, ignoreprintareas:=False
MsgBox "All PDFs have been successfully exported."
End Sub
If the value of Sheet2.Range("B1") is "Yes" then Sheet2 is included in the pdf, otherwise if it's any other value it is not included.
Explanation:
Relevant documentation:
Using Arrays (Covers setting lower/upper bound of array etc.)
If...Then...Else statement (VBA)
For...Next statement (VBA)
First I evaluate whether Sheet2.Range("B1") = "Yes" to dictate how we will populate the SheetsArray.
The statements are very similar depending on if it's "Yes" or not.
The ReDim SheetsArray is to set the dimension of our Array. Because arrays in VBA are Base 0 by default (meaning the first element of the array is 0, the second element is 1 etc...) I size the array as follows:
If the value is "Yes" the array is sized as 1 less than the number of worksheets. This is to account for the array starting at 0 rather than 1.
If the value is not "Yes" then the array is sized at 2 less than the number of worksheets. This accounts for the array starting at 0 rather than 1 AND that we are not including Sheet2.
The For Each...Next loop then iterates over the Worksheets collection, adding each worksheet name to the array. We have an extra If...Then statement within the code block for if the value is not "Yes" to determine if the TargetSheet is not Sheet2 and add the worksheet name if this condition is met. This will exclude Sheet2 from being added to our array.
The ArrayCounter variable simply increments with each worksheet name added to the array as "To set the value of an individual element, you specify the element's index."