How to dynamically attach the filepath of pdf to the batch script - batch-file

Question

I'm getting wrong with the older version Microsoft Edge and now I can't open pdf files with it. Though the newer version is available, I don't really like the newer version.Yesterday I learned that I can use Microsoft Edge to open pdf file through command line like below, but I don't know how to dynamically attach the filepath of the pdf to my batch script when I choose to open the pdf with my batch script.
start shell:AppsFolder\Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEdge file:\\\d:\\xxx.pdf

Answer 1

Open a command prompt, run call /? and read the output help carefully and completely. It explains how batch file arguments can be referenced from within a batch file. Argument 0 is always the batch file itself.
The batch file for your purpose could be coded as:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FileName=%~1"
if not defined FileName goto PrintHelp
set "FileName=%FileName:"=%"
if not defined FileName goto PrintHelp
if "%FileName%" == "/?" goto PrintHelp
set "FileName=%FileName:/=\%"
if not exist "%FileName%" (
echo ERROR: File not found: "%FileName%"
echo/
pause
goto EndBatch
)
set "FileName=%FileName:\=/%"
if not "%FileName:~0,1%" == "/" set "FileName=///%FileName%"
start "" shell:AppsFolder\Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEdge "file:%FileName%"
goto EndBatch
:PrintHelp
echo INFO: %~nx0 must be called with name of a file to open in Microsoft Edge.
echo/
pause
:EndBatch
endlocal
I do not really understand why a batch file is needed at all to open PDF files in Microsoft Edge. It would be also possible to simply associate the file extension .pdf with Microsoft Edge to get PDF files opened by default with Microsoft Edge.
The following command line can be executed in a command prompt window to get displayed which application is associated currently with file extension .pdf and which command is used to open a PDF file with %1 being the placeholder for the file name:
for /F "skip=1 tokens=2*" %I in ('%SystemRoot%\System32\reg.exe query HKEY_CLASSES_ROOT\.pdf /ve 2^>nul') do %SystemRoot%\System32\reg.exe query "HKEY_CLASSES_ROOT\%J\Shell\Open\Command" /ve
For understanding the commands used in the batch file and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
echo /?
endlocal /?
goto /?
if /?
pause /?
set /?
setlocal /?
start /?
See also the Wikipedia article about file URI scheme. It would be necessary to percent encode the file name for a 100% correct file URL, but Microsoft Edge supports also not correct encoded file URLs containing for example a space character instead of %20 or the umlaut ä instead of %c3%a4.

Answer 2

I'd assume that you could open your pdf located in the same directory as your batch-file, with the assistance of powershell:
#Echo Off & SetLocal EnableExtensions DisableDelayedExpansion
Set "filename=myfile! - 100%% virus free.pdf"
%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoProfile -NoLogo -Command "[System.Diagnostics.Process]::Start(\"msedge\",\"`\"%~dp0%filename%`\"\")"
You would replace my example filename with your own on line 2, (taking special care not to touch the closing doublequote). Please note that I have deliberately used a filename of myfile! - 100%% virus free.pdf, to show you that you must double any percent character in your filename, (as the percent character requires special treatment when used in a batch file).

Answer 3

In fact I got my answer after viewing some dos doc. And below is my solution(which is available for open pdf with 'open with' this batch script. To avoid opening the cmd window(it's ugly to my view), I also convert it to a exe using bat2exe converter.
#echo off
set prefix=file:///
set filepath=%~f1
set truepath=%filepath%%filepath:\=/%
start shell:AppsFolder\Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEdge %truepath%