How to hide a batch file after a command was issued - batch-file

Question

I have made a program in notepad which when runs allows the user to choose one of a select amount of options. Each option is a time that essentially counts down until when it hits 0 the computer locks itself.
Problems:
This has been created to allocate a set amount of time for my little brother however it can easily be stopped by just manually closing the program.
I wanted to know if I could therefore make it so after choosing an option the program would hide itself by running in the background or so if it is manually closed it would reopen and carry on counting down thank you.
Provided Example Code:
#echo off
cls
title Shutdown timer
color 0a
:start
echo
echo Choose Your Time allocated
echo 1. 35 Minutes
echo 2. 65 Minutes
echo 3. 95 Minutes
echo 4. 125 Minutes
echo 5. 1 Minutes
set /p choice=Type which number for your choice
if not '%choice%'== set choice=%choice:~0,1%
if '%choice%'=='1' goto :Choice1
if '%choice%'=='2' goto :Choice2
if '%choice%'=='3' goto :Choice3
if '%choice%'=='4' goto :Choice4
If '%choice%'=='5' goto :Choice5
echo "%choice%" is not a valid option. Please try again

Answer 1

You're looking to baby-poof a batch script? A simple solution is to simply hide the command window. This can be done by using a .VBS command shell to hide the command prompt process. Original post here.
CreateObject("Wscript.Shell").Run """" & WScript.Arguments(0) & """", 0, False
Above is the script to hide command windows in VBS. You can use this script by calling wscript.exe "Script" "Batch File". Pretty simple and easy way to do it without 3'rd party tools.
I combined your script to allow to create, export, use, and delete these files. Your Main shutdown script will also need exported to a new batch file to be called to by the VBS script. This can be done using a code block bellow
Rem | Create Timer.bat
(
Echo TIMEOUT /T %Time% /NOBREAK
Echo rundll32.exe user32.dll,LockWorkStation
Echo DEL "%%~f0"
)>> %Temp%\Timer.bat
This will create a new batch file containing the shutdown or lock commands. In this case rundll32.exe user32.dll,LockWorkStation will lock the workstation after X minutes by TIMEOUT /T
StartTimmer.bat:
#echo off
title Shutdown timer
color 0a
:start
cls
echo Choose Your Time allocated:
echo(
echo 1. 35 Minutes
echo 2. 65 Minutes
echo 3. 95 Minutes
echo 4. 125 Minutes
echo 5. 1 Minutes
echo(
set /p "choice=Type which number for your choice: "
if "%choice%"=="1" set "choice=35" & goto ChoiceSellected
if "%choice%"=="2" set "choice=65" & goto ChoiceSellected
if "%choice%"=="3" set "choice=95" & goto ChoiceSellected
if "%choice%"=="4" set "choice=125" & goto ChoiceSellected
If "%choice%"=="5" set "choice=1" & goto ChoiceSellected
goto start
:ChoiceSellected
Echo Now Starting Timmer For %choice% Minutes
Rem | Do math - Covert Seconds To Minutes
Set /a "Time=%choice% * 60"
Rem | Create Timer.bat
(
Echo TIMEOUT /T %Time% /NOBREAK
Echo rundll32.exe user32.dll,LockWorkStation
Echo DEL "%%~f0"
)>> %Temp%\Timer.bat
Rem | Export Hide Script & Use it
Echo CreateObject^("Wscript.Shell"^).Run """" ^& WScript.Arguments^(0^) ^& """", 0, False>> Hide.vbs
wscript.exe "%~dp0Hide.vbs" "%Temp%\Timer.bat"
del "%~dp0Hide.vbs"
goto :EOF
For help on any of the commands do the following:
call /?
set /?
for /?
if /?
find /?
So on.