Batch file Scipt Executing all instructions in one go in if statement - batch-file

Question

Im new to batch script and trying to create a script which is going to help me setup a long manual process in a go. i have used if else statement in the batch script but all instructions are executed in one go i have only given 1 as input. code is mentioned below.
call echo 1. Clone a branch from bitbucket
call echo 2. Specify the Absolute path of project
set /P choice=" Enter your Choice : "
if %choice%==1 (
call set /P fo="enter folder name: "
call cd %USERPROFILE%\Desktop\ProjectFolder\%fo%
echo Clone will be created in the following address
call cd
call set /P gitUserName="Enter bitbucket UserName : "
call set /P branch=" Enter Branch Name : "
call echo Git User : %gitUserName%
call echo Branch Name : %branch%
call git clone https://%gitUserName%#bitbucket.org/MyProject/Project-demo.git -b %branch%
call cd Project-demo
) else (
call set /P pathname = "Enter Absolute path of Project-demo : "
cd %pathname%
)
im running it on windows 10. tried disabling #echo off for debugging purposes and found that all instructions are getting executed and at last {call set /P fo="enter folder name: " } <-- this line is executed.
i want it to create a folder and git clone one of my project here. Any Help greatly appreciated.
Also do tell me is call necessary wherever i used it.

Answer 1

The problem you are having has to do with delayed expansion. Everything inside of your parens is processed at once so you can't really do what you are trying to do without more complication. This has to do with Delayed Expansion .
You have two choices.. you can either:
enable EnableDelayedExpansion flag and use "!" instead of "%" within your blocks..
OR
Use "call" properly.. unlike your current use. Call is for calling a label within a batch file.. sort of like a function. If you use goto :EOF at the end of that label.. it will return to the caller like a function in a real programming language.
BTW.. call can also be used to call another batch file but we won't talk about that right now. One bit at a time..
I will show you the call method (which I prefer and other people hate). The call method was the only way to do this before the EnableDelayedExpansion keyword was added.
:)
`
#echo off
:START
cls
echo 1. Clone a branch from bitbucket
echo 2. Specify the Absolute path of project
set /P choice=" Enter your Choice : "
:: If they didn't pick a valid option, show the question again...
if not "%choice%"=="1" if not "%choice%"=="2" goto :START
:: Otherwise, take them down the right path
if "%choice%"=="1" call :DoBitBucketClone
if "%choice%"=="2" call :DoAbsolutePath
:: goto :EOF here will simply exit the script
goto :EOF
:DoBitBucketClone
set /P fo="enter folder name: "
cd %USERPROFILE%\Desktop\ProjectFolder\%fo%
echo Clone will be created in the following address
cd
set /P gitUserName="Enter bitbucket UserName : "
set /P branch=" Enter Branch Name : "
echo Git User : %gitUserName%
echo Branch Name : %branch%
git clone https://%gitUserName%#bitbucket.org/MyProject/Project-demo.git -b %branch%
cd Project-demo
:: we 'could' just exit here but I am trying to
:: show you how the return works..
goto :EOF
:DoAbsolutePath
set /P pathname="Enter Absolute path of Project-demo : "
echo "Path set to %pathname%"
cd /d %pathname%
:: we 'could' just exit here but I am trying to
:: show you how the return works..
goto :EOF
`

Answer 2

When you remove #ECHO OFF it will show you the entire if statement, not just the part that you are running. That's just a limitation of batch scripting.
Also, you are attempting to use variables in the if statement that are also set inside the if statement. Due to the way that parsing and substitution is done, you need to either use Delayed Expansion (using !) or create a subroutine
Some other changes I made are:
Check that the target directory exists. If not, make it.
Explicitly check else case for 2 and add an error case for anything other than 1 or 2.
Wrap paths in quotes
Removed unnecessay usage of call
Added error check for git clone failure
The following illustrates a way you can do it with delayed expansion:
#ECHO OFF
SETLOCAL EnableDelayedExpansion
echo 1. Clone a branch from bitbucket
echo 2. Specify the Absolute path of project
set /P choice=" Enter your Choice : "
if %choice%==1 (
set /P fo="enter folder name: "
SET "DEST=!USERPROFILE!\Desktop\ProjectFolder\!fo!"
IF NOT EXIST "!DEST!" mkdir "!DEST!"
cd "!DEST!"
echo Clone will be created in the following address
echo !DEST!
set /P gitUserName="Enter bitbucket UserName : "
set /P branch=" Enter Branch Name : "
echo Git User : !gitUserName!
echo Branch Name : !branch!
git clone https://!gitUserName!#bitbucket.org/MyProject/Project-demo.git -b !branch!
if errorlevel 1 EXIT /B 1
cd Project-demo
) else if %choice%==2 (
set /P pathname = "Enter Absolute path of Project-demo : "
cd !pathname!
) else (
ECHO:
ECHO ERROR: Unexpected choice '%choice%'
ECHO:
)
(ENDLOCAL
EXIT /B 0)