Accumulating data based on two criteria - arrays

Question

I am trying to write a VB.NET program that reads data from a file and does a count for each column as shown in the format below and also writes to an output file.
I am able to do the count but I am unable to write the output per restaurant and day.
From what I have, I can only write the total sum from the array index.
Here is the code I have so far:
Dim IntSubjectArray(23) As String
OpenFileDialog1.ShowDialog()
strInputPath = OpenFileDialog1.FileName
FileOpen(IntInputFileName, strInputPath, OpenMode.Input)
Do While Not EOF(IntInputFileName)
Dim StrReadLine As String = LineInput(IntInputFileName)
Dim StrSplitRecord() As String = Split(StrReadLine, ",")
IntRestaurant = StrSplitRecord(0)
IntDay = StrSplitRecord(1)
Meal1 = StrSplitRecord(2)
Meal2 = StrSplitRecord(3)
Meal3 = StrSplitRecord(4)
If SaveDay <> IntDay Then
IntMealArray(meal1) += 1
IntMealArray(meal2) += 1
IntMealArray(meal3) += 1
SaveDay = IntDay
SaveDay = 0
End If
savetown = IntExamTown
Loop
Call WriteOutputArray()
FileClose(IntInputFileName)
MessageBox.Show("File written to specified location")
Public Sub WriteOutputArray()
IntOutputFileName = FreeFile()
For Each Array As String In IntMealArray
FileOpen(IntOutputFileName, "C:\Users\ireport\foodCount.txt", OpenMode.Append)
WriteLine(IntOutputFileName, IntMealArray(Array))
FileClose(IntOutputFileName)
Next
End Sub
File format is
001,1,5,6,21
001,1,5,6,21
001,1,5,6,21
001,1,10,12,18
001,2,5,6,19
001,2,8,9,19
001,2,6,19,21
001,2,5,6,21
001,3,7,12,18
001,3,8,12,19
001,3,7,12,18
040,4,7,12,18
040,4,7,12,18
040,4,7,12,18
040,4,9,12,19
Key:
The format is 001 is restaurant 1, then day 1, then foods eaten by a particular customer (there are to 23 different kinds of food), with each kind of meal represented by a code 1 to 23 as in the file.
Expected output is count of food eaten in each resturant in each day by a customer e.g.:
Rest day Rice Beans Yam Meat Snack coke Burger Meal8 Meal9 Meal10 M11 M12
001 1 0 0 0 0 3 3 0 0 0 1 0 1
001 2 0 0 0 0 2 3 0 1 1 0 0 0
001 3 0 0 0 0 0 0 2 1 0 0 0 3
040 4 0 0 0 0 0 0 3 0 1 0 0 4

Answer 1

