Manage accented characters in string - batch-file

Question

I am trying to make a simple batch script to compare two files and open them if it found a difference.
So I use FC to compare the files; if no difference is found, it'll send me this text:
Comparaison des fichiers FILE1 et FILE2
FC : aucune différence trouvée
As you can see, it's in French, and it contains accented characters. That's my problem.
So here's my code so far:
#echo off
set "FILE1=file1path"
set "FILE2=file2path"
set "edit=editorpath"
for /F "tokens=*" %%F in ('fc /A /C /N "%FILE1%" "%FILE2%"') do (
set "DIFF=%%F"
)
set "NODIFF=FC : aucune différence trouvée"
if /I "%DIFF%"=="%NODIFF%" (
echo "no difference found"
) else (
start "" %edit% %FILE1%
start "" %edit% %FILE2%
)
The problem is in "%DIFF%==%NODIFF%: the two vars are always different, even when they should be the same (I've tried with or without "" for the set and the If comparison). To see this, I've tried to echo both var. Here's what I get:
echo %DIFF%
FC : aucune différence trouvée
echo %NODIFF%
FC : aucune diff├®rence trouv├®e
seems that the encoding is not the same. Most answer I've found for it was to use some chcp (with different values). If I understand it well, it's supposed to change the encoding so that accented characters "works". So i've tried to add
chcp 65001>nul
to my code, but then I got this result:
echo %DIFF%
FC[?]: aucune diff[?]rence trouv[?]e
echo %NODIFF%
FC : aucune différence trouvée
So now the second string is ok, but the first one no more. I've tried others numbers instead of 65001, but they would just make both strings wrong (and not in the same way).
ofc I can also do something like this:
chcp 850
echo %DIFF%
FC : aucune différence trouvée
chcp 65001
echo %NODIFF%
FC : aucune différence trouvée
But then in the IF statement, I can't have change the chcp while doing the comparison.
Have someone an idea on how to make it works?
PS: i'm using cmd and NOT POWERSHELL on windows10 64bits with MINGW.

Answer 1

If you really wanted to do what you intended, then just narrow your result to verifying just the known standard characters:
#Echo Off
Set "FILE1=file1path"
Set "FILE2=file2path"
Set "edit=editorpath"
For /F Delims^=^ EOL^= %%G In (
'""%__APPDIR__%fc.exe" /A /C /N "%FILE1%" "%FILE2%""') Do Set "DIFF=%%G"
If /I Not "%DIFF%"=="%DIFF: aucune diff=%" (Echo no difference found) Else (
Start "" "%edit%" "%FILE1%"
Start "" "%edit%" "%FILE2%")
Exit /B
Essentially you're case insensitively comparing two strings, the second with the substring aucune diff removed. If they're not the same, then the substring was part of the string. Please note that as English versions would use FC: no differences encountered, your current idea is still language/locale dependent.
However, in my opinion, there's no need for a for-loop or to jump through hoops with language/locale dependent strings. You can simply use the returned exit code, (ErrorLevel):
2 Could not open at least one of the files.
1 Differences found.
0 No differences encountered.
-1 Invalid syntax used.
#Echo Off
Set "FILE1=fileone.cmd"
Set "FILE2=filetwo.cmd"
Set "FILE3=filethree.cmd"
"%__AppDir__%fc.exe" /A /C /N "%FILE1%" "%FILE2%" >NUL 2>&1
If %ERRORLEVEL% Equ 2 (Echo Could not open at least one of the files.
) Else If %ERRORLEVEL% Equ 1 (Start "" "%edit%" "%FILE1%"
Start "" "%edit%" "%FILE2%") Else If %ERRORLEVEL% Equ 0 (
Echo No differences encountered.) Else Echo Invalid syntax used.
Pause
GoTo :EOF
Although for your purposes, you could simply use && and || to conditionally determine if the previous command was successful or not:
#Echo Off
Set "FILE1=file1path"
Set "FILE2=file2path"
Set "edit=editorpath"
%__APPDIR__%fc.exe /A /C /N "%FILE1%" "%FILE2%" >NUL 2>&1 && (
Echo no difference found) || (Start "" "%edit%" "%FILE1%"
Start "" "%edit%" "%FILE2%")
Exit /B