Can you link an array variable with a control? - arrays

Question

I am making a program with PictureBox controls. It would be easiest to manage the things I want to do with the PictureBox controls if they were in an array already.
This is what I have tried.
Sub drawtiles()
For x As Integer = 0 To 32 Step 1
For y As Integer = 0 To 24 Step 1
Dim tile As New PictureBox()
tile.Width = 20
tile.Height = 20
tile.Top = y * 20
tile.Left = x * 20
tile.BackColor = Color.CornflowerBlue
Dim r As Random = New Random
' Get random numbers between 1 and 3.
' ... The values 1 and 2 are possible.
Dim s As Integer = (r.Next(1, 3))
If s = 1 Then
tile.BackgroundImage = My.Resources.g1774
Else
tile.BackgroundImage = My.Resources.rect881
End If
tiles(x)(y) = tile
Controls.Add(tile)
Next
Next
End Sub
... with the array being made here
Public Class Form1
Public tiles As Array
So, how would I assign the Picturebox control, to the 3d array value?

Answer 1

You should almost never declare something as type Array. That is really only for when you want to be able to refer to an array of any type. That usually only happens with method parameters but, since the advent of generics, you can just write a generic method where the generic type parameter is the type of the array, e.g.
Private Sub ProcessArray(Of T)(array As T())
For i = 0 To array.GetUpperBound(0)
'Process element at index i here.
Next
End Sub
If you want an array of PictureBoxes then create a PictureBox array. Also, don't use a jagged array when you should be using a 2D array. This is a jagged array of PictureBoxes:
Private jaggedArrays As PictureBox()()
and this is a 2D array:
Private twoDimensionalArray As PictureBox(,)
The difference is that the second is a single object whereas the first is a 1D array containing multiple 1D arrays.
You should be creating the array like this:
Private tiles(32, 24) As PictureBox
And then populating it like this:
For i = 0 To tiles.GetUpperBound(0)
For j = 0 To tiles.GetUpperBound(1)
Dim tile As New PictureBox
'...
tiles(i, j) = tile
Next
Next

Answer 2

Never ever ever use Array as a type name in VB.Net. Instead, you would declare it like this:
Public tiles() As PictureBox
Or this:
Public tiles(32*24) As PictureBox
Or this (probably your best fit):
Public tiles(32, 24) As PictureBox
Or this:
Public tiles As New List(Of PictureBox)
Or skip the extra array altogether, put the controls inside a Panel or GroupBox container, and write code like this when you need to find them:
For Each tile As Picturebox in TilePanel.Controls.OfType(Of PictureBox)()
' ...
Next
Remember, with the move to the .Net ecosystem, VB now works so much better when things are strongly-typed. Option Strict really should be On, and you want very specific type names.