VBA Create array with userform items - arrays

Question

I have a a list of checkbox in userform. I would like to create a code that is more efficient that the following one :
If checkbox1.value = true
Then Range("A1").value = 100
End if
If checkbox2.value = true
Then Range("A2").value = 200
End if
If checkbox3.value = true
Then Range("A3").value = 300
End if
The problem is that I have 40 checkbox and I would like to create something that says: in my list of checkbox, if it is true then add in my range A1. I'm not sure how to proceed but I tried this:
Dim Element as variant
For each element in MyList
If element.value = true Then
For i = 1 to NumberOfTrueElement
Range("A" & i + 1).value = Mylist(i)
Next i
End if
Next
Mylist is the frame of all my checkboxes.
Please help me if you have a hint.

Answer 1

It's not really clear where the array part comes into thing but if we assume a couple of things,
You have an array named Mylist with 40 items.
The checkboxes are named consistently e.g. checkbox1, checkbox2 etc
then you could use something like this.
For I = 1 To 40
If Me.Controls("checkbox" & I).Value
Range("A" & I).Value = Mylist(I)
End If
Next I

Answer 2

Please, try this way:
Dim i As Long, k As Long
For k = 0 To Me.Controls.count - 1
If TypeName(Me.Controls(k)) = "CheckBox" Then
i = i + 1
If Me.Controls("checkbox" & i).value Then
Range("A" & i).value = i * 100
End If
End If
Next k
If you need a faster way, please test the next code:
Dim i As Long, k As Long, arr
ReDim arr(Me.Controls.count)
For k = 0 To Me.Controls.count - 1
If TypeName(Me.Controls(k)) = "CheckBox" Then
i = i + 1
If Me.Controls("checkbox" & i).value Then
arr(i - 1) = i * 100
Else
arr(i - 1) = "False"
End If
End If
Next k
ReDim Preserve arr(i - 1)
Range("A1").Resize(UBound(arr) + 1, 1) = Application.Transpose(arr)
It loads the necessary values in an array, using "False" when the check box is not checked and drops the array values at once at the end.
Of course, the check boxes name should be consistently built. Starting from "checkbox1" to "checkboxn". If the name consistence exists, the code works for as many check boxes exist on the form...

Answer 3

Write Value If Checkbox Checked
A kind of an answer would be in the CommandButton_Click procedure.
This example is easily setup by anyone: open a new workbook, add a user form and add a command button on it. Double-click the command button and copy the following code to the just-opened window (user form code). Run the first procedure. Tick a few checkboxes and press the command button. See the copied values in the first column of the worksheet.
The Code
Option Explicit
Sub doShow()
UserForm1.Show
End Sub
Private Sub CommandButton1_Click()
Dim arr() As Variant: ReDim arr(1 To Me.Controls.Count)
Dim chb As MSForms.Control
Dim n As Long
For Each chb In Me.Controls
If TypeName(chb) = "CheckBox" Then
n = n + 1
If chb.Value = True Then
arr(n) = n * 100
End If
End If
Next chb
ReDim Preserve arr(1 To n)
With ThisWorkbook.Worksheets("Sheet1")
.Range("A1").Resize(n).Value = Application.Transpose(arr)
End With
End Sub
Private Sub UserForm_Initialize()
Const CheckBoxesCount As Long = 10
Dim n As Long
For n = 1 To CheckBoxesCount
With Me.Controls.Add("Forms.CheckBox.1", "CheckBox_" & n, True)
.Caption = "CheckBox" & n
.Left = 5
.Top = 5 + ((n - 1) * 20)
End With
Next n
End Sub