STM32F7: hard fault when jumping to application from custom bootloader - c

Question

I'm working on a Nucleo-F767zi board (stm32F767ZIT6U MCU) with custom bootloader and application in Atollic TrueSTUDIO. I have working bootloader and application. I have started both separately without errors. But when I try to run application from bootloader I have hard_fault in application. Image of application is correct (address, size and check code of image are valid) before I jump. I would appreciate for any idea of what I should pay attention and remake.
part of bootloader code:
int boot_main(void)
{
// Reset of all peripherals, Initializes the Flash interface and the Systick.
HAL_Init();
// Configure the system clock
SystemClock_Config();
// bootloader
if (isBootFlag() || checkMainAppWithSign()) {
//HAL_DeInit();
startMainApp();
}
// Initialize all configured peripherals
MX_GPIO_Init();
MX_ETH_Init();
MX_USART3_UART_Init();
MX_USB_DEVICE_Init();
createTask(&sysTaskControlBlock, threadTaskSystem, NULL, tskIDLE_PRIORITY + 3, bufferTaskSystem, sizemas(bufferTaskSystem), "SystemTask");
// Start scheduler */
osKernelStart();
// We should never get here as control is now taken by the scheduler
// Infinite loop
while (1) {
}
}
void startMainApp(void)
{
uint32_t mainAppAddr;
mainAppAddr = (uint32_t)Flash_Get_Starting_Address(FLASH_SPACE_APPLICATION);
__disable_irq();
typedef void(*pMainApp)(void);
pMainApp mainApplication;
mainApplication = (pMainApp)(mainAppAddr + 4);
__set_MSP(*(uint32_t*)mainAppAddr);
SCB->VTOR = mainAppAddr;
mainApplication();
}
bootloader linker script:
/* Entry Point */
ENTRY(Boot_Reset_Handler)
/* Highest address of the user mode stack */
_estack = 0x20080000; /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0; /* required amount of heap */
_Min_Stack_Size = 0x400; /* required amount of stack */
/* Specify the memory areas */
MEMORY
{
/* Single bank mode */
FLASH_LOADER(rx) : ORIGIN = 0x08000000, LENGTH = 96K /* 32K * 3 sectors*/
FLASH_SIGN(rx) : ORIGIN = 0x08000000 + 96K, LENGTH = 32K /* 32K * 1 sector*/
FLASH_USER_DATA(rx) : ORIGIN = 0x08000000 + 96K + 32K, LENGTH = 128K /* 128K * 1 sector*/
FLASH_MAIN_APP(rx) : ORIGIN = 0x08000000 + 128K + 128K, LENGTH = 512K /* 256K * 2 sector*/
DTCMRAM (xrw) : ORIGIN = 0x20000000, LENGTH = 128K
SRAM1 (xrw) : ORIGIN = 0x20020000, LENGTH = 368K - 32
SRAM1_FLAG (xrw): ORIGIN = 0x20020000 + 368K - 32, LENGTH = 32
SRAM2 (xrw) : ORIGIN = 0x2007C000, LENGTH = 16K
MEMORY_B1 (rx) : ORIGIN = 0x60000000, LENGTH = 0K
}
REGION_ALIAS("FLASH", FLASH_LOADER)
__flash_sign__ = ORIGIN(FLASH_SIGN);
__flash_sign_end__ = __flash_user_data__ + LENGTH(FLASH_SIGN);
__flash_user_data__ = ORIGIN(FLASH_USER_DATA);
__flash_user_data_end__ = __flash_user_data__ + LENGTH(FLASH_USER_DATA);
__flash_main_app__ = ORIGIN(FLASH_MAIN_APP);
__flash_main_app_end__ = __flash_main_app__ + LENGTH(FLASH_MAIN_APP);
__ram_bootflag__ = ORIGIN(SRAM1_FLAG);
/* Define output sections */
SECTIONS
{
/* The startup code goes first into FLASH */
.isr_vector :
{
. = ALIGN(4);
KEEP(*(.isr_vector)) /* Startup code */
. = ALIGN(4);
} >FLASH
/* The program code and other data goes into FLASH */
.text :
{
. = ALIGN(4);
*(.text) /* .text sections (code) */
*(.text*) /* .text* sections (code) */
*(.glue_7) /* glue arm to thumb code */
*(.glue_7t) /* glue thumb to arm code */
*(.eh_frame)
KEEP (*(.init))
KEEP (*(.fini))
. = ALIGN(4);
_etext = .; /* define a global symbols at end of code */
} >FLASH
/* Constant data goes into FLASH */
.rodata :
{
. = ALIGN(4);
*(.rodata) /* .rodata sections (constants, strings, etc.) */
*(.rodata*) /* .rodata* sections (constants, strings, etc.) */
. = ALIGN(4);
} >FLASH
.ARM.extab : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
.ARM : {
__exidx_start = .;
*(.ARM.exidx*)
__exidx_end = .;
} >FLASH
.preinit_array :
{
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP (*(.preinit_array*))
PROVIDE_HIDDEN (__preinit_array_end = .);
} >FLASH
.init_array :
{
PROVIDE_HIDDEN (__init_array_start = .);
KEEP (*(SORT(.init_array.*)))
KEEP (*(.init_array*))
PROVIDE_HIDDEN (__init_array_end = .);
} >FLASH
.fini_array :
{
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP (*(SORT(.fini_array.*)))
KEEP (*(.fini_array*))
PROVIDE_HIDDEN (__fini_array_end = .);
} >FLASH
/* used by the startup to initialize data */
_sidata = LOADADDR(.data);
/* Initialized data sections goes into RAM, load LMA copy after code */
.data :
{
. = ALIGN(4);
_sdata = .; /* create a global symbol at data start */
*(.data) /* .data sections */
*(.data*) /* .data* sections */
. = ALIGN(4);
_edata = .; /* define a global symbol at data end */
} >SRAM1 AT> FLASH
_sidtcmram = LOADADDR(.dtcmram);
/* DTCMRAM section
*
* IMPORTANT NOTE!
* If initialized variables will be placed in this section,
* the startup code needs to be modified to copy the init-values.
*/
.dtcmram :
{
. = ALIGN(4);
_sdtcmram = .; /* create a global symbol at dtcmram start */
*(.dtcmram)
*(.dtcmram*)
. = ALIGN(4);
_edtcmram = .; /* create a global symbol at dtcmram end */
} >DTCMRAM AT> FLASH
_sisram2 = LOADADDR(.sram2);
/* SRAM2 section
*
* IMPORTANT NOTE!
* If initialized variables will be placed in this section,
* the startup code needs to be modified to copy the init-values.
*/
.sram2 :
{
. = ALIGN(4);
_ssram2 = .; /* create a global symbol at sram2 start */
*(.sram2)
*(.sram2*)
. = ALIGN(4);
_esram2 = .; /* create a global symbol at sram2 end */
} >SRAM2 AT> FLASH
/* Uninitialized data section */
. = ALIGN(4);
.bss :
{
/* This is used by the startup in order to initialize the .bss secion */
_sbss = .; /* define a global symbol at bss start */
__bss_start__ = _sbss;
*(.bss)
*(.bss*)
*(COMMON)
. = ALIGN(4);
_ebss = .; /* define a global symbol at bss end */
__bss_end__ = _ebss;
} >SRAM1
/* User_heap_stack section, used to check that there is enough SRAM1 left */
._user_heap_stack :
{
. = ALIGN(4);
PROVIDE ( end = . );
PROVIDE ( _end = . );
. = . + _Min_Heap_Size;
. = . + _Min_Stack_Size;
. = ALIGN(4);
} >SRAM1
/* MEMORY_bank1 section, code must be located here explicitly */
/* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
.memory_b1_text :
{
*(.mb1text) /* .mb1text sections (code) */
*(.mb1text*) /* .mb1text* sections (code) */
*(.mb1rodata) /* read-only data (constants) */
*(.mb1rodata*)
} >MEMORY_B1
/* Remove information from the standard libraries */
/DISCARD/ :
{
libc.a ( * )
libm.a ( * )
libgcc.a ( * )
}
.ARM.attributes 0 : { *(.ARM.attributes) }
}
application linker script:
/* Entry Point */
ENTRY(Reset_Handler)
/* Highest address of the user mode stack */
_estack = 0x20080000; /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0; /* required amount of heap */
_Min_Stack_Size = 0x400; /* required amount of stack */
/* Specify the memory areas */
MEMORY
{
/* Single bank mode */
FLASH_LOADER(rx) : ORIGIN = 0x08000000, LENGTH = 96K /* 32K * 3 sectors*/
FLASH_SIGN(rx) : ORIGIN = 0x08000000 + 96K, LENGTH = 32K /* 32K * 1 sector*/
FLASH_USER_DATA(rx) : ORIGIN = 0x08000000 + 96K + 32K, LENGTH = 128K /* 128K * 1 sector*/
FLASH_MAIN_APP(rx) : ORIGIN = 0x08000000 + 128K + 128K, LENGTH = 512K /* 256K * 2 sector*/
DTCMRAM (xrw) : ORIGIN = 0x20000000, LENGTH = 128K
SRAM1 (xrw) : ORIGIN = 0x20020000, LENGTH = 368K - 32
SRAM1_FLAG (xrw): ORIGIN = 0x20020000 + 368K - 32, LENGTH = 32
SRAM2 (xrw) : ORIGIN = 0x2007C000, LENGTH = 16K
MEMORY_B1 (rx) : ORIGIN = 0x60000000, LENGTH = 0K
}
REGION_ALIAS("FLASH", FLASH_MAIN_APP)
__flash_sign__ = ORIGIN(FLASH_SIGN);
__flash_sign_end__ = __flash_user_data__ + LENGTH(FLASH_SIGN);
__flash_user_data__ = ORIGIN(FLASH_USER_DATA);
__flash_user_data_end__ = __flash_user_data__ + LENGTH(FLASH_USER_DATA);
__flash_main_app__ = ORIGIN(FLASH_MAIN_APP);
__flash_main_app_end__ = __flash_main_app__ + LENGTH(FLASH_MAIN_APP);
__ram_bootflag__ = ORIGIN(SRAM1_FLAG);
/* Define output sections */
SECTIONS
{
/* The startup code goes first into FLASH */
.isr_vector :
{
. = ALIGN(4);
KEEP(*(.isr_vector)) /* Startup code */
. = ALIGN(4);
} >FLASH
/* The program code and other data goes into FLASH */
.text :
{
. = ALIGN(4);
*(.text) /* .text sections (code) */
*(.text*) /* .text* sections (code) */
*(.glue_7) /* glue arm to thumb code */
*(.glue_7t) /* glue thumb to arm code */
*(.eh_frame)
KEEP (*(.init))
KEEP (*(.fini))
. = ALIGN(4);
_etext = .; /* define a global symbols at end of code */
} >FLASH
/* Constant data goes into FLASH */
.rodata :
{
. = ALIGN(4);
*(.rodata) /* .rodata sections (constants, strings, etc.) */
*(.rodata*) /* .rodata* sections (constants, strings, etc.) */
. = ALIGN(4);
} >FLASH
.ARM.extab : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
.ARM : {
__exidx_start = .;
*(.ARM.exidx*)
__exidx_end = .;
} >FLASH
.preinit_array :
{
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP (*(.preinit_array*))
PROVIDE_HIDDEN (__preinit_array_end = .);
} >FLASH
.init_array :
{
PROVIDE_HIDDEN (__init_array_start = .);
KEEP (*(SORT(.init_array.*)))
KEEP (*(.init_array*))
PROVIDE_HIDDEN (__init_array_end = .);
} >FLASH
.fini_array :
{
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP (*(SORT(.fini_array.*)))
KEEP (*(.fini_array*))
PROVIDE_HIDDEN (__fini_array_end = .);
} >FLASH
/* used by the startup to initialize data */
_sidata = LOADADDR(.data);
/* Initialized data sections goes into RAM, load LMA copy after code */
.data :
{
. = ALIGN(4);
_sdata = .; /* create a global symbol at data start */
*(.data) /* .data sections */
*(.data*) /* .data* sections */
. = ALIGN(4);
_edata = .; /* define a global symbol at data end */
} >SRAM1 AT> FLASH
_sidtcmram = LOADADDR(.dtcmram);
/* DTCMRAM section
*
* IMPORTANT NOTE!
* If initialized variables will be placed in this section,
* the startup code needs to be modified to copy the init-values.
*/
.dtcmram :
{
. = ALIGN(4);
_sdtcmram = .; /* create a global symbol at dtcmram start */
*(.dtcmram)
*(.dtcmram*)
. = ALIGN(4);
_edtcmram = .; /* create a global symbol at dtcmram end */
} >DTCMRAM AT> FLASH
_sisram2 = LOADADDR(.sram2);
/* SRAM2 section
*
* IMPORTANT NOTE!
* If initialized variables will be placed in this section,
* the startup code needs to be modified to copy the init-values.
*/
.sram2 :
{
. = ALIGN(4);
_ssram2 = .; /* create a global symbol at sram2 start */
*(.sram2)
*(.sram2*)
. = ALIGN(4);
_esram2 = .; /* create a global symbol at sram2 end */
} >SRAM2 AT> FLASH
/* Uninitialized data section */
. = ALIGN(4);
.bss :
{
/* This is used by the startup in order to initialize the .bss secion */
_sbss = .; /* define a global symbol at bss start */
__bss_start__ = _sbss;
*(.bss)
*(.bss*)
*(COMMON)
. = ALIGN(4);
_ebss = .; /* define a global symbol at bss end */
__bss_end__ = _ebss;
} >SRAM1
/* User_heap_stack section, used to check that there is enough SRAM1 left */
._user_heap_stack :
{
. = ALIGN(4);
PROVIDE ( end = . );
PROVIDE ( _end = . );
. = . + _Min_Heap_Size;
. = . + _Min_Stack_Size;
. = ALIGN(4);
} >SRAM1
/* MEMORY_bank1 section, code must be located here explicitly */
/* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
.memory_b1_text :
{
*(.mb1text) /* .mb1text sections (code) */
*(.mb1text*) /* .mb1text* sections (code) */
*(.mb1rodata) /* read-only data (constants) */
*(.mb1rodata*)
} >MEMORY_B1
/* Remove information from the standard libraries */
/DISCARD/ :
{
libc.a ( * )
libm.a ( * )
libgcc.a ( * )
}
.ARM.attributes 0 : { *(.ARM.attributes) }
}

Answer 1

I found my error. Thanks to Fiddling Bits who gave me useful hint.
Working code for my application:
void startMainApp(void)
{
typedef void(*pMainApp)(void);
pMainApp mainApplication;
uint32_t mainAppAddr = (uint32_t)Flash_Get_Starting_Address(FLASH_SPACE_APPLICATION);
uint32_t mainAppStack = (uint32_t)*((uint32_t*)mainAppAddr);
mainApplication = (pMainApp)*(uint32_t*)(mainAppAddr + 4); // Corrected!!!
__disable_irq();
__set_MSP(mainAppStack);
SCB->VTOR = mainAppAddr;
__enable_irq();
mainApplication();
}