How do you edit a text outcome in a batch file - batch-file

Question

Im new to learning to code batch files.
Basically I have this script
#echo off
echo.
echo Current Serials-
echo.
wmic bios get serialnumber
wmic diskdrive get serialnumber
wmic baseboard get serialnumber
pause
Which has this output
Current Serials-
SerialNumber
Insert Serial Number Here
SerialNumber
Insert Serial Number Here
Insert Serial Number Here
SerialNumber
Insert Serial Number Here
But I want the output to look like this
Current Serials-
Bios SerialNumber- Insert Serial Number Here
Diskdrive SerialNumber- Insert Serial Number Here, Insert Serial Number Here
BaseBoard SerialNumber- Insert Serial Number Here
So how do I do that?

Answer 1

The simplest approach is using a for /F loop to catch and split the output of wmic
#Echo off
Echo(Current Serial numbers:
For %%A in (Bios Diskdrive Baseboard) Do (
For /F "Skip=1 Delims=" %%G in ('WMIC %%A get serialnumber') Do (
For %%O in (%%G)Do Echo(%%A Serial Number: %%O
))

Answer 2

To process files, strings or command outputs, use a for loop. See for /? (then read it again - it's one of the mightiest commands in cmd. Any time you invest into understanding it is a good investment.)
#echo off
setlocal enabledelayedexpansion
set "drives=Diskdrive "
for /f %%a in ('wmic diskdrive get serialnumber^|findstr .') do set "drives=!drives!%%a, "
echo %drives:~0,-2%
As you are new to cmd, let me suggest SS64. Save it as favorite and visit it often.

Answer 3

You could probably do it in a single line from your batch-file, with the help of powershell:
#PowerShell -NoP "Write-Host Current Serials-`r`n`r`nBIOS - $(GCim CIM_BIOSElement).SerialNumber`r`nPrimary Disk - $(GCim CIM_DiskDrive -F \"DeviceID Like '%%PHYSICALDRIVE0'\").SerialNumber.Trim()`r`nMotherboard - $(Get-CimInstance -Query \"Select * From CIM_Card Where Name='Base Board'\").SerialNumber"

Answer 4

Because serialnumbers contains numeric, but the empty lines and the word Serianumber does not, I use findstr to determine which lines are serials and only echo them.
#echo off
for %%i in (Bios Diskdrive Baseboard) do (
for /f "delims=" %%a in ('wmic %%~i get serialnumber ^| findstr /r "[0-9]"') do echo %%~i Serialnumber- %%a
)

Answer 5

Just another option if you just want to use the standard output from the WMIC commands.
set /p ".=BIOS "<nul&wmic bios get serialnumber /value|more|findstr /I "serial"
set /p ".=DISKDRIVE "<nul&wmic diskdrive get serialnumber /value|more|findstr /I "serial"
set /p ".=BASEBOARD "<nul&wmic baseboard get serialnumber /value|more|findstr /I "serial"
Which would give you output like this.
BIOS SerialNumber=3ZB80R2
DISKDRIVE SerialNumber=0100_0000_0000_0000_8CE3_8E04_0016_7812.
BASEBOARD SerialNumber=/3ZB80R2/TW320709A3011C/
Or you could simplify it with a FOR command.
FOR %%G IN (BIOS DISKDRIVE BASEBOARD) DO set /p ".=%%G "<nul&wmic %%G get serialnumber /value|more|findstr /I "serial"

Answer 6

If you need to get all disk serial numbers on the same line also delimited by a comma...
#echo off
set "_str=SerialNumber"
echo\ & echo\Current Serials-
setlocal enabledelayedexpansion
set "_gets=Bios,DiskDrive,BaseBoard"
set "_wmic=%__AppDir__%wbem\wmic.exe"
echo\ & for %%i in (!_gets!)do for /f usebackq %%I in (`
!_wmic! %%i get %_str%^|%__AppDir__%Findstr.exe/v %_str%^|%__AppDir__%Findstr.exe .
`)do echo\%%i;|%__AppDir__%Findstr.exe /bl Bios; >nul && (echo\%%i !_str!- %%I
)|| if /i "%%~i" == "BaseBoard" (echo=!_sn!&& echo\%%~i !_str!- %%~I
)else if "!_sn!" == "" (set "_sn=%%~i !_str!- %%~I"
)else set "_sn=!_sn!, %%~I"
>con: %__AppDir__%TimeOut.exe -1|echo\Press any key to continue... & endlocal & goto :eOf
Results
Current Serials-
Bios SerialNumber- XTE03A187
DiskDrive SerialNumber- 50026B776605D1D3, ZDZ0QKMT
BaseBoard SerialNumber- S0AFF01XDTS
Press any key to continue...
In conventional layout:
#echo off
setlocal enabledelayedexpansion
echo\
echo\Current Serials-
echo\
for %%i in (Bios,DiskDrive,BaseBoard)do (
for /f usebackq %%I in (`%__AppDir__%wbem\wmic.exe %%i get SerialNumber^|%__AppDir__%Findstr.exe/v SerialNumber^|%__AppDir__%Findstr.exe .`)do (
echo\%%i;|%__AppDir__%Findstr.exe /bl Bios; >nul && (
echo\%%i SerialNumber- %%I ) || (
if /i "%%~i" == "BaseBoard" (
echo=!_sn!&& echo\%%~i SerialNumber- %%~I
) else if "!_sn!" == "" (
set "_sn=%%~i SerialNumber- %%~I"
) else (
set "_sn=!_sn!, %%~I"
)
)
)
%__AppDir__%TimeOut.exe -1
endlocal