First you need to get your data into some format which will make it easier to see in the code which part is which. An easy way to do that is create a Class with properties which have meaningful names.
Then you can group the data by restaurant, and for each restaurant you can group the data for each date.
As the output is in columns of the widths of the names of the foods, you need to take those names into account when formatting the output.
For simplicity, I created a console app instead of a Windows Forms app. Also, I would split it up into more methods if I was doing this for more than a proof-of-concept.
Imports System.IO
Imports System.Text
Module Module1
Dim Foods As Dictionary(Of String, String)
Class Datum
Property Restaurant As String
Property Day As Integer
Property FoodCodes As List(Of String)
Public Overrides Function ToString() As String
' Useful for debugging.
Return $"{Restaurant} {Day} " & String.Join(",", FoodCodes)
End Function
End Class
Sub LoadFoods()
' Generate some food names. The first food name has a code of "1".
Foods = New Dictionary(Of String, String)
Dim names = {"Rice", "Beans", "Banana", "Meat", "Snacks", "Potato", "Spinach",
"Fish", "Aubergine", "Peas", "Egg", "Chicken", "Cheese", "Onion",
"Carrots", "Brocolli", "Asparagus", "Garlic", "Cabbage", "Coconut", "Yam",
"Naan", "Lentils"}
For i = 1 To names.Count
Foods.Add(i.ToString(), names(i - 1))
Next
End Sub
Sub Main()
LoadFoods()
Dim src = "C:\temp\FoodRecords.txt"
Dim dest = "C:\temp\meals.txt"
Dim data As New List(Of Datum)
For Each line In File.ReadLines(src)
Dim parts = line.Split({","c})
If parts.Count = 5 Then
Dim d As New Datum With {.Restaurant = parts(0),
.Day = Integer.Parse(parts(1)),
.FoodCodes = parts.Skip(2).OrderBy(Function(s) s).ToList()}
data.Add(d)
End If
Next
' Prepare information on the widths of the columns to be output...
Dim colWidths As New List(Of Integer)
colWidths.Add(-("Restaurant".Length))
colWidths.Add(-("Day".Length))
For Each food In Foods
colWidths.Add(food.Value.Length)
Next
' Group the data by restaurant...
Dim restaurantData = From d In data
Group By RestCode = d.Restaurant
Into RestData = Group
Using sw As New StreamWriter(dest)
sw.Write("Restaurant Day ")
sw.WriteLine(String.Join(" ", Foods.Select(Function(f) f.Value)))
For Each x In restaurantData
'Console.WriteLine(x.RestCode & " " & String.Join(",", x.RestData))
' Get each day of data for this restaurant
Dim restaurantDay = From y In x.RestData
Group By Day = y.Day
Into DayData = Group
For Each rd In restaurantDay
' Count the occurrences of food codes for this day...
Dim dayFoodCounts As New Dictionary(Of String, Integer)
For Each fd In rd.DayData
For Each fc In fd.FoodCodes
If dayFoodCounts.ContainsKey(fc) Then
dayFoodCounts(fc) += 1
Else
dayFoodCounts.Add(fc, 1)
End If
Next
Next
' Generate the first two columns
Dim sb As New StringBuilder()
Dim fmt = "{0," & colWidths(0) & "}"
sb.AppendFormat(fmt, x.RestCode)
sb.Append(" ")
fmt = "{0," & colWidths(1) & "}"
sb.AppendFormat(fmt, rd.Day)
sb.Append(" ")
' Generate the columns with food consumption counts
Dim n = 0
For Each kvp In Foods
If dayFoodCounts.ContainsKey(kvp.Key) Then
sb.Append(String.Format("{0," & colWidths(n + 2) & "}", dayFoodCounts(kvp.Key)) & " ")
Else
' no count for this food item, so fill it with spaces
sb.Append(New String(" "c, colWidths(n + 2) + 1))
End If
n += 1
Next
sw.WriteLine(sb.ToString())
Next
Next
End Using
Console.WriteLine("Done.")
Console.ReadLine()
End Sub
End Module
Given the sample data from the question, the above code generates a file with this content:
Restaurant Day Rice Beans Banana Meat Snacks Potato Spinach Fish Aubergine Peas Egg Chicken Cheese Onion Carrots Brocolli Asparagus Garlic Cabbage Coconut Yam Naan Lentils
001 1 3 3 1 1 1 3
001 2 2 3 1 1 3 2
001 3 2 1 3 2 1
040 4 3 1 4 3 1

Answer 2

