How to print variable name in Cobol - c

Question

I am trying to pass to a C function the variable names from a cobol program.
01 Message.
03 varA PIC X(32).
03 varB PIC X(32).
Consider the fact that this function will be used in many programs and the structure of variable Message will be different everytime , how can i pass to the C function the names of the variables?
I allready consider making another group data item to contain the variable names, but this is not a good solution for me.
I am using Microfocus Server Express v5.1 on AIX.

Answer 1

how can i pass to the C function the names of the variables?
It is not possible to pass a variable name, directly, with CALL USING; at least, not one that would be better than a group data item.
What I did here is to create a JSON-like object using a STRING statement with a REPLACE statement to pass a name/value pair. I chose this method because there are many open source libraries that may be called from C to decode JSON objects. It also very flexible with regard to text lengths and the number of variables to be passed.
[Ed. Changed code to place all STRING statement data items in the REPLACE statement. Changed some names to reflect "name/value" pairings. Removed string length code to nested program.]
program-id. call-c.
data division.
working-storage section.
1 msg.
2 varA pic x(32) value "Message 1".
2 varB pic x(32) value "Message 2".
1 lengths binary.
2 len-1 pic 9(4).
2 len-2 pic 9(4).
replace
==name-1== by =="varA"==
==value-1== by ==varA(1:len-1)==
==name-2== by =="varB"==
==value-2== by ==varB(1:len-2)==
==newline== by ==x"0a"==
.
1 json-string pic x(256).
procedure division.
begin.
compute len-1 = function length (varA)
call "rtrim-len" using varA len-1
compute len-2 = function length (varB)
call "rtrim-len" using varB len-2
string
"{" newline
quote name-1 quote ": "
quote value-1 quote "," newline
quote name-2 quote ": "
quote value-2 quote newline
"}" x"00"
delimited size into json-string
call "c_prog" using
by reference json-string
stop run
.
program-id. rtrim-len.
data division.
linkage section.
1 str pic x(256).
1 str-len binary pic 9(4).
procedure division using str str-len.
begin.
perform varying str-len from str-len by -1
until str-len < 1 or str (str-len:1) not = space
continue
end-perform
exit program
.
end program rtrim-len.
end program call-c.
A COBOL program to substitute for a called C program.
program-id. "c_prog".
data division.
working-storage section.
1 json-string-count binary pic 9(4).
1 json-string-pos binary pic 9(4).
1 json-text-count binary pic 9(4).
1 json-text pic x(64).
linkage section.
1 json-string pic x(256).
procedure division using json-string.
begin.
move 0 to json-string-count
inspect json-string tallying
json-string-count for characters before x"00"
move 1 to json-string-pos
perform until json-string-pos > json-string-count
unstring json-string delimited x"0a" or x"00"
into json-text count json-text-count
pointer json-string-pos
display json-text (1:json-text-count)
end-perform
exit program
.
end program "c_prog".
Output:
{
"varA": "Message 1",
"varB": "Message 2"
}
If a TRIM function is available, the length calculations, data items, and nested program are not needed and the REPLACE statement becomes,
replace
==name-1== by =="varA"==
==value-1== by ==trim(varA)==
==name-2== by =="varB"==
==value-2== by ==trim(varB)==
==newline== by ==x"0a"==
.