The system cannot find the path specified - batch to exe - batch-file

Question

Good morning. I have written a batch file that updates the group policy via the audit.csv file. Previously I was changing the policy via auditpol but those changes didn't persist so I came up with this solution.
:: Write the correct audit settings to audit.csv
set "auditFile="C:\Windows\System32\GroupPolicy\Machine\Microsoft\Windows NT\Audit\audit.csv""
echo Machine Name,Policy Target,Subcategory,Subcategory GUID,Inclusion Setting,Exclusion Setting,Setting Value > %auditFile%
echo ,System,Audit Credential Validation,{0cce923f-69ae-11d9-bed3-505054503030},Success and Failure,,3 >> %auditFile%
…
It does some other stuff, but that's where I'm getting the error.
Yesterday, running this just as a regular batch script file worked fine. Now I'm getting the The system cannot find the path specified. error. I have seen a few posts with the same problem and the solution was to run cmd /c file.bat which isn't working for me right now. When creating the post, I wasn't expecting to have this problem running the batch file. When I tested yesterday, the batch file worked fine, but when I converted to an exe (both with PowerArchiver and iexpress) is when I got the error. So I don't know why it's not working in the .bat version, but I guess if I can fix this it should fix the converted exe.
My main question is why am I getting that error? Is it because of the echo command? Is it giving me the error because of the file I'm trying to access? Is it a permissions thing?

Answer 1

The batch file is executed by 64-bit cmd.exe stored in %SystemRoot%\System32 on double clicking on the batch file with Windows File Explorer. The directory %SystemRoot%\System32\GroupPolicy\Machine\Microsoft\Windows NT\Audit exists most likely in this case (not on my Windows computers).
But after packing the batch file into a 32-bit executable file which extracts it on execution into %TEMP% or a temporarily created subdirectory in %TEMP% and next runs Windows command processor for execution of the temporarily extracted batch file, the 32-bit cmd.exe stored in %SystemRoot%\SysWOW64 is executed because of Windows File System Redirector.
The file system redirector active in execution environment of x86 applications redirects the write access to file %SystemRoot%\System32\GroupPolicy\Machine\Microsoft\Windows NT\Audit\audit.csv now to %SystemRoot%\SysWOW64\GroupPolicy\Machine\Microsoft\Windows NT\Audit\audit.csv and most likely the entire directory tree for file audit.csv does not exist in this case.
A solution would be using this code:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem Define Windows system folder path and make sure the right path is used
rem if this batch file is executed on 64-bit Windows in 32-bit environment.
set "SystemFolder=%SystemRoot%\System32"
if not "%ProgramFiles(x86)%" == "" if exist %SystemRoot%\Sysnative\cmd.exe set "SystemFolder=%SystemRoot%\Sysnative"
set "AuditFilePath=%SystemFolder%\GroupPolicy\Machine\Microsoft\Windows NT\Audit"
rem Create the directory with suppressing the error message on missing
rem permissions to create this directory or on directory existing already.
md "%AuditFilePath%" 2>nul
if not exist "%AuditFilePath%\" (
echo ERROR: Failed to creeate the directory:
echo %SystemRoot%\System32\GroupPolicy\Machine\Microsoft\Windows NT\Audit
echo The batch file "%~nx0" must be run as administrator.
goto EndBatch
)
rem Write the correct audit settings to file audit.csv.
set "FullAuditFileName=%AuditFilePath%\audit.csv"
(
echo Machine Name,Policy Target,Subcategory,Subcategory GUID,Inclusion Setting,Exclusion Setting,Setting Value
echo ,System,Audit Credential Validation,{0cce923f-69ae-11d9-bed3-505054503030},Success and Failure,,3
) >"%FullAuditFileName%"
rem More commands to execute.
:EndBatch
endlocal
This batch file also creates the file audit.csv with the two CSV lines without a trailing space at end of both lines.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
call /? ... explains %~nx0 ... name + extension of batch file
echo /?
endlocal /?
goto /?
if /?
md /?
rem /?
set /?
setlocal /?
See also:
Microsoft documentation about WOW64 Implementation Details
Microsoft documentation about Using command redirection operators