Batch File To Remove Starting Videos in Conan Exiles DefaultGame.ini - batch-file

Question

#echo OFF
setlocal EnableExtensions DisableDelayedExpansion
set "FileName=F:\Program Files(x86)\SteamLibrary\steamapps\common\Conan Exiles\ConanSandbox\Config\DefaultGame.ini"
set "TempFile=%TEMP%\%~n0.tmp"
if not exist "%FileName%" goto EndBatch
del "%TempFile%" 2>nul
for /F delims^=^ eol^= %%A in ('%SystemRoot%\System32\findstr.exe /N "^" "%FileName%"') do (
set "Line=%%A"
setlocal EnableDelayedExpansion
if not "!Line:+StartupMovies=StartupUE4!" == "!Line!" (
echo -StartupMovies=StartupUE4
) else if not "!Line:+StartupMovies=StartupNvidia!" == "!Line!" (
echo -StartupMovies=StartupNvidia
) else if not "!Line:+StartupMovies=CinematicIntroV2!" == "!Line!" (
echo -StartupMovies=CinematicIntroV2
) else echo(!Line:*:=!
endlocal
) >>"%TempFile%"
rem Is the temporary file not binary equal the existing INI file, then move
rem the temporary file over existing INI file and delete the temporary file
rem if that fails like on INI file currently opened by an application with
rem no shared write access. Delete the temporary file if it is binary equal
rem the existing INI file because of nothing really changed.
%SystemRoot%\System32\fc.exe /B "%TempFile%" "%FileName%" >nul
if errorlevel 1 (
move /Y "%TempFile%" "%FileName%"
if errorlevel 1 del "%TempFile%"
) else del "%TempFile%"
:EndBatch
endlocal
What it starts with in that ini file
[/Script/MoviePlayer.MoviePlayerSettings]
bWaitForMoviesToComplete=True
bMoviesAreSkippable=True
-StartupMovies=
+StartupMovies=StartupUE4
+StartupMovies=StartupNvidia
+StartupMovies=CinematicIntroV2
What i want it to do
[/Script/MoviePlayer.MoviePlayerSettings]
bWaitForMoviesToComplete=True
bMoviesAreSkippable=True
-StartupMovies=
-StartupMovies=StartupUE4
-StartupMovies=StartupNvidia
-StartupMovies=CinematicIntroV2
What it Really Does
[/Script/MoviePlayer.MoviePlayerSettings]
bWaitForMoviesToComplete=True
bMoviesAreSkippable=True
-StartupMovies=
-StartupMovies=StartupUE4
-StartupMovies=StartupUE4
-StartupMovies=StartupUE4
Me and My Buddy have been at this for a bit this is as close as we have gotten to getting even remotely close before this we had it repeating and replaceing the whole ini file and repeating in a loop now we are just having trouble getting the code to work right and replace all the lines like we want it
Any ideas On How i can Possibly Fix this?

Answer 1

Aaaak! It would probably be easier if you got rid of the if not ... else ... structure. Your double-negatives are very hard to follow.
As for your problem, examine :
"!Line:+StartupMovies=StartupUE4!" == "!Line!"
This will replace any +StartupMovies in line with StartupUE4 and compare the result to the original value of Line
This means that any line containing +StartupMovies will test FALSE. You use a NOT in your if test, so the following echo -StartupMovies=StartupUE4 will be executed for any line which contains +StartupMovies.
Try this:
....
for /F "usebackq delims=" %%A in ("%FileName%") do (
setlocal EnableDelayedExpansion
set "Line=%%A"
set "regurgitate=Y"
if "!Line:+StartupMovies=!" NEQ "!Line!" (
rem a "+StartupMovies" line
for %%s in (StartupUE4 StartupNvidia CinematicIntroV2) do if "!Line:%%s=!" NEQ "!Line!" (
echo -StartupMovies=%%s
set "regurgitate="
)
)
if defined regurgitate echo %%A
endlocal
) >>"%TempFile%"
....
Since filename is quoted (as it has to be assuming its contents may include spaces), then the usebackq modifier tells batch that it is to process the file "%FileName%". The delims= assigns the entire line to %%A.
For each line, regurgitate is set to a non-empty value. Detect the required common string and if that line also includes any of the three strings, then echo the -start... line and set the value of regurgitate to empty
If regurgitate survives the process, then simply echo the original unprocessed line.
Now, if you simply want to change +startup... to -startup... then this is a little shorter:
for /F "usebackq delims=" %%A in ("%FileName%") do (
setlocal EnableDelayedExpansion
set "Line=%%A"
echo !Line:+StartupMovies=-StartupMovies!
endlocal
) >>"%TempFile%"
That is, if the string is found, replace it; otherwise, regurgitate it.