xcopy the whole folder in this case - batch-file

Question

This is another problem that i got in the same code, that i have already asked for help, so i am not sure if it is a duplicate or not.
The problem now is when i run the script, at the command xcopy i wanted to be able to copy the whole folder that the file is located instead of only the file.
#echo off
setlocal enabledelayedexpansion
set /p COU1=COU No. 1 serial number?:
echo COU serial number is: %COU1%
for /f %%i in ('dir /s /b /a-d AssayInfo.txt') do (
for /f "tokens=2" %%a in ('type "%%~fi" ^| findstr /i "CouID"') do set "number=%%a"
echo Found number !number! in file "%%~fi"
if !number!==!COU1! xcopy "%%~fi" "C:\dev\WORKING"
pause
)
so to simplify i want to copy the whole folder that the file "~fi" was found instead of only the file
i also tried something like this:
set /p COU1=COU No. 1 serial number?:
echo COU serial number is: %COU1%
for /D %%k in ("C:\dev\*") do for /f "tokens=1,* delims=: " %%i in ('type "%%k\AssayInfo.txt" ^| findstr /i CouID') do set "number=%%j"
if %number%==%COU1% (echo Hello it worked) else (echo ERROR:No files with that serial number)
pause
but the problem here it is the IF statment its outside the FOR, so it will keep changing the !number! even if it matches, and will take the last value found not the one that is equal to COU1.

Answer 1

we can use robocopy here. But you were trying to copy the filename, not the folder, remember we set !number! as the found value.
#echo off
setlocal enabledelayedexpansion
set /p COU1=COU No. 1 serial number?:
echo COU serial number is: %COU1%
for /f %%i in ('dir /s /b /a-d AssayInfo.txt') do (
for /f "tokens=2" %%a in ('type "%%~fi" ^| findstr /i "CouID"') do set "number=%%a"
echo Found number !number! in file "%%~fi"
set "fpat=%%~dpi"
set "fpat=!fpat:~0,-1!"
for %%u in (!fpat!) do set "dst=%%~nu"
if "!number!"=="!COU1!" robocopy "!fpat!" "C:\dev\WORKING\!dst!" /E
pause
)

Answer 2

Had you provided all of the information you needed at the outset, you wouldn't have needed 4 questions to achieve this task.
Based upon what we now know, I would have suggested you perform the task like this:
#Echo Off
Set "COU1="
:Ask
Set /P "COU1=COU No. 1 serial number?: "
If Not Defined COU1 GoTo Ask
For /F "Delims=" %%A In ('FindStr /SMIC:"CouId: %COU1%" "AssayInfo.txt" 2^>Nul^
^|FindStr /VBLI "WORKING\\"') Do #For %%B In ("%%~dpA."
) Do XCopy "%%~B" "C:\dev\WORKING\%%~nxB" /ECIHRKY>Nul 2>&1
Based on the info you provided this script would be ran from C:\dev.