Command line - "x was unexpected at this time" - batch-file

Question

I was creating something with command line and came across this error - 'x was unexpected at this time', I tried switching the variable to x, %%x and %x% but none of them worked. Here are the code in the part:
echo Please enter the memory value [Recommended: 512M Xms 1024M Xmx]
set /p rams=Xms[MB]=
set /p ramx=Xmx[MB]=
echo %rams%|findstr /R "^[1-9][0-9]*$">nul
if NOT %errorlevel% EQU 0 (
echo Error: Please enter a valid number [Xms].
)
echo %ramx%|findstr /R "^[1-9][0-9]*$">nul
if NOT %errorlevel% EQU 0 (
echo Error: Please enter a valid number [Xmx].
)
if NOT %errorlevel% EQU 0 (
echo Execution failure: Invalid args
pause
goto start
)
set count=0
for %x in (*.jar) do set /a count+=1
if %count% == 1 (
java -Xms%rams%M -Xmx%ramx%M -jar BCU.jar
echo BCU.jar was executed.
pause
goto start
)
if %count% GEQ 1 (
echo [= = = = Multiple file found = = = =]
dir *.jar /B
echo [= = = = = = = = = = = = = = = = = =]
echo Please input file by the whole name with extension.
set /p file=Select File:
if exist %file% (
java -Xms%rams%M -Xmx%ramx%M -jar %file%
echo %file% was executed.
pause
) else (
echo File was not found.
pause
)
goto start
)
For some reason, the for command works normally when I execute it from the command prompt, but not when it was ran.
I ran the program as administrator
Only the for part is faulty, anything above it works normal
It is expected to have the count value defined and able to be used for the IF statement below
It is known that the java line works just fine without problem
For the full file it is located at: https://drive.google.com/file/d/1SgdoyCL5qaZGIWGJQDUKEJyEyUI2Y2u8/view?usp=sharing

Answer 1

Your immediate error is that you need to use %% within batch files, a single % works only on the command line. In other words, it should be:
for %%x in (*.jar) do set /a count+=1
(I'm not convinced you did try %%x as you state, since that actually works, but it may be that you just formatted it incorrectly).
But you'll strike another problem (at least) with using things like this (pared back and formatted for explanation):
if %count% GEQ 1 (
set /p file=Select File:
if exist %file% (
java -Xms%rams%M -Xmx%ramx%M -jar %file%
)
)
The entire block above is evaluated before it executes, meaning that %file% will be turned into whatever it was before the block started, despite the fact you're setting it within the block.
What you need to do is setlocal enabledelayedexpansion at the top of your file, and use the !file! delayed-expansion variant, something like:
setlocal enableextensions enabledelayedexpansion
:
if %count% GEQ 1 (
set /p file=Select File:
if exist !file%! (
java -Xms%rams%M -Xmx%ramx%M -jar !file!
)
)
:
endlocal
It's only needed for variables that can change within the loop, so not for the %rams% and %ramx% in this particular case - they're set before the if block starts.