How to make series with a given array? - arrays

Question

I am a VB.Net user. I would like to make an array as per below
Dim QRList() As Integer = {1, 2, 3, 4, 9, 12, 13, 14, 15, 16, 41, 42, 44, 48, 49, 50}
into a series as per below
1 - 4,
9 - 9,
12 - 16,
41 - 42,
44 - 44,
48 - 50,
I have tried the code below. But it doesn't work.
Dim QRList() As Integer = {1, 2, 3, 4, 9, 12, 13, 14, 15, 16, 41, 42, 44, 48, 49, 50}
Dim QRCount As Integer = QRList.Length
Dim startIndex, startN, endN As Integer
For i As Integer = 0 to QRCount - 1
startindex = 0
i = startindex
startN = QRList(i)
Do
If startindex = QRCount - 1 Then
endN = QRList(i)
ElseIf startindex < QRCount - 1 Then
If QRList(i + 1) - QRList(i) + 1 = 1 Then
endN = QRList(i + 1)
ElseIf QRList(i + 1) - QRList(i) + 1 > 1 Then
endN = QRList(i)
Exit For
End If
End If
startindex = i + 1
Console.Writeline(CStr(startN) & " - " & CStr(endN) & vbNewLine)
Loop While startindex < QRCount
Next
Hope anyone can help on this issue, Thanks.
Austin HO

Answer 1

This is a perfect candidate for the Yield statement to return an IEnumerable(Of String). You can pass that resulting IEnumerable(Of String) to String.Join() to obtain the final result.
Here's a quick example:
Sub Main()
Dim QRList() As Integer = {1, 2, 3, 4, 9, 12, 13, 14, 15, 16, 41, 42, 44, 48, 49, 50}
Dim series As String = String.Join("," & vbCrLf, GetSeries(QRList))
Console.WriteLine("Original: " & String.Join(", ", QRList))
Console.WriteLine("Series:")
Console.WriteLine(series)
Console.Write("Press Enter to quit...")
Console.ReadLine()
End Sub
Public Iterator Function GetSeries(ByVal values() As Integer) As IEnumerable(Of String)
Dim startNum, endNum As Integer?
For Each value As Integer In values
If Not startNum.HasValue Then
startNum = value
endNum = value
ElseIf value = (endNum + 1) Then
endNum = value
Else
Yield startNum & " - " & endNum
startNum = value
endNum = value
End If
Next
Yield startNum & " - " & endNum
End Function
Producing the following output:
Original: 1, 2, 3, 4, 9, 12, 13, 14, 15, 16, 41, 42, 44, 48, 49, 50
Series:
1 - 4,
9 - 9,
12 - 16,
41 - 42,
44 - 44,
48 - 50
Press Enter to quit...
Just to make it extra clear what is happening, you can convert the iterator to an array like this:
Dim arrSeries() As String = GetSeries(QRList).ToArray
For i As Integer = 0 To arrSeries.Length - 1
Console.WriteLine(i & ": " & arrSeries(i))
Next
Producing:
0: 1 - 4
1: 9 - 9
2: 12 - 16
3: 41 - 42
4: 44 - 44
5: 48 - 50
And, finally, if you need to work with the actual Integer start and stop values as a set, then simply convert the iterator function to return IEnumerable(Of Tuple(Of Integer, Integer)) instead, and use this Yield statement in the function in both places:
Yield New Tuple(Of Integer, Integer)(startNum, endNum)

Answer 2

Your loop fails at the first comparison: If QRList(i + 1) - QRList(i) + 1 = 1.
Since the condition is not met, the execution continues to the endN = QRList(i) assignment and exits the for loop entirely.
You can simplify this process a bit.
Since you need to generate sequences of contiguous numbers, you just need to determine the starting values - values in the original series that have a distance > 1 - and a variable to store the value of the previous iteration, used to perform the comparison.
Here, I'm using a List of named tuples (List(Of (StartValue As Integer, EndValue As Integer)) to store the values in the series.
You can use a List(Of String), or another type of collection, if that's preferable or named Tuples are not available
Dim QRList As Integer() = { 9, 12, 13, 14, 15, 16, 41, 42, 44, 48, 49, 50, 1, 2, 3, 4}
' Sort the array in case it's not already sorted
Array.Sort(QRList)
Dim maxDistance As Integer = 1
Dim seriesCount As Integer = -1
' Assign starting values that are less than ([Min Value] - [Max Distance])
Dim startValue As Integer = QRList(0) - (maxDistance + 1)
Dim previousValue As Integer = startValue
Dim series As New List(Of (StartValue As Integer, EndValue As Integer))()
For Each value As Integer In QRList
' The distance is less than or equal to the maximum: update the current item
If (value - maxDistance) <= previousValue Then
series(seriesCount) = (startValue, value)
Else
' The distance is > maxDistance: add a new starting item
startValue = value
series.Add((value, value))
seriesCount += 1
End If
previousValue = value
Next
To print the elements in the series:
For Each t In series
Console.WriteLine($"{t.StartValue} - {t.EndValue}")
Next
With maxDistance = 1, the series are:
1 - 4
9 - 9
12 - 16
41 - 42
44 - 44
48 - 50
With maxDistance = 4, the series are:
1 - 4
9 - 16
41 - 50