Moving files using For Loop in Batch File programming - batch-file

Question

I am trying to create a batch-file to organize files by filetypes.
The idea is to move all files with extensions, except for the running script, into new directories, each named with the extension.
What code should I need to add or substitute for some of the code given below? This .bat file is in Documents folder and there are some files there.
#echo off
set x="%cd%\log.txt"
rem 'log.txt' contains the name of folder 'My Folder' and is already created in Downloads folder.
for %%a in (".\*") do (
for /F "tokens=*" %%i In ('type %x%') do (
if "%%~xa" neq "" if "%%~dpnxa" neq "%~dpnx0" (
if not exist "C:\Users\%username%\Downloads\%%i\%%~xa" md "C:\Users\%username%\Downloads\%%i\%%~xa"
move "%%a" "C:\Users\%username%\Downloads\%%i\%%~xa\"
)
)
)
pause
OUTPUT:
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
The system cannot find the file specified.
Press any key to continue . . .

Answer 1

This will create folders as C:\users\username\Downloads\.ext including the dot.
#echo off
set "x=%~dp0\log.txt"
rem 'log.txt' contains the name of folder 'My Folder' and is already created in Downloads folder.
for /F "delims=" %%i In ('type %x%') do (
if "%%~xi" neq "" if "%%~fi" neq "%~f0" (
md "%userprofile%\%%~xi" >nul 2>&1
move "%%~fi" "%userprofile%\Downloads\%%~xi\"
)
)
pause
If you do not want the dot. i.e C:\users\username\Downloads\ext
#echo off
setlocal enabledelayedexpansion
set "x=%~dp0\log.txt"
rem 'log.txt' contains the name of folder 'My Folder' and is already created in Downloads folder.
for /F "delims=" %%i In ('type %x%') do (
if "%%~xi" neq "" if "%%~fi" neq "%~f0" (
set "ext=%%~xi"
call set ext=!ext:.=!
md "%userprofile%\!ext!" >nul 2>&1
echo move "%%~fi" "%userprofile%\Downloads\!ext!"
)
)
pause
Note, I removed the %%i from the md command as it will create a folder with the name of the file, if that is what you wanted, just put it back.

Answer 2

Given my understanding of what you're trying to do, I would suggest something a little more like this:
#Echo Off
Set "DestDirName=My Folder"
If Exist "%~dp0log.txt" Set /P "DestDirName="<"%~dp0log.txt"
If Exist "log.txt" Set /P "DestDirName="<"log.txt"
For %%A In (*)Do If /I Not "%%A"=="%~nx0" If Not "%%A"=="log.txt" If Not "%%~xA"=="" (
Set "FileExtension=%%~xA"
SetLocal EnableDelayedExpansion
RoboCopy . "%UserProfile%\Downloads\%DestDirName%\!FileExtension:~1!" "%%A" /Mov>Nul
EndLocal
)
Pause
Lines 2, 3 and 4 will Set the name of the parent directory in Downloads which will hold the directories for your files to be moved to. I have used a new directory named My Folder as a backup just in case the file log.txt cannot be found in either the current directory, or that holding your running batch file. It currently selects the name in the following order of preference: 'current directory', 'batch file directory', 'My Folder'; you can switch lines 3 and 4, if you'd prefer the 'batch file directory' to take precedence over the 'current' directory. If log.txt is found, the Set /P command will set the variable DestDirName to the content of the first line of that file, please don't use doublequotes or a trailing backslash in that content.
The For loop will then proceed to move all files with extensions to directories named using their extension, without its leading period, held within the directory, from lines 2-4, and inside the users Downloads directory. When doing that it will not include itself or any file named log.txt.
BTW, it doesn't matter if the directory name string value of %DestDirName% already exists in Downloads, it will be created automatically if it doesn't.