Batch file: Run specific part on particular OS - batch-file

Question

I'm trying to create a script with the purpose of creating a scheduled task on either a W2K3 or W2K12 server (more to be added later on) depending on the target server. I won't create separate scripts for each server type as this is already a part of a bundle of installation scripts that need to be distributed via a single package.
There are different users for the servers.
I have tried the following, but both jobs are created on each server type, with the one being redundant as it does not fit. I only want one scheduled task to be created dependent on the server type.
I'm a bit blind for the moment on how to solve it, also it would be great to avoid using "goto". I would appreciate your take on it.
setlocal
set runlevel=
for /f "tokens=2*" %%i in ('reg.exe query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "CurrentVersion"') do set os_ver=%%j
if /i "%os_ver:~,1%" EQU "5.2" (
set runlevel=/rl HIGHEST goto W2K3
exit
)
else
(
if /i "%os_ver:~,1%" GEQ "6.2" (
set runlevel=/rl HIGHEST goto W2K12
exit
)
)
:W2K3
schtasks.exe /create /tn "Files Handler W2K3" /sc DAILY /TR "D:\TMP_DONT_DELETE\Files_Handler.bat" /ST 05:30 /ru User1 /rp epicfun %runlevel%
:w2K12
schtasks.exe /create /tn "Files Handler W2K12" /sc DAILY /TR "D:\TMP_DONT_DELETE\Files_Handler.bat" /ST 05:30 /ru User2 /rp newkidontheblock %runlevel%

Answer 1

Here's an idea using wmic instead of the registry, to get your required version number. This additionally filters the results to only those with a product type of 3, (Server).
#SetLocal EnableExtensions
#Set "strVer="
#For /F "EOL=V Tokens=1-2 Delims=." %%G In (
'%__AppDir__%wbem\WMIC.exe OS Where "ProductType='3'" Get Version'
) Do #Set /A "strVer=%%G%%H" 2>NUL
#If Not Defined strVer GoTo :EOF
#If %strVer% Equ 52 (%__AppDir__%schtasks.exe /Create /RU User1 /RP epicfun^
/SC DAILY /TN "Files Handler W2K3" /TR "D:\TMP_DONT_DELETE\Files_Handler.bat"^
/ST 05:30) Else If %strver% Equ 62 %__AppDir__%schtasks.exe /Create /RU User2^
/RP newkidontheblock /SC DAILY /TN "Files Handler W2K12"^
/TR "D:\TMP_DONT_DELETE\Files_Handler.bat" /ST 05:30 /RL HIGHEST
I have removed the /RL option from the Windows 2003 SchTasks command because Microsoft says it isn't available in that OS, feel free to put it back in, if you don't believe them.

Answer 2

Put an goto :EOF statement after the :W2K3 schtasks.exe statement and remove %runlevel% because it's not supported as noted in Compo's answer:
...
:W2K3
schtasks.exe /create /tn "Files Handler W2K3" /sc DAILY /TR "D:\TMP_DONT_DELETE\Files_Handler.bat" /ST 05:30 /ru User1 /rp epicfun
goto :EOF
...