Retrieve PC Model from BIOS information - batch-file

Question

I'm writing a batch-file to update the BIOS on the PCs within my organization using the HP Bios Configuration Utility and I need a it to check a registry value in order to apply the appropriate configuration.
I found this code on the internet but can't get it to work:
#echo off
ECHO BIOS check HP
CD c:\Batch\bios\HP
reg query "HKEY_LOCAL_MACHINE\Hardware\Description\system\BIOS" /v "SystemProductName" | find /i "HP ProDesk 600 G3 PCI MT"
if errorlevel 0 (
echo HP ProDesk 600 G3 PCI MT
goto :end
)
reg query "HKEY_LOCAL_MACHINE\Hardware\Description\system\BIOS" /v "SystemProductName" | find /i "HP EliteDesk 800 G1 TWR"
if errorlevel 0 (
echo HP EliteDesk 800 G1 TWR
goto :end
)
:end
PAUSE
The error level doesn't work but it does look for the value.
This is what I'm using currently but systeminfo is taking too long to load on some PCs with a lot of hotfixes:
systeminfo > C:\Temp\Sysinf%t%.txt
CD c:\Batch\bios\HP
find "System Model: HP ProDesk 600 G3 PCI MT" C:\Temp\Sysinf%t%.txt
if %errorlevel%==0 goto :Leg_HP_ProDesk_600_G3_PCI_MT
find "System Manufacturer: HP EliteDesk 800 G1 TWR" C:\Temp\Sysinf%t%.txt
if %errorlevel%==0 goto :Leg_HP_EliteDesk_800_G1_TWR
:Leg_HP_ProDesk_600_G3_PCI_MT
BiosConfigUtility64.exe /setconfig:Leg_HP_ProDesk_600_G3_PCI_MT.txt /cspwdfile:"currentpassword.bin"
goto :Setpass
:Leg_HP_EliteDesk_800_G1_TWR
BiosConfigUtility64.exe /setconfig:Leg_HP_EliteDesk_800_G1_TWR.txt /cspwdfile:"currentpassword.bin"
goto :Setpass
:Setpass
BIOSConfigUtility64.exe /nspwdfile:"newpassword.bin" /cspwdfile:"currentpassword.bin"

Answer 1

I would expect something like this to work reasonably well, as long as BiosConfigUtility64.exe the .txt and .bin files are in C:\Batch\bios\HP:
#Set "SPN="&For /F "Tokens=2*" %%A In ('^""%__AppDir__%reg.exe" Query ^
"HKLM\Hardware\Description\system\BIOS" /V "SystemProductName" 2^>NUL^|^
"%__AppDir__%findstr.exe" /IC:"HP ProDesk 600 G3 PCI MT" /C:"HP EliteDesk 800 G1 TWR"^"'
)Do #Set "SPN=%%B"
#If Not Defined SPN Exit /B
#CD /D "C:\Batch\bios\HP" 2>NUL||Exit /B
#"BIOSConfigUtility64.exe" /SetConfig:"Leg_%SPN: =_%.txt" /cspwdfile:"currentpassword.bin"
#"BIOSConfigUtility64.exe" /nspwdfile:"newpassword.bin" /cspwdfile:"currentpassword.bin"
If you create all of your text files using the same naming format, (the returned name with spaces replaced with underscores and prefixed with Leg_), you could forget about the using findstr, just save the value and then check for an existing, matching .txt file:
#CD /D "C:\Batch\bios\HP" 2>NUL||Exit /B
#For /F "Tokens=2*" %%A In ('^""%__AppDir__%reg.exe" Query ^
"HKLM\Hardware\Description\system\BIOS" /V "SystemProductName" 2^>NUL^"')Do #Set "SPN=%%B"
#If Not Exist "Leg_%SPN: =_%.txt" Exit /B
#"BIOSConfigUtility64.exe" /SetConfig:"Leg_%SPN: =_%.txt" /cspwdfile:"currentpassword.bin"
#"BIOSConfigUtility64.exe" /nspwdfile:"newpassword.bin" /cspwdfile:"currentpassword.bin"