Arraylist of Dates and SQL in VB.Net - sql-server

Question

I have an Arraylist of Dates as such
8/30/2020
8/27/2020
9/28/2020
9/9/2020
8/31/2020
8/29/2020
I then have a query with an in clause for the dates as such
allQuery = "Select pj.ProjectName, tcd.Date, sum(tcd.Executed), sum(tcd.Passed), sum(tcd.Passedbug), sum(tcd.Flaky), sum(tcd.Failed), sum(tcd.Newfailures) "
allQuery &= "From qastats.dbo.TestCaseDetails tcd inner Join qastats.dbo.Pipelines p on tcd.PipelineID=p.PipelineID inner Join qastats.dbo.Projects pj on p.ProjectID=pj.ProjectID "
allQuery &= "where pj.ProjectName =#projectname "
allQuery &= "And tcd.Date in (#dates) group by pj.ProjectName, tcd.Date"
I want to take the list of dates in the Array list and put it in this format (same as String.Join)
8/30/2020,8/27/2020,9/28/2020,9/9/2020,8/31/2020,8/29/2020
so I can pass them in as a value for the parameter
comm.Parameters.Add("#dates", SqlDbType.DateTime).Value = ListofDates
Is there a way to do it the way I want or a better way?
Thanks

Answer 1

As suggested on the comments, use List instead of ArrayList.
Use a table valued parameter for the dates.
You'll need to create the table type in the database like this (I modified your query slightly moving the dates validation into a join if you want it in the where you can uncomment the commented line and comment the one for the join to #dates):
CREATE TYPE dbo.DatetimeTvp AS TABLE
(
value DATETIME NOT NULL
)
And then you can use this code:
Private Sub RunQuery()
Dim dates As IList(Of DateTime) = New List(Of DateTime)({DateTime.Now, DateTime.UtcNow})
Dim sb As StringBuilder = New StringBuilder()
sb.AppendLine(" Select pj.ProjectName, tcd.Date, sum(tcd.Executed), sum(tcd.Passed), sum(tcd.Passedbug), sum(tcd.Flaky), sum(tcd.Failed), sum(tcd.Newfailures) ")
sb.AppendLine(" From qastats.dbo.TestCaseDetails tcd ")
sb.AppendLine(" inner Join qastats.dbo.Pipelines p on tcd.PipelineID=p.PipelineID ")
sb.AppendLine(" inner Join qastats.dbo.Projects pj on p.ProjectID=pj.ProjectID ")
sb.AppendLine(" inner Join #dates dts on dts.value = tcd.Date ")
sb.AppendLine(" where pj.ProjectName =#projectname ")
'sb.AppendLine(" and tcd.Date in (select value from #dates) ")
sb.AppendLine(" group by pj.ProjectName, tcd.Date ")
Using cn As SqlConnection = New SqlConnection(ConnectionString)
Using cmd As SqlCommand = New SqlCommand(sb.ToString(), cn)
Dim pDates = GetTvp("#dates", dates.Distinct())
cmd.Parameters.Add(pDates)
Dim ds As DataSet = New DataSet()
Dim sqlAd = New SqlDataAdapter(cmd)
sqlAd.Fill(ds)
Print(ds)
End Using
End Using
End Sub
Private Function GetTvp(ByVal name As String, ByVal dates As IEnumerable(Of DateTime)) As SqlParameter
Dim dt As DataTable = New DataTable()
dt.Columns.Add("value", GetType(DateTime))
For Each d In dates
dt.Rows.Add(d)
Next
Dim p As SqlParameter = New SqlParameter(name, dt)
p.SqlDbType = SqlDbType.Structured
p.TypeName = "dbo.DatetimeTvp"
Return p
End Function