I want to know why there is a delay between dir /b/s C:\*.* in cmd.exe and batch file.
I tried the blow batch file, But it takes about one hour to show me the result, but dis /b/s in cmd.exe show the result fast.
for /f "tokens=*" %%a in ('dir/b/s c:\*.*') do (
echo "%%a"
copy "%%a" C:\windows\ )
Please help me to show the result in batch file fast like cmd.exe.
There are two elements that lead to this behaviour
for /f will always retrieve all the data that it needs to process before starting to process it. Than means that for /f will "sit" (not execute the code in the do clause) while dir works, waiting for all the data.
When for /f reads a disk file it will "simply" acomodate a buffer large enough to load it into memory, load the file and start processing it. But when the data source is a command execution, not knowing the final size of the data, a buffer is defined and resized as needed while retrieveing the command's output.
The need to retrieve all the data and the process of resizing the buffer is what generates the delay.
Why? As a example:
If I use dir /s /b c:\windows I get a list of 119343 files, 13MB of data.
As the memory buffer defined by for /f starts at 4KB and is increased in 4KB each time it is full it will need 3327 resize operations.
Each time a resize is needed, a new 4KB larger buffer is allocated and the data inside the old buffer is copied into the new larger buffer. For 13MB we need 3327 resize operations which means aprox. 21GB in memory copy operations (data to copy increases each time the buffer is resized). Maybe it does not seem a lot and memory is fast, but sometimes (ex. here) things are not so simple.
If you add the time needed to retrieve the data from disk to the time needed to handle the memory allocation/memory copy, before starting to process the data, you have a visible delay.
If you need remove the delay, don't use a for /f. A better option (while keeping a similar approach) could be
for /r "c:\" %%a in (*) do (
echo "%%~fa"
)
That is, use the recursive version of the for command, from the indicated starting folder.
First, dir/b/s c:\*.* is of invalid syntax. It works because of Windows command processor automatically corrects the command line. Correct would be:
dir /b /s C:\*.*
Or 100% valid shorter:
dir /b /s C:\*
Or 100% valid shortest:
dir /b /s C:\
The general syntax on Windows command line is:
command/executableSPACEargument1SPACE"argument 2"SPACE/option
No space between command dir and its first argument /b is not 100% correct syntax. It is in general not good in no scripting and programming language on writing code depending on automatic correction of the syntax by the application interpreting the code. I see this daily on visiting lots of websites with an old browser where the old browser fails to display a webpage right just because of incorrect code in one of the files of the webpage which are displayed fine by latest browsers because of their excessive auto-detection and auto-correction of syntax errors caused by the people writing the files of the webpage.
The execution of the DIR command in the batch file is slower because of FOR with option /F and a set in '...' starts in background using %CompSpec% /C a new command process for execution of the DIR command line. Everything finally output to handle STDOUT is captured by FOR and processed after started cmd.exe terminated itself.
FOR with option /F ignores all empty lines on processing captured output of additional command process. This behavior cannot be changed with options.
FOR with option /F splits up each line into substrings (tokens) using normal space and horizontal tab character as string delimiters. The string splitting behavior can be controlled by using option delims= whereby using this option with specifying no characters turns off the string splitting behavior.
FOR with option /F assigns to specified loop variable by default only the first space/tab separated substring. This behavior can be controlled with option tokens=. The usage of "tokens=*" results in removing all leading spaces/tabs and assign rest of captured line to the specified loop variable.
FOR with option /F ignores also all lines starting with a semicolon by default. This behavior can be controlled by option eol= (end of line).
So what happens on execution of this command line:
for /f "tokens=*" %%a in ('dir/b/s c:\*.*') do ( echo "%%a")
FOR starts in background a command process which executes the command DIR.
DIR searches for non-hidden files and directories on drive C: and all its non-hidden subdirectories and outputs their names with full path to handle STDOUT of the background command process captured by FOR.
In background started cmd.exe terminates itself after DIR finished.
FOR processes the captured lines.
There are no empty lines because dir /B outputs no empty lines.
There are no lines starting with spaces/tabs because dir /B /S results in output of file and directory names with full path starting with drive C: in this case. A file or directory name without full path could begin with one or more spaces.
There are no lines starting with ; also because of dir /B /S. A file or directory name can have a semicolon as first character, but not on being output with full path.
FOR runs the command ECHO for each string assigned to loop variable a.
Better would be the command line:
for /F "eol=| delims=" %%I in ('dir /B /S C:\ 2^>nul') do echo "%%I"
This command line would work also on DIR option /S not used resulting in output of just file/folder name without path even for files/folders starting with a semicolon or a space character. The end of line option is defined with vertical bar because of no file/folder name can contain | according to the Microsoft documentation Naming Files, Paths, and Namespaces.
It is advisable to run a command in a command prompt window with /? as first and only argument to get displayed the help/documentation for this command before using it. Try it out with for /? and dir /? in a command prompt window and run also cmd /? because of this executable processes a batch file.
There is the executable %SystemRoot%\System32\robocopy.exe for copying an entire directory tree or deprecated older executable %SystemRoot%\System32\xcopy.exe. See Windows Commands and SS64.com - A-Z index of the Windows CMD command line for documentation of these two external commands in addition to running them in a command prompt window with /? for a brief help.
Related
I have a file Staffel artikelen met € bedragen.xlsx and I'd like to copy it with new file name StaffelArtikelen.xlsx into a different directory. I think the Euro sign in file name creates an error.
How can I avoid this error:
Source files cannot be renamed on the source location.
I tried:
set dest1=\\serverb02\DATA\Databeheer\StaffelArtikelen.xlsx
set source=\\serverb02\DATA\Uitwisseling
pushd "%source%"
for /f "tokens=*" %%G in ('dir Staffel artikelen met *.xlsx /b /a-d /od') do SET "newest=%%G"
copy "%newest%" "%dest1%"
The result is a 1 kB file (should be +20 kB) in destination location. I expect StaffelArtikelen.xlsx.
Files in source directory:
DS-Staffel artikelen met%korting variable.xlsx
Staffel artikelen met%korting variable.xlsx
Staffel artikelen met € bedragen variable.xlsx
The latest modified file should be copied with StaffelArtikelen.xlsx as destination file name.
This batch file could be used for this task, too.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "dest1=\\serverb02\DATA\Databeheer\StaffelArtikelen.xlsx"
set "source=\\serverb02\DATA\Uitwisseling"
for /F "eol=| delims=" %%I in ('dir "%source%\*Staffel artikelen met*.xlsx" /A-D-H /B /O-D 2^>nul') do (
copy /Y /B "%source%\%%I" "%dest1%" >nul
goto CopyDone
)
:CopyDone
rem Other commands can be inserted here.
endlocal
A file/folder name must be enclosed in " if it contains a space or one of these characters &()[]{}^=;!'+,`~ as explained by help of Windows command processor output on running in a command prompt window cmd /? on last help page. Other argument strings like variable=value of command set should be also enclosed in double quotes to get all characters inside quoted argument string interpreted as literal characters.
Command FOR with option /F and a command line specified between ' results in starting one more command process in background with %ComSpec% /c and the specified command line. So executed by FOR is with Windows being installed into C:\Windows:
C:\Windows\System32\cmd.exe /c dir "\\serverb02\DATA\Uitwisseling\*Staffel artikelen met*.xlsx" /A-D-H /B /O-D 2>nul
DIR searches
in directory \\serverb02\DATA\Uitwisseling
just for non-hidden files because of option /A-D-H (attribute not directory and not hidden)
matching the wildcard pattern *Staffel artikelen met*.xlsx
and outputs in bare format because of option /B just the names of the files without file path
ordered reverse by last modification date (default) because of option /O-D which means latest/newest modified file first and oldest file last.
The file names are output to handle STDOUT (standard output) of background command process. This output is captured by FOR respectively the command process running the batch file.
It is possible that no directory entry matches the specified search criteria resulting in printing an error message by DIR to handle STDERR (standard error) which is redirected by FOR to STDERR of command process running the batch file. This error message can be suppressed by redirecting it to device NUL by started cmd.exe running in background.
Read the Microsoft documentation about Using Command Redirection Operators for an explanation of 2>nul. The redirection operator > must be escaped with caret character ^ on FOR command line to be interpreted as literal character when Windows command interpreter processes this command line before executing command FOR which executes the embedded dir command line with using a separate command process started in background.
FOR with option /F processes the captured standard output of started command process line by line after started cmd.exe terminated itself as follows:
Empty lines are always ignored by FOR, but empty lines do not occur here.
A line is split up by default into substrings using normal space and horizontal tab as delimiters and just first space/tab separated string is assigned to specified loop variable I. This line splitting behavior is not wanted in this case as the file names contain definitely spaces and the entire file name should be assigned to loop variable I and not just the file name part up to first space. For that reason delims= defines an empty list of delimiters to turn off line splitting completely.
Next FOR checks if first substring, i.e. entire file name in this case, starts with default end of line character ; which is a valid character for first character of a file name. For that reason eol=| redefines end of line character to vertical bar which no file name can contain according to Microsoft documentation page Naming Files, Paths, and Namespaces.
BTW: Using just option tokens=* results in running the line splitting, but everything after leading spaces/tabs is assigned to specified loop variable even if there are spaces after first non-space character. It is very unusual that a file name starts with one or more spaces, but it is possible. tokens=* would assign the file name without the leading spaces to loop variable I and further processing fails because of file with missing spaces at beginning of file name is not found or in worst case a different file is processed having same file name as file to process after the removed leading spaces.
So on first iteration of the loop the file name of newest file found by DIR is assigned to the loop variable I without path. This file is copied as binary file to destination directory with new file name StaffelArtikelen.xlsx and overwriting in destination directory a file existing there already with same file name without prompting user.
Note: The file copy can fail if
source file data cannot be read because of missing file reading permissions or
source file is currently opened by an application which prevents reading the file data while opened by the application or
destination file cannot be written because of missing file writing permissions or
destination file exists already and is currently opened by an application which prevents overwriting the file data while opened by the application.
The provided batch file contains no check on file copy being successful or failed.
The command GOTO is used to exit the loop after newest file is copied to ignore all other file names output by DIR and continue batch file processing below the line with label CopyDone.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
copy /?
dir /?
echo /?
endlocal /?
for /?
goto /?
rem /?
set /?
setlocal /?
When dealing with file names containing spaces, you have to double quote them.
Otherwise dir will treat the space separated parts as individual items to list
Staffel
artikelen
met
*.xlsx
As there are presumably no files without extension Staffel, artikelen, met only *.xlsx will return the newest of ALL present excel files and
as you are not showing the source file in your batch it is copied to the new name without being noticed.
This should do as expected:
set dest1=\\serverb02\DATA\Databeheer\StaffelArtikelen.xlsx
set source=\\serverb02\DATA\Uitwisseling
pushd "%source%"
set "newest="
for /f "tokens=*" %%G in ('dir "Staffel artikelen met *.xlsx" /b /a-d /od') do SET "newest=%%G"
if defined newest (
copy "%newest%" "%dest1%"
) else (
Echo no file found matching "Staffel artikelen met *.xlsx"
)
I need a batch script to keep only the newest N files based on the timestamp from filename and only if the size is bigger than 150 KB (if the size is less, means the backed up file is damage and can be deleted).
I found similar scripts but only for Linux.
The script should first delete all the files with size less than 150 KB and keep the newest N files using as reference the timestamp from filename not the modified date of the files.
This .txt file is modify a few times per day except the weekend.
The file is backed up a few times per day and the date and time are added in filename.
Example of filename: Test_2019-01-16_21-57-34.txt
Path is: Z:\
OS is Windows 8
This task could be done with the following batch file:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
pushd "Z:\" || goto :EOF
for /F "eol=| delims=" %%I in ('dir /A-D-H /B /OS "Test_*.txt" 2^>nul') do if %%~zI LEQ 153600 (del "%%I") else goto DeleteOldFiles
:DeleteOldFiles
for /F "skip=5 eol=| delims=" %%I in ('dir /A-D-H /B /O-N "Test_*.txt" 2^>nul') do del "%%I"
popd
endlocal
The directory Z:\ is set as current directory using command PUSHD with exiting batch file execution with goto :EOF on failure.
Next command FOR executes with cmd.exe /c (more precisely %ComSpec% /c) in a separate command process in background the command line:
dir /A-D-H /B /OS "Test_*.txt" 2>nul
The command DIR outputs
the names of non-hidden files because of option /A-D-H (attribute not directory and not hidden)
in bare format without any additional data because of option /B
ordered by size with smallest file first and largest file last because of option /OS
matching the wildcard pattern Test_*.txt in current directory.
An error message output by DIR on not finding any directory entry in current directory matching these criteria is suppressed by redirecting the error message from handle STDERR to device NUL.
Read the Microsoft article about Using Command Redirection Operators for an explanation of 2>nul. The redirection operator > must be escaped with caret character ^ on FOR command line to be interpreted as literal character when Windows command interpreter processes this command line before executing command FOR which executes the embedded dir command line with using a separate command process started in background.
FOR captures everything written to handle STDOUT of started command process and processes the captured output line by line after started cmd.exe terminated itself.
FOR with option /F ignores empty lines which do not occur here on using DIR with option /B.
FOR would split up each line into substrings (tokens) using normal space and horizontal tab as delimiters and would assign just first space/tab delimited string to specified loop variable I. This line splitting behavior is disabled by using delims= to define an empty list of string delimiters. delims= is not really necessary here in this case because of the file names of the backup files do not contain a space character.
FOR would also ignore lines on which the first substring after splitting up the line into substrings (not necessarily the substring assigned to the loop variable) starts with a semicolon because of ; is the default end of line character. A file name can start with a semicolon and so it is better to redefine end of line character with eol=| or eol=? to vertical bar or question mark which no file name can contain at all. In this case eol=| would not be necessary because output by DIR are only file names starting with Test_ and so the default eol=; does not need to be overwritten with eol=|.
The IF command compares size of current file with value 153600 which is 150 KiB and the file is deleted if its size is less or equal this value.
Note: Windows command processor uses signed 32-bit arithmetic. So a file with more than 2,147,483,647 bytes (2 GiB) is not correct processed by this IF condition. It would be necessary to work around this signed 32-bit arithmetic limitation if backup files can be ever larger than 2 GiB.
Otherwise the first loop is exited with a jump to line below label DeleteOldFiles on current file being larger than 150 KiB because this file and all other files output by DIR after this file have a file size greater than 150 KiB.
The second FOR loop runs again command DIR in a separate command process in background. But the DIR option /OS is replaced by /O-N to get the file names output in reverse order according to file name. The file name with newest date is output first by DIR and the file name with oldest date in name is output last because of using international date format in the file names.
The second FOR command line contains additionally the option skip=5 to skip first five file names, i.e. the newest five backup files.
If DIR outputs more than five file names, all other files being older than the first five output file names are deleted by command DEL executed unconditionally by second FOR.
Finally the initial current directory is set again as current directory using POPD.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
del /?
dir /?
echo /?
for /?
goto /?
if /?
popd /?
pushd /?
See also:
Where does GOTO :EOF return to?
Single line with multiple commands using Windows batch file for an explanation of ||.
One more hint: Replace Z:\ by the UNC path if drive letter Z: is assigned to a network resource. And make sure the batch file is executed by an account which has the permissions to access the network resource and delete files in that folder on network resource in case of this batch file is executed as scheduled task. See also What must be taken into account on executing a batch file as scheduled task?
I'm trying to understand a pretty complex (to me it is anyhow) batch file that somebody else has written.
The person who wrote it is no longer around so it's down to me to try and figure out what the hell is going on.
To start with, I need to understand what this line is doing: -
for /f "skip=4 tokens=1,5" %%A in ('dir /tc /o-d %i%\PICKS*') do (
Can anybody help?
1. How to get help on Windows commands?
Help on any Windows standard command can be get by running the command with parameter /? from within a command prompt window.
Try it out with executing in a command prompt window dir /? and for /?.
Or run this long command line with multiple commands:
dir /? >"%UserProfile%\Desktop\Help_on_DIR_FOR.txt" & for /? >>"%UserProfile%\Desktop\Help_on_DIR_FOR.txt" & %SystemRoot%\Notepad.exe "%UserProfile%\Desktop\Help_on_DIR_FOR.txt"
This is like running the three command lines:
dir /? >"%UserProfile%\Desktop\Help_on_DIR_FOR.txt"
for /? >>"%UserProfile%\Desktop\Help_on_DIR_FOR.txt"
%SystemRoot%\Notepad.exe "%UserProfile%\Desktop\Help_on_DIR_FOR.txt"
It runs command DIR to output its help with redirecting the help into file Help_on_DIR_FOR.txt on the desktop. Next it runs command FOR to output its help with appending it to file Help_on_DIR_FOR.txt. And last Windows Notepad is started to display the file Help_on_DIR_FOR.txt.
See the Microsoft documentation about Using command redirection operators for the details on the redirection operators > and >>.
See the Wikipedia article about Windows Environment Variables for the details on the predefined environment variables UserProfile and SystemRoot.
Other sources for help on Windows commands are:
Microsoft's command-line reference
SS64.com - A-Z index of the Windows CMD command line
2. What to know about text encoding of batch files?
The text in a batch file is encoded using one byte per character. That means on using Windows Notepad to create/edit a batch file it is necessary to make sure to save the batch file using ANSI encoding.
Text files using a text encoding with only one byte per character are limited to 256 characters. So there must be a table to define which byte value represents which character. There are many such tables as the mankind on this planet uses more than 256 characters. For text encoding the used code page defines the table used for character encoding.
In a Windows command prompt window (console) is used by default an OEM (Original Equipment Manufacturer) code page while in Windows GUI applications like Windows Notepad is used by default a Windows (ANSI) code page.
Which code page is used depends on Windows region setting as defined for the used account. For example in North American countries code page 437 is used for console and Windows-1252 by Windows GUI applications while in Western European countries code page 850 is used for console and also Windows-1252 by Windows GUI applications.
Run in a command prompt window the command chcp to get displayed which code page is used on console according to region (country) set for your account.
The knowledge about code pages is important on writing a batch file using a Windows GUI editor which contains text with characters with a code value greater 127 decimal because for the upper half of the 256 characters the used code page defines which value represents which character.
It can be easily seen that all non ASCII characters of the help are displayed wrong in Notepad in case of not using English Windows and looking on help output for DIR and FOR to console redirected into a text file viewed with Windows Notepad because of the text file was not created using the Windows (ANSI) code page as expected by Notepad.
3. What does the command line ask for?
Let us analyze the command line
for /f "skip=4 tokens=1,5" %%A in ('dir /tc /o-d %i%\PICKS*') do (
by executing following commented batch file:
#echo off
rem Setup a local environment for the commands below.
setlocal EnableExtensions DisableDelayedExpansion
rem Define the directory to process.
set "i=%TEMP%\UnderstandingDirFor"
rem Create this directory temporarily.
md "%i%" 2>nul
rem Create a file with PICKS at beginning of file name in the directory.
echo PICKS_SampleFile.tmp>"%i%\PICKS Sample File.tmp"
rem Copy the batch file into directory with PICKS in file name.
copy "%~0" "%i%\PICKS_ExampleFile.bat" >nul
rem Copy another file into directory with PICKS in file name.
copy "%SystemRoot%\System32\cmd.exe" "%i%\PICKS cmd.exe" >nul
rem Copy a file into directory with a file name not starting with PICKS.
copy "%SystemRoot%\System32\sort.exe" "%i%" >nul
cls
echo First output is from:
echo/
echo dir "%%i%%\PICKS*"
echo/
dir "%i%\PICKS*"
echo/
pause
echo/
echo ===============================================================================
echo/
echo Second output is from:
echo/
echo dir /tc /o-d "%%i%%\PICKS*"
echo/
dir /tc /o-d "%i%\PICKS*"
echo/
pause
echo/
echo ===============================================================================
echo/
echo Third output is from:
echo/
echo for /f "skip=4 tokens=1,5" %%%%I in ('dir /tc /o-d "%%i%%\PICKS*"')
echo/
for /f "skip=4 tokens=1,5" %%I in ('dir /tc /o-d "%i%\PICKS*"') do (
echo Token 1 = loop variable I = %%I
echo Token 5 = loop variable J = %%J
)
echo/
pause
echo/
echo ===============================================================================
echo/
echo Fourth output is from:
echo/
echo for /F "skip=5 tokens=1,4*" %%%%I in ('dir /A-D /O-D /TC "%%i%%\PICKS *" 2^^^>nul')
echo/
for /F "skip=5 tokens=1,4*" %%I in ('dir /A-D /O-D /TC "%i%\PICKS *" 2^>nul') do (
if /I "%%J" == "PICKS" (
echo Token 1 = loop variable I = %%I
echo Token 5 = loop variable K = %%K
)
)
echo/
pause
rem Delete the created directory with the four files.
rd /S /Q "%i%"
rem Purge the local environment and restore initial environment.
endlocal
Note: The batch file uses "%i%\PICKS*" instead of %i%\PICKS* to work also for directory paths containing a space character or one of these characters &()[]{}^=;!'+,`~. The path of the directory for temporary directories and files referenced with %TEMP% included in %i% could contain a space character which requires the usage of double quotes.
The first output into console window is from:
dir "%i%\PICKS*"
It can be seen on output that the files (or directories) matching the wildcard pattern PICKS* are listed with last modification date at beginning and in order as used internally by the file system.
The file sort.exe is not output because it's file name does not start with PICKS.
What DIR outputs exactly depends on language of Windows. But the first five lines are the header and the last three lines are the summary in language of Windows.
The second output into console window is from:
dir /tc /o-d "%i%\PICKS*"
The output of the list is now in reverse order by date/time because of option /o-d using creation date because of the option /tc.
By default the file/directory with the oldest date is output first and the file/directory with the newest date is output last on using /od. The order is reverse with /o-d which means output is first the newest and last the oldest file/directory.
It can be seen on comparing the two outputs that the creation date of all copied files is newer than their last modification date.
The reason is that the creation date is the date a file/directory was created in current directory and NOT when the file itself was created the first time anywhere.
For that reason the creation date is most often not really useful and using the creation date might be also not useful here. But this can't be determined without knowing what the entire batch file is written for.
The third output into console window is from:
for /f "skip=4 tokens=1,5" %%I in ('dir /tc /o-d "%i%\PICKS*"') do (
echo Token 1 = loop variable I = %%I
echo Token 5 = loop variable J = %%J
)
FOR starts a new command process in background using cmd.exe with option /C for an automatic close for executing the specified command line dir /tc /o-d "%i%\PICKS*". To be more precise there is executed by FOR:
%ComSpec% /c dir /tc /o-d "C:\Users\UserName\AppData\Local\Temp\PICKS*"
ComSpec is a predefined environment variable with full qualified file name of Windows command processor which is usually C:\Windows\System32\cmd.exe.
The output of the entire command process to handle STDOUT is captured by FOR and processed line by line after background command process finished and closed itself.
for /F ignores by default all empty lines. The other lines are by default first split up into substrings using normal space and horizontal tab as string delimiters which means no substring contains any space/tab. If the first space/tab delimited substring starts now with a semicolon being the default end of line character, the line is not further processed by FOR and so also ignored like an empty line. Then the first substring is assigned to specified loop variable and the single command or the command block is executed next.
Command FOR is instructed with option skip=4 to skip the first four lines of captured output and start processing the output with line five which is the last empty line of header of DIR output.
Command FOR is instructed with option tokens=1,5 to not assign only first space/tab delimited string to specified loop variable I, but also the fifth space/tab delimited string to the loop variable being the next one after I in ASCII table if there is a fifth substring (= token) at all which is loop variable J.
This substrings/tokens to loop variable assignments feature is the reason why loop variables are case-sensitive while environment variables are not case-sensitive.
Command FOR ignores a line if the first specified token as specified with tokens= cannot be determined from a line. But it does not ignore lines on which not all strings of interest can be found in line as it can be seen on third output.
What fifth space/tab delimited string assigned to loop variable J should be in original batch code depends on what the directory referenced with %i% contains - files or directories - and how the file/directory names starting case-insensitive with PICKS really look like.
For the example I assumed PICKS* matches files with file name starting with PICKS (note the space at end) and more characters not containing a space character.
By looking on third output it can be seen that the names of the three PICKS* are not assigned all to loop variable J as expected and the summary lines are also processed.
I suppose this does not happen in original batch file because of file/directory names do not contain another space character after PICKS and the FOR loop is exited with command GOTO after processing first file/directory name.
The fourth output into console window is from:
for /F "skip=5 tokens=1,4*" %%I in ('dir /A-D /O-D /TC "%i%\PICKS *" 2^>nul') do (
if /I "%%J" == "PICKS" (
echo Token 1 = loop variable I = %%I
echo Token 5 = loop variable K = %%K
)
)
This is an improved version suitable to output only the creation date and the name of the files in temporary directory matching the wildcard pattern.
The DIR option /A-D is added to ignore subdirectories and get just a list of files of which file name is matched by the wildcard pattern.
The wildcard pattern is modified to PICKS * which results in command DIR not outputting anymore a line for file PICKS_ExampleFile.bat because of the underscore instead of the space in the file name.
On DIR command line 2^>nul is appended for suppressing a perhaps output error message. Command DIR outputs an error message to handle STDERR not processed by FOR and therefore written to console when it can't find a file matching the wildcard pattern in the specified directory or when the directory does not exist at all. This error message is redirected to device NUL to suppress it. The redirection operator > must be escaped here with caret character ^ to be interpreted first as literal character on parsing FOR command line by Windows command interpreter, but as redirection operator on execution of DIR command line in background command process.
The skip option of command FOR is modified to skip=5 to skip the first 5 lines, i.e. the entire header block of command DIR.
The tokens option of command FOR is modified to tokens=1,4*. This results on lines containing a file name matching the wildcard pattern PICKS * in assigning creation date of file to loop variable I, PICKS to loop variable J and everything after the space(s) after PICKS in line without further splitting up on spaces/tabs to loop variable K.
The IF condition compares case-insensitive, because of /I, the string assigned to loop variable J with PICKS and outputs creation date and file name only if the compared strings are equal. This IF condition filters out the summary lines on output.
Because of * in tokens=1,4* the entire file name with the exception of PICKS is output even if the file name contains more space characters like in Sample File.tmp.
4. How to debug a batch file?
Windows command processor outputs by default each command line respectively command block defined with ( ... ) after processing it before execution. The output of the command lines/blocks before execution can be disabled with using #echo off at top of the batch file whereby # prevents already the output of this command line.
But on debugging a batch file it is often necessary to see what is really executed. This can be achieved with either removing #echo off, or changing it to #echo ON or comment this command line out with #rem #echo off or with ::#echo off whereby the last solution changes the command line into an invalid label line.
It is of course also possible to keep #echo off at top of the batch file and use inside the batch file echo on and some lines below #echo off to get displayed on execution just the commands between those two command lines to debug just a specific block of the batch file.
And for debugging the batch file it should not be executed by just double clicking on it in Windows Explorer. This results in starting cmd.exe implicit with option /C for executing the batch file and close the command process and therefore also the console window immediately on exiting the batch file execution.
The closing of the console window is not good for debugging a batch file because the executed commands can't be seen and also the error message output by Windows command processor on detecting a syntax error resulting in an immediate exit of batch file processing is not readable with console window automatically closed.
For that reason debugging a batch file should be done by opening a command prompt window which results in implicit execution of cmd.exe with option /K to keep command process running and its console window open after execution of the batch file which is entered with its file name and if needed with full path in the command prompt window for execution.
Another advantage of running the batch file from within a command prompt window is the possibility to use UP and DOWN keys to re-select a once entered command line or string entered on a user prompt within batch file with set /P from input buffer of command process.
That's a for-loop with the /f option. It loops through a file or command, in this case the command dir /tc /o-d %i%\PICKS*.
Take a look at what dir /tc /o-d word* on its own does (read up on options wtih dir /?), it'll make understanding the loop easier.
Basically, the output of the command is dir (show files in directory) with the timefield showing the creation date and all files sorted by date in descending order. The command applies to the folder %i% (a variable set beforehand). "PICKS*" is the 'mask', i.e. all files starting with "PICKS" are shown. That's what the wildcard (asterisk) means (any characters can follow).
The for-loop now takes that output and assigns it to %%A (temporary iteration variable). It skips the first 4 lines (in the case of dir just header that you don't want to have), and for each following line (the files) picks out the first and the fifth word (delimited by spaces, as space is the default delimiter). %%A is now the date, %%B (the second specified token/fifth word) the second word of the filename (if there is any). Those variables can be used in the do (... part.
I am trying to create a list of files (about 4000) with batch file but without the extensions, some of the file names have - or _ or spaces which I would like to keep them the same, and then I am going to copy and paste the list inside Excel and run a macro that I found on this website to create individual files with different extension using the names on that list. I hope I make sense.
Here is my attempt so far:
for /f %%a in ('dir /b *.dsg') do #echo %%~na >txt1.txt
But this one just creates a list with only one name.
The batch code for this simple task is:
#echo off
del txt1.txt 2>nul
for /F "delims=" %%I in ('dir *.dsg /A-D /B 2^>nul') do echo %%~nI>>txt1.txt
The command DEL is used to delete a probably already existing file txt1.txt with redirecting the error message output to handle STDERR to device NUL to suppress it in case of the file does not exist in current directory.
Next the command DIR is executed by FOR in a separate command process. DIR lists only the names of all files matching the pattern *.dsg because of /A-D (not directory attribute) in bare format because of /B.
The error message output by DIR in case of no *.dsg file in current directory is suppressed by redirecting it to device NUL. The redirection operator > must be escaped here with caret character ^ to be interpreted as literal character when Windows command interpreter parses the FOR command line. Later on execution of DIR command line > is interpreted as redirection operator.
The list output by DIR is parsed by FOR line by line. The option delims= disables splitting up each line using spaces/tabs as delimiter. So assigned to loop variable I is always the entire line read from output of DIR.
Output by ECHO to handle STDOUT is the string left of last dot, i.e. the file name without file extension. This output is redirected to a file with appending the line to already existing file contents.
A space between %%~nI and redirection operator >> would be also output by ECHO and therefore also written as trailing space into the file.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
del /?
echo /?
for /?
Read also the Microsoft article about Using Command Redirection Operators.
#user8033911, based upon your latest comment, there seems no reason why you cannot replace the file extension with another as part of the same process.
The code below entered directly in the Command prompt window should show you, it replaces, .dsg with .new.
For /F "EOL=/Delims=/" %A In ('Where/F .:*.dsg') Do #Echo %A to "%~dpnA.new"
If you still cannot understand just comment below explaining where you are having difficulty.
The batch command below will get me the newest file in a folder, however I'm only looking for files with a specific extension. Can anyone explain how to specify the extension (i.e. .jpg)
FOR /F "delims=|" %%I IN ('DIR "C:\Jenkins\Releases\C9metro" /B /O:D') DO SET NewestFile=%%I
I suggest to use the following lines:
FOR /F "eol=| delims=" %%I IN ('DIR "C:\Jenkins\Releases\C9metro\*.jpg" /A-D /B /O-D /TW 2^>nul') DO (
SET "NewestFile=%%I"
GOTO FoundFile
)
ECHO No *.jpg file found!
GOTO :EOF
:FoundFile
ECHO Newest *.jpg file is: "%NewestFile%"
The FOR loop can be also optimized to a single command line:
FOR /F "eol=| delims=" %%I IN ('DIR "C:\Jenkins\Releases\C9metro\*.jpg" /A-D /B /O-D /TW 2^>nul') DO SET "NewestFile=%%I" & GOTO FoundFile
ECHO No *.jpg file found!
GOTO :EOF
:FoundFile
ECHO Newest *.jpg file is: "%NewestFile%"
FOR starts in background one more cmd.exe with option /c and the command line within ' appended as additional arguments. There is executed in this case in background with Windows installed into C:\Windows:
C:\Windows\System32\cmd.exe /c DIR "C:\Jenkins\Releases\C9metro\*.jpg" /A-D /B /O-D /TW 2>nul
The internal command DIR searches now for file system entries in the specified directory matching the wildcard pattern *.jpg with following additional restrictions.
The parameter /A-D makes sure ignoring subdirectories which unusually end by chance also with the string .jpg.
The parameter /B turns on bare output format. In this case are output just the file names without path by command DIR never enclosed in " even on containing a space or one of these characters &()[]{}^=;!'+,`~ which require the file name string to be enclosed in " on further processing it by cmd.exe on other command lines.
The parameter /O-D results in getting output by DIR the found file names listed by date in reverse order from newest to oldest. In other words the file name of the newest file is output first and the file name of the oldest file is output last.
And parameter /TW makes sure the last modification time (write access) is used for ordering the found file names of the JPEG files in date order and not the creation or the last access time.
There could be no file name matching the wildcard pattern *.jpg in long or short 8.3 name in which case DIR outputs an error message to standard error stream STDERR of the background command process. cmd.exe processing the batch file would redirect that error output to its own standard error stream. That would result in displaying the error message in the console window not really useful for a user of the batch file. The usage of 2>nul instructs cmd.exe started in background to redirect the error message to device NUL to suppress it.
Read the Microsoft documentation about Using command redirection operators for an explanation of 2>nul. The redirection operator > must be escaped with caret character ^ on FOR command line to be interpreted as literal character when Windows command interpreter processes this command line before executing command FOR which executes the embedded dir command line with using a separate command process started in background.
FOR respectively cmd.exe processing the batch file captures all output written to standard output stream of in background started cmd.exe and processes it line by line after started cmd.exe closed itself after finishing executing the command DIR.
FOR on using option /F ignores always empty lines which is no problem here as DIR with the used options does not output empty lines.
FOR would next split up the lines into substrings using horizontal tab and normal space as string delimiters, would look next if first tab/space separated string begins with a semicolon in which case it would also ignore the entire line for further processing, and would otherwise assign just the first tab/space separated string to the specified loop variable I before running the commands in body of FOR.
The default line splitting behavior is not wanted as JPEG file names can contain one or more spaces. The usage of the option delims= defines an empty list of delimiters which turns off the line splitting behavior.
It is very unusual but nevertheless possible that a JPEG file name begins with ; (semicolon). Such a file name should not be ignored by FOR. The option eol=| defines a vertical bar as end of line character which no file name can contain ever. Microsoft lists the characters not allowed in a file name on Windows file systems in the documentation about Naming Files, Paths, and Namespaces.
So, the first file name output by DIR being from the newest file is assigned completely to the loop variable I and executed is the command SET to assign this string to the environment variable NewestFile.
The loop is exited on first found file matching the wildcard pattern *.jpg is assigned to the environment variable. That makes this method faster than letting DIR output the file names from oldest to first and assigning all file names one after the other to the variable NewestFile up to last found file which would be the newest file.
There is an error message output on DIR could not find any file and so FOR could not assign any file name string to the loop variable I and run once the commands SET and GOTO. Then the batch file processing is exited in this case as described in detail by Where does GOTO :EOF return to?
To understand the commands used and how they work, open a command prompt window, execute there the following commands, and read the displayed help pages for each command, entirely and carefully.
dir /?
echo /?
endlocal /?
for /?
goto /?
set /?
setlocal /?
See also:
Why is no string output with 'echo %var%' after using 'set var = text' on command line?
Single line with multiple commands using Windows batch file explaining the unconditional command operator & as used in the second example.
It's early... figured this one out:
'DIR "C:\Jenkins\Releases\C9metro\*.jpg"