(In my previous solution I had wrongly assumed that the numbers are counts and each column represents an article, which was not the case. Here my new solution.)
I would separate reading the file from writing the table. To be able to represent the content of the file easily, let's create a class to represent food.
Public Class Food
Public Property Restaurant As String
Public Property Day As Integer
Public Property ArticleNo As Integer
Public Property Quantity As Integer
End Class
The Quantity property is not strictly necessary, since it will always be 1. But it seems logical to have it in case the file format evolves in future.
Now we can read the file like this
Public Function ReadFoodFile(inputPath As String) As List(Of Food)
Dim foodList = New List(Of Food)
For Each line As String In File.ReadLines(inputPath)
Dim parts As String() = line.Split(",")
If parts.Length > 2 Then 'Make sure we don't try to read an empty line,
' e.g.at the end of the file.
Dim dayNo As Integer = CInt(parts(1))
For i = 2 To parts.Length - 1
Dim articleNo As Integer
If Int32.TryParse(parts(i), articleNo) AndAlso articleNo <> 0 Then
Dim food = New Food()
food.Restaurant = parts(0)
food.Day = dayNo
food.ArticleNo = articleNo
food.Quantity = 1
foodList.Add(food)
End If
Next
End If
Next
Return foodList
End Function
The function for reading the file has the input path as parameter and returns a list of food where each entry corresponds to one restaurant, one day and one food article.
This was the easy part. Writing the table is complicated as we must group by restaurants and days as well as by article for each row. Then we must be able to look up the article by its article number. We need a class representing an article:
Public Class Article
Public Property ArticleNo As Integer
Public Property Name As String
Public Sub New(articleNo As Integer, name As String)
Me.ArticleNo = articleNo
Me.Name = name
End Sub
Private Shared _allArticles = New Article() {
New Article(1, "Rice"), New Article(2, "Beans"), New Article(3, "Yam"), New Article(4, "Meat"),
New Article(5, "Snack"), New Article(6, "Coke"), New Article(7, "Burger"), New Article(8, "Meal8"),
New Article(9, "Meal9"), New Article(10, "Meal10"), New Article(11, "M11"), New Article(12, "M12"),
New Article(13, "M13"), New Article(14, "M14"), New Article(15, "M15"), New Article(16, "M16"),
New Article(17, "M17"), New Article(18, "M18"), New Article(19, "M19"), New Article(20, "M20"),
New Article(21, "M21"), New Article(22, "M22"), New Article(23, "M23")
}
Shared ReadOnly Property AllArticles() As Article()
Get
Return _allArticles
End Get
End Property
End Class
Besides article no. and name, it contains a shared property returning a list of articles. In a real-life application, the list of articles should probably be read from a file or a database instead of being hard-coded.
Now, we can formulate the Sub writing the table. It makes heavy use of LINQ and uses the new ValueTuple type available since VB/VS 2017.
Public Sub WriteFoodTable(outputPath As String, foods As IEnumerable(Of Food))
Const ColumnSize = 8
'Create an IEnumerable(Of (Restaurant As String,
' Day As Integer,
' Articles As Dictionary(Of Integer, Integer))
' )
' )
' where the dictionary stores article quantities using the article no. as key.
Dim groupedFood = From food In foods
Group By food.Restaurant, food.Day Into g1 = Group
Select (
Restaurant:=Restaurant, Day:=Day,
Articles:=
(From x In g1
Group By x.ArticleNo Into g2 = Group
Select (ArticleNo:=ArticleNo,
Quantity:=g2.Sum(Function(f) f.Quantity))
).ToDictionary(Function(a) a.ArticleNo, Function(a) a.Quantity)
)
Using writer As New StreamWriter(outputPath)
' Write header
writer.Write("Rest Day")
For Each art In Article.AllArticles
writer.Write(art.Name.PadLeft(ColumnSize))
Next
writer.WriteLine()
' Write rows
For Each row In groupedFood
writer.Write(row.Restaurant.PadRight(5))
writer.Write(row.Day.ToString().PadLeft(4))
For Each art In Article.AllArticles
Dim quantity As Integer
row.Articles.TryGetValue(art.ArticleNo, quantity) ' yields 0 if not found.
writer.Write(quantity.ToString().PadLeft(ColumnSize))
Next
writer.WriteLine()
Next
End Using
End Sub
Putting things together
Dim foods As List(Of Food) = ReadFoodFile(inputPath)
WriteFoodTable(outputPath, foods)
See also:
Tuples (Visual Basic)
LINQ in Visual Basic