Proportion of the variables in each observation that satisfy certain conditions in SAS - arrays

Question

HAVE is a SAS data set with 1700 observations and ~1,000 variables. There are three "types" of variables beyond the id. They are denoted by different prefixes. Here is a subset of the file:
id a_dog b_dog c_dog a_cat b_cat c_cat a_mouse b_mouse c_mouse ...
prsn1 1 -1 -2 2 2 0 1 4 1
prsn2 -1 -3 4 2 2 -1 0 -1 -1
...
I need to calculate the proportion of values that are above, below, or equal to zero for each respondent, by the type of variable (i.e., (a_, b_, or c_). The solution should append these new variables to the file:
... prop_a_gt0 prop_a_lt0 prop_a_eq0 prop_b_gt0 prop_b_lt0 prop_b_eq0 prop_c_gt0 prop_c_lt0 prop_c_eq0
... 1.0000 0.0000 0.0000 0.6667 0.3333 0.0000 0.3333 0.3333 0.3333
... 0.3333 0.3333 0.3333 0.3333 0.6667 0.0000 0.3333 0.6667 0.0000
Note how prop_b_gt0, for example, is 0.6667 for prsn1 because two of the three b_ variables in the prsn1 row have values greater than 0.
I'm not sure how to accomplish this systematically. Perhaps there's a way to combine arrays with a proc sql step? Any solution welcome!

Answer 1

With an array you will need to loop through the array and count the number greater (and possibly count the number non-missing).
data want;
set have ;
array a a_: ;
numerator=0;
denominator=0;
do index=1 to dim(a);
numerator=sum(numerator,a[index]>0);
denominator=sum(denominator,not missing(a[index]));
end;
prob_a_gt0=numerator/denominator;
drop index numerator denominator;
run;
Just replicate the block of code for the B and C variables also.

Answer 2

For the case of more than three arrays (grouped by variable name suffix A, B, C) a macro will help ensure there are no typos or stray edits that can happen during copy and paste (code replication).
Suppose a macro compute_proportions emits code that loops over a variable array defined in a DATA Step. The code generator counts each conditional states met by criteria during the loop and calculates the proportion after looping.
* simulate data;
data have;
array a a_1-a_300; * for simplicity, presume 1 to 300 correspond to dog, cat, mouse, ...;
array b b_1-b_300;
array c c_1-c_300;
call streaminit(123);
do id = 1 to 10;
do _n_ = 1 to dim(a);
a (_n_) = ceil(rand('uniform', 9)) - 5;
b (_n_) = ceil(rand('uniform', 9)) - 5;
c (_n_) = ceil(rand('uniform', 9)) - 5;
end;
output;
end;
run;
%macro compute_proportions(array=, prefix=);
_lt = 0; %* <0 count;
_eq = 0; %* =0 count;
_gt = 0; %* >0 count;
_n = 0;
do _index = 1 to dim(&array);
_v = &array(_n_);
if not missing(_v) then do;
_lt + _v < 0;
_eq + _v = 0;
_gt + _v > 0;
_n + 1;
end;
end;
if _n > 0 then do;
&prefix.prop_lt0 = _lt / _n;
&prefix.prop_eq0 = _eq / _n;
&prefix.prop_gt0 = _gt / _n;
end;
drop _lt _eq _gt _index _v _n;
%mend;
data want;
set have;
array a a_:; * all variables whose names start with a_ can be array referenced during step;
array b b_:;
array c c_:;
%compute_proportions (array=a, prefix=a_)
%compute_proportions (array=b, prefix=b_)
%compute_proportions (array=c, prefix=c_)
run;