Multiple Option Batch File [closed] - batch-file

Question

Closed. This question needs debugging details. It is not currently accepting answers.
Edit the question to include desired behavior, a specific problem or error, and the shortest code necessary to reproduce the problem. This will help others answer the question.
Closed 2 years ago.
Improve this question
I am trying to make an easy messenger program for our office.
I'm not sure what I am missing, but everytime I try running the code for options, it just messages my computer and not the one I am trying to message. I am able to message the other computer if I don't have the easy options.
Please Help!
I would like to just choose a number and have the program paste that choice to the prompt. ex the user chose 1, that is person a (code for person a is /server:ECRCL). The code "/server:ECRCL" is now showing on the prompt for the "c" in the msg code. (%c% %m%)*
Here is my code:
#echo off
Title Doodle's Messenger Program
echo Messenger
chdir /
echo Select a Person
echo 1) Person a
echo 2) Person b
echo 3) Person c
echo 4) Person d
:START
echo ========================================
set /p c=Choose the number of the person you would like to message:
if %c%=="1" echo /server:ECRCL
if %c%=="2" echo /server:ECRCB
if %c%=="3" echo /server:ECRCCI
if %c%=="4" echo /server:ECRCCO
:A
set /p m=Message:
msg * %c% %m%
GoTo A
:1
: echo %/server:ECRCL /time:300 /v /w%
:2
:/server:ECRCB
:3
:/server:ECRCCI
:4
:/server:ECRCCO
The following script does work for messaging but I would like to make it easier for others with typing 1, 2, 3, or 4
#echo Copy one of the following computers you would like to message and paste it where it asks for the computer name.
#echo person a - /server:ECRCL
#echo person b - /server:ECRCB
#echo person c - /server:ECRCCI
#echo person d - /server:ECRCCO
:START
set /p c=Enter Selection:
:A
set /p m=Message:
msg * %c% %m%
GoTo A

Answer 1

Here's an example which may assist you.
#Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
Title Doodle's Messenger Program
Set "msg=%SYSTEMROOT%\System32\msg.exe"
If %PROCESSOR_ARCHITECTURE:~-2% Equ 86 If Defined PROCESSOR_ARCHITEW6432 Set "msg=%SYSTEMROOT%\SysNative\msg.exe"
For %%G In ("%msg%") Do If "%%~aG" Lss "-" (Set "msg=") Else If "%%~aG" GEq "d" Set "msg="
If Not Defined msg (Echo Error! The system file msg.exe is missing.
"%__AppDir__%timeout.exe" /T 3 /NoBreak 1> NUL
GoTo :EOF)
:Start
Echo(
Echo Messenger Selection List
Echo 1. Viktor [//ECRCL]
Echo 2. Rashi [//ECRCB]
Echo 3. Kian [//ECRCCI]
Echo 4. Cedric [//ECRCCO]
Echo(
"%__AppDir__%choice.exe" /C 1234 /N /M "Enter the number for the user you would like to message."
If %ErrorLevel% Equ 1 Set "Svr=ECRCL"
If %ErrorLevel% Equ 2 Set "Svr=ECRCB"
If %ErrorLevel% Equ 3 Set "Svr=ECRCCI"
If %ErrorLevel% Equ 4 Set "Svr=ECRCCO"
:AskMessage
Set "m="
Set /P "m=Please type your message, then press the enter key>"
If Not Defined m (
Echo Empty messages are not allowed!
"%__AppDir__%timeout.exe" /T 2 /NoBreak 1> NUL
GoTo AskMessage
)
%msg% * /server:%svr% %m%
GoTo Start

Answer 2

As Compo has stated, the choice command is the option for this style of menu, however it's possible to use the value returned by choice in a more direct fashion to enact the desired commands by combining indexed variables with associated variables and Delayed expansion with For loop metavariables to pull the server Id from the indexed recipient number.
#Echo Off& Setlocal DisableDelayedExpansion
rem // Macro Definitions
Set "MSG=%SYSTEMROOT%\System32\msg.exe * "
Set "List/D/V=Set "#$L=0"&Set "$$L="&For %%n in (1 2)Do if %%n==2 (For %%G in (!$L!)Do (Set "%%~G" > Nul &Set /A "#$L+=1"))Else Set $L="
Set "Div=---------------------------------------------------------------------------------------------"
Set "MENU=Echo/!Div!&(For /F "Tokens=1,2 Delims==[" %%X in ('Set $V') Do Set /A "CNT=!#%%~X!" & Set "Array=%%~Y") & Set "Choices=" & (For %%A in (!ARRAY!)Do For /L %%U in (1 1 !CNT!)Do Set "Choices=!Choices!%%U"&For %%S in ("!%%~A[%%U]!")Do Echo/%%~A[%%U] %%~S !%%~S!)&Echo/[E]xit&Echo/!Div!"
rem // ACTION/E Macro to utilise the value of an Array Element
Set "ACTION/E=For /F "Delims=" %%I in ('Choice /N /C:!Choices!E')Do IF "%%I"=="E" (Endlocal&Endlocal&Goto :Eof)Else For %%A in ("!Array![%%I]")Do $M !%%~A!"
rem // ACTION/S Macro to utilise a value assigned to the value of an Array Element (Sub value)
Set "ACTION/S=For /F "Delims=" %%I in ('Choice /N /C:!Choices!E')Do IF "%%I"=="E" (Endlocal&Endlocal&Goto :Eof)Else For %%A in ("!Array![%%I]")Do For %%O in ("!%%~A!")Do $M !%%~O!"
Setlocal EnableExtensions EnableDelayedExpansion
rem // Define associated variables between recipients and servers to enable Access to the values from indexed variables
%List/D/V:$L=Users%"recipient[1]=Person 1" "recipient[2]=Person 2" "recipient[3]=Person 3" "recipient[4]=Person 4"
%List/D/V:$L=Servers%"Person 1=/server:ECRCL" "Person 2=/server:ECRCB" "Person 3=/server:ECRCCI" "Person 4=/server:ECRCCO"
:Loop
CLS
%MENU:$V=Users%
rem // examples of different command usage for ACTION macros. $M is substituted with the required command/s to executed on the value retrieved from the array
rem ::: %ACTION/E:$M=Echo/%
Set "Input="&Set /P "input=Enter Message: "
rem ::: if not "!input!"=="" ((If /I "!input!"=="E" (Exit /B 0)Else Echo/Select Recipient & %ACTION/S:$M=Echo/!Msg!% !input! 2> Nul) || Echo/!Msg! not installed)Else Echo/Input required
if not "!input!"=="" ((If /I "!input!"=="E" (Exit /B 0)Else Echo/Select Recipient & %ACTION/S:$M=!Msg!% !input! 2> Nul) || Echo/!Msg! not installed)Else Echo/Input required
Pause
Goto :Loop
The above has been modified to make the macro's more Generic for different Menu usages. The $M substring of the ACTION macros is substituted with the command to be executed on the value returned through choice selection for the selected index