How to set multiple Delims - batch-file

Question

I am working on writing a script that will create folders based on parts of file names. The problem is the Delim's are both the same. File names look like this: "Bacon-HunterBacon-00002" I am looking at using the first and second tokens to be the folder name. So the folder would be named Bacon-HunterBacon
#echo off
setlocal enabledelayedexpansion
for %%A in (*.cr2 *.jpg) do (
echo file found %%A
for /f "delims=" %%B in ("%%A") do set fname=%%~nB
for /f "delims=" %%C in ("%%A") do set fextn=%%~xC
for /f "tokens=1,2* delims=-" %%D in ("!fname!") do set folname=%%D
echo folder name !folname!
if not exist "!folname!" (
echo Folder !folname! does not exist, creating
md "!folname!"
) else (
echo Folder !folname! exists
)
echo Moving file %%A to folder !folname!
move "%%A" "!folname!"
)
echo Finished

Answer 1

In the loop for /f"tokens=1,2* delims=-" %%D in ..., the first token is assigned to %%D, the second one to %%E and the rest (*) to %%F (but which you do not use), so you should do set folname=%%D-%%E to get the desired folder name in variable folname:
#echo off
setlocal EnableDelayedExpansion
for %%A in ("*-*-*.cr2" "*-*-*.jpg") do (
echo file found %%A
for /f "tokens=1,2 delims=-" %%D in ("%%~nA") do set "folname=%%D-%%E"
echo folder name !folname!
if not exist "!folname!" (
echo Folder !folname! does not exist, creating
md "!folname!"
) else (
echo Folder !folname! exists
)
echo Moving file %%A to folder !folname!
move "%%~A" "!folname!"
)
endlocal
echo Finished
The loops for /f "delims=" %%B and for /f "delims=" %%C are useless, you could use %%~nA and %%~xA directly to get the values fname and fextn, respectively. But you do not need these interim variables at all, therefore I removed them.
And you should use the quoted set syntax like set "folname=%%D-%%E" in general.
I also changed the file masks to not match files that contain less than two hyphens (-).
Actually you do not even need the interim variable folname when you use the tokens %%D and %%E immediately. So you do no longer need delayed expansion any more:
#echo off
setlocal
for %%A in ("*-*-*.cr2" "*-*-*.jpg") do (
echo file found %%A
for /f "tokens=1,2 delims=-" %%D in ("%%~nA") do (
echo folder name %%D-%%E
if not exist "%%D-%%E" (
echo Folder %%D-%%E does not exist, creating
md "%%D-%%E"
) else (
echo Folder %%D-%%E exists
)
echo Moving file %%A to folder %%D-%%E
move "%%~A" "%%D-%%E"
)
)
endlocal
echo Finished