Extract correct creation date from avi file - file

Question

I am using Delphi 10 and Windows 10 Home Edition 64-bit. I have a video file called MVI_0640.AVI. The date shown in the File Explorer is 15/04/04 which corresponds to the Media Created Date in the Properties window.
I am using the following code to extract dates.
procedure TForm1.Button1Click(Sender: TObject);
var
ADate: TDateTime;
FlHandle: integer;
MyData: TWin32FindData;
FlTime: TFileTime;
MySysTime: TSystemTime;
begin
{get date using GetCreationTime}
ADate := TFile.GetCreationTime(FlName);
Memo1.Lines.Add('GetCreationTime ' + DateToStr(ADate));
{get date using FileGetDate}
FlHandle := FileOpen(FlName,fmOpenRead);
ADate := FileDateToDateTime(FileGetDate(FlHandle));
FileClose(FlHandle);
Memo1.Lines.Add('FileGetDate ' + DateToStr(ADate));
{get date using FindFirstFile}
FindFirstFile(PChar(FlName), MyData);
FlTime := MyData.ftCreationTime;
FileTimeToSystemTime(FlTime, MySysTime);
ADate := SystemTimeToDateTime(MySysTime);
Memo1.Lines.Add('ftCreationTime ' + DateToStr(ADate));
FlTime := MyData.ftLastAccessTime;
FileTimeToSystemTime(FlTime, MySysTime);
ADate := SystemTimeToDateTime(MySysTime);
Memo1.Lines.Add('ftLastAccessTime ' + DateToStr(ADate));
FlTime := MyData.ftLastWriteTime;
FileTimeToSystemTime(FlTime, MySysTime);
ADate := SystemTimeToDateTime(MySysTime);
Memo1.Lines.Add('ftLastWriteTime ' + DateToStr(ADate));
end;
The result looks like this:
None of the dates reflect the Media Created Date. How can I extract it?
In answer to Tom Brunberg’s comment I attach an extract of the file taken with a hex editor.

Answer 1

The date you are looking for is in a chunk called IDIT. It is referred to e.g. in this document
Structure is simple, (sample data from a file of mine):
chunk id: IDIT // 4 ASCII chars
chunk length: 0000001A // 26 bytes
chunk data: Sun Aug 31 12:15:22 2008/n/0 // date as ascii string
The structure of an AVI file is outlined by Microsoft, as follows, with addition of the location of IDIT chunk if present
RIFF ('AVI '
LIST ('hdrl'
'avih'(<Main AVI Header>)
LIST ('strl'
'strh'(<Stream header>)
'strf'(<Stream format>)
[ 'strd'(<Additional header data>) ]
[ 'strn'(<Stream name>) ]
...
)
... (note, if present, the IDIT chunk appears here)
)
LIST ('movi'
{SubChunk | LIST ('rec '
SubChunk1
SubChunk2
...
)
...
}
...
)
['idx1' (<AVI Index>) ]
)
The above mentioned document also outlines the various structures.
Sample data:
A function to get the date (if present in the file) could be as follows:
// Note! finetuned to search only the main TLIST 'hdrl'
function GetOriginalDate(AviFileName: TFileName; out s: string): boolean;
type
TChunkId = array[0..3] of AnsiChar;
TChunk = record
chid: TChunkId;
size: cardinal;
form: TChunkId;
end;
var
fs: TFileStream;
Root: TChunk;
Chnk: TChunk;
Done: boolean;
Date: ansistring;
endpos: integer;
begin
s := 'not found';
Done := False;
result := False;
fs:= TFileStream.Create(AviFileName, fmOpenRead or fmShareDenyWrite);
try
fs.Read(Root, SizeOf(Root));
if Root.chid <> 'RIFF' then exit;
if Root.form <> 'AVI ' then exit;
fs.Read(Chnk, SizeOf(TChunk)); // main LIST
if Chnk.chid <> 'LIST' then exit;
if Chnk.form <> 'hdrl' then exit;
endpos := fs.Position + Chnk.size;
repeat
fs.Read(Chnk, SizeOf(TChunk));
if Chnk.chid = 'IDIT' then
begin
fs.Seek(-4, TSeekOrigin.soCurrent);
SetLength(Date, Chnk.size);
fs.Read(Date[1], Length(Date));
s := Date;
Done := True;
end
else
fs.Seek(Chnk.size-4, TSeekOrigin.soCurrent);
until Done or (fs.Position > endpos);
finally
fs.Free;
end;
end;
To call it, for example:
procedure TForm1.Button2Click(Sender: TObject);
var
s: string;
begin
GetOriginalDate('F:\My Video\2008-08-31\MVI_1279.AVI', s);
Memo1.Lines.Add(s);
end;
And result in Memo1
Sun Aug 31 12:15:22 2008

Answer 2

I found an answer to my question. Probably not very elegant or save but it does it's job. I tested it on more than 100 files and it worked without a problem. Here is my answer:
function TForm1.GetAviMediaCreationDate(AFile: string): TDateTime;
var
FS: TFileStream;
NumOfChar: integer;
i,d: integer;
ABuffer: array of byte;
AStr: string;
DateStr: string;
sdp: integer; //start date position
dn,mn,yn: integer; //used to encode date
begin
sdp := 0;
FS := TFileStream.Create(AFile,fmOpenRead);
NumOfChar := 400;
SetLength(ABuffer,NumOfChar);
FS.Read(Pointer(ABuffer)^, NumOfChar);
{find IDIT}
for i := 0 to NumOfChar-1 do
begin
AStr := Char(ABuffer[i]) +
Char(ABuffer[i+1]) +
Char(ABuffer[i+2]) +
Char(ABuffer[i+3]);
if AStr = 'IDIT' then sdp := i+7;
end;
{extract date}
for d := 1 to 24 do
DateStr := DateStr + Char(ABuffer[sdp+d]);
{assemble TDateTime}
//123456789 123456789 123456789
//Sun Jun 28 10:13:39 2015
dn := StrToInt(Copy(DateStr,9,2));
mn := IndexText(Copy(DateStr,5,3),ShortMonthNames)+1;
yn := StrToInt(Copy(DateStr,21,4));
Result := EncodeDate(yn, mn, dn);
FS.Free;
end;
procedure TForm1.Button2Click(Sender: TObject);
var
ADate: TDateTime;
begin
ADate := GetAviMediaCreationDate(FlName);
Memo1.Lines.Add(DateToStr(ADate));
end;