VBS to Rename File via Send To Menu - file

Question

Every day I have to rename files to replace spaces with dashes before I can send them to our machines (a few of our machines don't read spaces in file names but our file naming conventions have spaces, a conflict of interest I know).
Sometimes it's one file others it's a half dozen so my approach is to use the Windows Send To menu to send selected files to the script.
I've gotten as far as renaming the strings but the actual move function says path not found when I get to the fso.movefile function.
Here's what I have so far.
Set objArgs = WScript.Arguments
Dim Fso
Set Fso = WScript.CreateObject("Scripting.FileSystemObject")
'Cycle through files
For I = 0 to objArgs.Count - 1
' Assign array entry to variable
t = objArgs(I)
' Parse variable to replace spaces with dashes
s = Replace(t, " ", "-")
' Let me know how I did
WScript.Echo t & vbcrlf & s
'Move 'em
fso.movefile t, s
Next
Any help will be greatly appreciated.

Answer 1

So my problem was the folder I was in had spaces too. So my code was trying to rename to a folder that didn't exist.
Once I parsed the file name out of the path and re-grouped the modified file name it worked great. Code below.
Dim t ' original file and path
Dim s ' file name only with spaces
Dim u ' new file name without spaces
Dim v ' path only
Dim obj
Set objArgs = WScript.Arguments
set obj = WScript.CreateObject("Scripting.FileSystemObject")
'Cycle through files
For I = 0 to objArgs.Count - 1
' Assign array entry to variable
t = objArgs(I)
' Parse file name from path
s = Right(t, Len(t) - InStrRev(t, "\"))
' Remove file name from path
v = left(t, InStrRev(t, "\"))
' Parse variable to replace spaces with dashes
u = Replace(s, " ", "-")
' ' Let me know how I did
' WScript.Echo "Was(t): " & t & vbcrlf & "Is(s): " & s & vbcrlf & "Path: " & v
'Move 'em
obj.movefile t, v & u
Next