How to export many variables of a simulation result to csv? - arrays

Question

I'm trying to export my results from Dymola to excel through a csv file. But I have many results. How can I write them in an array??
I tried to create a for loop but I lack the knowledge on how to type the code.
if (time) <= 0 then
Modelica.Utilities.Files.removeFile("tube_0.02"+".csv");
Modelica.Utilities.Streams.print("temps," +
"delta_fr1,"+
"delta_fr2,"+
"delta_fr3,",
"tube_0.02"+".csv");
else
Modelica.Utilities.Streams.print(String(time) +
"," + String( my_code_tube1[1].delta_fr)+
"," + String( my_code_tube1[2].delta_fr)+
"," + String( my_code_tube1[3].delta_fr),
"tube_0.02"+".csv");
end if;
Instead of having to write delta_fr1, delta_fr2... and then my_code_tube1[1].delta_fr, my_code_tube1[2].delta_fr.... I need to create a for loop because I will have almost 1500 variable to export.

Answer 1

Trying to write the results to a csv file during simulation comes with some troubles in Modelica:
For which time steps do you want to write the result? Using the solver step size is not possible.
But we can define a periodic output using the sample() function
Calling print is quite expensive. You don't want to do that too many times while your simulation runs
The print function always adds a newline after every call. That requires us to write every line at once (but due to the performance limits mentioned before we should write as much text as possible at once anyhow).
Unfortunately, the default maximum string size of Dymola is quite small, limited on 500.
You have to ensure that the current Dymola instance is using an appropriate large value by setting e.g. Advanced.MaxStringLength = 50000.
With these things in mind, we could come up with a code like below:
model SO_print_for
My_code_tube my_code_tube1[1500];
protected
String line;
String f="tube_0.02" + ".csv";
model My_code_tube
Real delta_fr=1;
end My_code_tube;
initial algorithm
line := "temps";
for i in 1:size(my_code_tube1,1) loop
line := line + ", delta_fr" + String(i);
end for;
Modelica.Utilities.Files.removeFile(f);
Modelica.Utilities.Streams.print(line, f);
algorithm
when sample(0, 0.1) then
line := String(time);
for i in 1:size(my_code_tube1,1) loop
line := line + ", "+String(my_code_tube1[i].delta_fr);
end for;
Modelica.Utilities.Streams.print(line, f);
end when;
end SO_print_for;
The code works, but it will slow down your simulation, as many time events are generated (from the sample() function).
Instead of writing a csv during the simulation, you should consider one of the following ways to convert the result file after the simulation has finished:
Use Export Result in the Dymola variable browser to export all or only the plotted variables into csv. This must be done manually after every simulation and can not be scrippted
Use the function DataFiles.convertMATtoCSV. The following two lines of code will extract 1500 delta_fr variables from the .mat result file
vars = {"my_code_tube1["+String(i)+"].delta_fr" for i in 1:1500}
DataFiles.convertMATtoCSV("your-model.mat", vars, "out.csv")
Use Matlab, Octave or FreeMat to open the .mat result file and convert it to a file format which Excel understands.
Dymola provides dymload.m to import .mat result files into Matlab. See the User manual volume 1 of Dymola for details
Use python to convert the results to a csv file, e.g. by using the package DyMat or SDF-Python, which can both be used to read the result files