How to display data in a datagrid - sql-server

Question

I have a class name cal.class. the function perform a loan calculation. it read the interest rate from a database and perform the calculation based on the amount input. I want to display the result in a data grid. for e.g InterestRate, MonthlyPayment, TotalPayment. I don't know how to do it.
Below is what I have I tried:
Cal.class
Public Shared Sub Calculator(ByVal _Source As String, ByVal _LoanAmount As Double, ByVal _LoanType As String,ByVal _Years As Double)
Dim myCommand As New SqlCommand
Dim SConn As String = ClsConnStr.GetConnString(_Source)
Using conn As New SqlConnection(SConn)
Dim MonthlyPayment As Double
Dim MonthlyInterestRate As Double
Dim TotalPayment As Double
conn.Open()
myCommand.Connection = conn
Dim daReader As SqlDataReader
Dim Sql As String = "Select Interestrate AS RESULT from tblloan where LoanType = '" & _LoanType & "'"
Dim scmd As New SqlCommand(Sql, conn)
daReader = scmd.ExecuteReader()
If daReader.HasRows Then
While daReader.Read()
MonthlyInterestRate = (daReader("RESULT")) / 1200
MonthlyPayment = _LoanAmount * MonthlyInterestRate / (1 - 1 / Math.Pow(1 + MonthlyInterestRate, _Years * 12))
TotalPayment = MonthlyPayment * _Years * 12
End While
End If
conn.Close()
End Using
End Sub
I call the method: cal.Calculator("TEST", "5000", "FS", "5")
and I have a data grid in my form.

Answer 1

Create a DataTable with the column headers and datatypes you need.
Include your command in the Using...End Using block. You can pass your connection string directly to the constructor of the connection. Also, you can pass the command text and the connection to the constructor of the command.
Add rows to the DataTable in the While loop
Public Shared Function Calculator(ByVal _Source As String, ByVal _LoanAmount As Double, ByVal _LoanType As String, ByVal _Years As Double) As DataTable
Dim dt As New DataTable
dt.Columns.Add("Monthly Interest Rate", GetType(Decimal))
dt.Columns.Add("Monthly Payment", GetType(Decimal))
dt.Columns.Add("Total Payment", GetType(Decimal))
Dim SConn As String = ClsConnStr.GetConnString(_Source)
Using conn As New SqlConnection(SConn),
myCommand As New SqlCommand("Select Interestrate AS RESULT from tblloan where LoanType = #LoanType", conn)
myCommand.Parameters.Add("#LoanType", SqlDbType.VarChar).Value = _LoanType
conn.Open()
Using daReader = myCommand.ExecuteReader
If daReader.HasRows Then
While daReader.Read()
Dim col1 = CDbl(daReader("RESULT")) / 1200
Dim col2 = _LoanAmount * col1 / (1 - 1 / Math.Pow(1 + col1, _Years * 12))
Dim col3 = col2 * _Years * 12
dt.Rows.Add({CDec(col1), CDec(col2), CDec(col3)})
End While
End If
End Using
End Using
Return dt
End Function
Your call parameters are wrong. You cannot pass a Double as a String (enclosed in quote)
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim dt = Calculator("TEST", 5000, "FS", 5)
'You will probably have to add formatting to the grid
DataGridView1.DataSource = dt
End Sub