How to use puts with multiple variable in one argument in Tcl? - loops

Question

I have a series of list like a1, a2, a3, a4, ....
I want to print them in a loop, Thus both a and i are variables. How can I do that?
This doesn't work.
for {set i 1}....
puts $a$i
}
Thanks in advance

Answer 1

Ideally you'd have them in an associative array, but otherwise…
To read from a variable whose name is not constant, use the set command with just one argument instead of the $ syntax. (This use of set predates $.)
for {set i 1} {$i <= 3} {incr i} {
puts [set a$i]
}
However, it would be better to use an array (so the variables would effectively be named a(1), a(2), etc instead of a1, a2, etc). But it does mean a change to the code that creates the variables too.
for {set i 1} {$i <= 3} {incr i} {
puts $a($i)
}
The other realistic option for doing access to variable variables is the upvar command. It's not really recommended in the global namespace, but in a procedure it's very effective.
proc printThree {} {
for {set i 1} {$i <= 3} {incr i} {
upvar 1 a$i vbl
puts $vbl
}
}
This works particularly well when doing more complex operations than just printing the value.

Answer 2

As list:
set a1 [list 1 2 3 4]
set a2 [list 10 20 30 40]
set a3 [list 100 200 300 400]
set a4 [list 1000 2000 3000 4000]
foreach i [list {*}$a1] { puts "\$a$i: [set a$i]" }
# $a1: 1 2 3 4
# $a2: 10 20 30 40
# $a3: 100 200 300 400
# $a4: 1000 2000 3000 4000
As array:
array set a {
1 {1 2 3 4}
2 {10 20 30 40}
3 {100 200 300 400}
4 {1000 2000 3000 4000}
}
parray a
# a(1) = 1 2 3 4
# a(2) = 10 20 30 40
# a(3) = 100 200 300 400
# a(4) = 1000 2000 3000 4000
As dict:
set a [dict create \
a1 {1 2 3 4} \
a2 {10 20 30 40} \
a3 {100 200 300 400} \
a4 {1000 2000 3000 4000}]
dict for {k v} $a { puts "$k: $v" }
# a1: 1 2 3 4
# a2: 10 20 30 40
# a3: 100 200 300 400
# a4: 1000 2000 3000 4000
As matrix:
package require struct::matrix
::struct::matrix xdata
xdata add columns 4
xdata add rows 4
xdata set rect 0 0 {
{1 2 3 4}
{10 20 30 40}
{100 200 300 400}
{1000 2000 3000 4000}
}
join [xdata get rect 0 0 end end] \n
# 1 2 3 4
# 10 20 30 40
# 100 200 300 400
# 1000 2000 3000 4000
#cleanup
xdata destroy