In Subversion, get full URL of branch for most recent change - batch-file

Question

Briefly - is there a simple svn command to tell us the "most recently changed branch"?
In more depth, as part of our build process, we're trying to detect the most recently-changed branch in Subversion, in order to perform further processing on that branch.
For example, if someone added the file:
http://server/svn/project/branches/Integration1/newfile.txt
we'd want to be able to determine the string:
http://server/svn/project/branches/Integration1
that is, the parent folder of the most recent change.
The closest we can find is to execute the following command:
svn log --verbose --limit 1 http://server/svn/project/
but it then gives a 4-line output that we'd need to parse, using batch.
We have a Jenkins build server with the Subversion plugin installed, which can detect the change to the overall subversion repository, but it only gives us the environment variables SVN_URL and SVN_REVISION, neither of which address our goal.

Answer 1

I would use:
svn log --verbose --quiet --limit 1 "http://server/svn/project/"
So you get rid of any commit log messages and have just a list of modified paths and a header. Then use a for /F loop loop to capture the paths:
rem // Capture output of `svn log`, skip header and hyphen-only lines:
for /F "skip=3 eol=- tokens=1*" %%I in ('
svn log --verbose --quiet --limit 1 "http://server/svn/project/"
') do echo(%%J
The tricky part is to derive the common root path of multiple items, which might be done like in the following script, for instance (see all the explanatory rem remarks in the code; provide the repository path http://server/svn/project/ as the first command line argument):
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set "_REPOPATH=%~1" & rem // (take the first argument as the repository path)
rem // Clear buffer for common root path:
set "COMM="
rem // Clear all variables beginning with `$`:
for /F "delims=" %%K in ('set $ 2^> nul') do set "%%K="
rem // Capture output of `svn log`, skip header and hyphen-only lines:
for /F "skip=3 eol=- tokens=1*" %%I in ('
svn log --verbose --quiet --limit 1 "%_REPOPATH%"
') do (
rem // Store currently iterated path:
set "ITEM=%%J"
rem // Check whether buffer for common root path is empty:
if not defined COMM (
rem // Buffer is empty, hence this is the first iteration:
set "COMM=%%J"
) else (
rem // Otherwise, store each `/`-separated path element in array `$ITEM[]`:
set /A "IDX=0"
setlocal EnableDelayedExpansion
for %%K in ("!ITEM:/=" "!") do (
for %%L in (!IDX!) do (
endlocal
set "$ITEM[%%L]=%%~K"
set /A "IDX+=1"
setlocal EnableDelayedExpansion
)
)
endlocal
rem // Store each element of buffered common root path in array `$COMM[]`:
set /A "CNT=IDX-1, IDX=0"
setlocal EnableDelayedExpansion
for %%K in ("!COMM:/=" "!") do (
for %%L in (!IDX!) do (
endlocal
set "$COMM[%%L]=%%~K"
set /A "IDX+=1"
setlocal EnableDelayedExpansion
)
)
rem // Determine the lower number of elements of `$ITEM[]` and `$COMM[]`:
if !CNT! geq !IDX! set /A "CNT=IDX-1"
rem // Loop through both arrays and write all common elements to buffer:
set "COMM=" & set "FLAG=#"
for /L %%L in (0,1,!CNT!) do (
if /I "!$ITEM[%%L]!" == "!$COMM[%%L]!" (
rem // The flag is just necessary to stop at the first difference:
if defined FLAG set "COMM=!COMM!!$COMM[%%L]!/"
) else set "FLAG="
)
rem // Transport the built common root path buffer beyond `endlocal`:
for /F "delims=" %%K in (""!COMM!"") do (
endlocal & set "COMM=%%~K"
)
)
)
setlocal EnableDelayedExpansion
if defined COMM (
rem // Check if there was only one path and just get get its parent in case:
if not "!COMM:~-1!" == "/" (
for %%K in ("!COMM:/=\!") do (
endlocal & set "COMM=%%~pK"
setlocal EnableDelayedExpansion
set "COMM=!COMM:\=/!"
)
)
rem // Return the finally retrieved common root path of all paths:
echo(!COMM:~1,-1!
)
endlocal
endlocal
exit /B

Answer 2

I don't know if that will work in your Jenkins environment, but here is what I would do in a standard (eg bash) shell. I use a terse svn log:
svn log ^/branches -l1 -q --incremental
Adding a pipe to parse it, the full command would be:
svn log ^/branches -l1 -q --incremental | sed -n "s/.*| \(.*\) |.*/\1/p"
Replace the caret (^) with http://server/svn/project/.
EDIT: to get the branch name, increase the verbosity of svn log with -v to print the modified paths, and adapt the sed command to extract the branch name. The following works for me:
svn log ^/branches -l1 -q -v | sed -n '4 s|.*/branches/||p'
or more aggressive:
svn log ^/branches -l1 -q -v | sed -nr '4 s|.*/branches/([^/]+).*|\1|p'