This query seems very lazy for a "WHERE IN"... Because not need to check "the universe", only the little IN () set.
SELECT ?item ?itemLabel ?of ?ofLabel
WHERE
{
?item wdt:P31 ?of.
FILTER ( ?item IN (
wd:Q28114532, wd:Q27745011,wd:Q3415363,wd:Q3415324,wd:Q2877432,wd:Q2877444,
wd:Q2396644,wd:Q3444776,wd:Q2877428,wd:Q578757,wd:Q2877445,wd:Q2333617
) )
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
}
}
There are another way to do faster the same thing?
NOTE
The problem grows with similar thing, but checking if the item has "any dependency" — an instance, sub-instance, class or sub-class of something (eg. Q7860962).
SELECT ?item ?itemLabel ?x ?xLabel
WHERE
{
?x (wdt:P31|wdt:P279)* wd:Q7860962 .
?item wdt:P31 ?x .
FILTER ( ?item IN (
wd:Q28114532, wd:Q27745011,wd:Q3415363,wd:Q3415324,wd:Q2877432,wd:Q2877444,
wd:Q2396644,wd:Q3444776,wd:Q2877428,wd:Q578757,wd:Q2877445,wd:Q2333617
) )
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
}
}
As #AKSW has pointed out, you could use VALUES. Your first query will be ~150 times faster:
SELECT ?item ?itemLabel ?of ?ofLabel
WHERE
{ VALUES (?item) {
(wd:Q28114532) (wd:Q27745011) (wd:Q3415363) (wd:Q3415324) (wd:Q2877432) (wd:Q2877444)
(wd:Q2396644) (wd:Q3444776) (wd:Q2877428) (wd:Q578757) (wd:Q2877445) (wd:Q2333617)
}
?item wdt:P31 ?of.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
}
}
Try it!
In your second query, you should also add hint:Prior hint:gearing "forward":
SELECT ?item ?itemLabel ?x ?xLabel
WHERE
{
VALUES (?item) {
(wd:Q28114532) (wd:Q27745011) (wd:Q3415363) (wd:Q3415324) (wd:Q2877432) (wd:Q2877444)
(wd:Q2396644) (wd:Q3444776) (wd:Q2877428) (wd:Q578757) (wd:Q2877445) (wd:Q2333617)
}
?item wdt:P31 ?x .
?x (wdt:P31|wdt:P279)* wd:Q7860962 .
hint:Prior hint:gearing "forward" .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
}
}
Try it!
Related
In my triple store i've a collection of schema:CreativeWork which has the property schema:version and schema:dateCreated.
Now i want to get all schema:CreativeWork but only the newest ones.
My sample:
PREFIX schema: <https://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
SELECT DISTINCT *
WHERE {
?subject rdf:type schema:CreativeWork .
?subject schema:identifier ?identifier .
?subject schema:version ?version .
?subject schema:dateCreated ?dateCreated .
OPTIONAL {?subject schema:about/schema:name ?name .}
FILTER( ?identifier = "46d8b7abfec44865a567ea04e385661b" ) .
} LIMIT 10
How do i manage to query only the latest version?
executable sample: https://api.triplydb.com/s/rLq4V-JgS
Note: FILTER( ?identifier = "46d8b7abfec44865a567ea04e385661b" ) . is just to make it easier.
The query of UninformedUser is working well:
PREFIX schema: <https://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
SELECT DISTINCT *
{
{
SELECT ?identifier (max(?dateCreated) as ?latestDate)
WHERE {
?subject rdf:type schema:CreativeWork .
?subject schema:identifier ?identifier .
?subject schema:dateCreated ?dateCreated .
} group by ?identifier
}
?subject schema:identifier ?identifier .
?subject schema:version ?version .
?subject schema:dateCreated ?latestDate .
OPTIONAL {?subject schema:about/schema:name ?name . }
} LIMIT 100
Trying to populate a combo box with mapped drive letters (name) and FQDN (Root). I think I have most of the code but the combo box entries includes coded entries.
I'm not only curious about how to fix this but why the results are entered this way. Running this via command line does not display results this way.
NOTE: I'm also using a function to populate the combo box.
Code to retrieve mapped drives
Load-ComboBox -ComboBox $cboDomain -Items (Get-PSDrive -PSProvider FileSystem | Select-Object name, #{ n = "Root"; e = { if ($_.DisplayRoot -eq $null) { $_.Root } else { $_.DisplayRoot } } })
Function to load combo box
function Load-ComboBox{
Param (
[ValidateNotNull()]
[Parameter(Mandatory=$true)]
[System.Windows.Forms.ComboBox]$ComboBox,
[ValidateNotNull()]
[Parameter(Mandatory=$true)]
$Items,
[Parameter(Mandatory=$false)]
[string]$DisplayMember,
[switch]$Append
)
if(-not $Append)
{
$ComboBox.Items.Clear()
}
if($Items -is [Object[]])
{
$ComboBox.Items.AddRange($Items)
}
elseif ($Items -is [System.Collections.IEnumerable])
{
$ComboBox.BeginUpdate()
foreach($obj in $Items)
{
$ComboBox.Items.Add($obj)
}
$ComboBox.EndUpdate()
}
else
{
$ComboBox.Items.Add($Items)
}
$ComboBox.DisplayMember = $DisplayMember}
The entries look like;
#{Name=C; Root=C:}
#Name=S; Root=\\server\share}
I want it to look like;
C<-tab->C:\
S<-tab->\\server\share
*Sorry couldn't figure out how to actually insert tab
Since you are sending Objects to the function (Select-Object returns objects), and not an array of tab separated strings, the function would work if you call it like this:
$drives = (Get-PSDrive -PSProvider FileSystem | ForEach-Object {
$root = if ($_.DisplayRoot -eq $null) { $_.Root } else { $_.DisplayRoot }
# output a tab-separated string that gets collected in the $drives variable
"$($_.Name)`t$root"
})
Load-ComboBox -ComboBox $cboDomain -Items $drives
Hope that explains
I would like to query the db to retrieve all events that do not have a comment created after the start date. Following structure for EVENT and COMMENT
EVENT
id
start
created_at
updated_at
COMMENT
id
comment
event_id
created_at
updated_at
Create a query ( $query = Event::query()->with('comments'); ) which gives me the following construct.
[{
"id": 1,
"start": "2018-06-18 12:00:00",
"created_at": "2018-06-18 11:50:07",
"updated_at": "2018-07-02 12:13:15",
"comments": [
{
"id": 1,
"created_at": "2018-06-18 12:44:35",
"updated_at": "2018-06-18 12:44:35",
"comment": "cascsac"
}
]
}]
I want to retrieve all entries where comment.created_at is after the start date of the event. I tried with the following:
$query->orWhere(function ($query) {
$value = $query->where(function ($query) use ('start') {
$query->whereHas('comments', function ($query) use ('start') {
$query->where('created_at','<=','start');
//->whereColumn('created_at', '<=', 'start');
});
});
});
But its does not like my attempts to pass start to a nested query and am not sure how to pass it for whereColumn query.
How do I pass values from columns to a nested where.
Or how else do I query a with the value of a separate column.
Edit1
On request the whole query
$query
Event::query()->with('comments');
$query->orWhere(function ($query) {
$value = $query->where(function ($query) use ('start') {
$query->whereHas('comments', function ($query) use ('start') {
$query->where('created_at','>=','start');
//->whereColumn('created_at', '>=', 'start');
});
});
});
$events = $query->get();
Passing variable $start would work too but I cannot convert column value of start to variable $start to pass the nested query
Answered on https://laracasts.com/discuss/channels/eloquent/querybuilder-pass-column-to-nested-query
$events = Event::with('comments')->whereHas('comments',function ($query) {
$query->whereColumn('comments.created_at','<','events.start');
})->get();
whereColumn is function to compare columns in query.
Wrong code is 'start'> It must be $start
$start = Carbon::now()->subYears(100); // for examplee
$query->orWhere(function ($query) {
$value = $query->where(function ($query) use ($start) {
$query->whereHas('comments', function ($query) use ($start) {
$query->where('created_at','<=', $start);
//->whereColumn('created_at', '<=', $start);
});
});
})
I have my own dataset and I want to perform a federated query in SPARQL. Here is the query:
PREFIX : <http://myURIsNamespace#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
select * where {
?bioentity :hasMutatedVersionOf ?gene .
?gene :partOf wd:Q430258 .
SERVICE <https://query.wikidata.org/sparql> {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>21000000 && xsd:integer(?start)<30000000)
}
}
I run the query via graphDB SPARQL interface but it's really really slow. It takes more than a minute to return 8 records. If I split the query in two parts, they are ridiculously fast.
Query#1
select * where {
?bioentity :hasMutatedVersionOf ?gene .
?gene :partOf wd:Q430258 .
}
56 records in 0.1s
Query#2
select * where {
SERVICE <https://query.wikidata.org/sparql> {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>21000000 && xsd:integer(?start)<30000000)
}
}
158 records in 0.5s
Why the is the federation so slow? Is there a way to optimize the performance?
Short answer
Just place your SERVICE part first, i. e. before ?bioentity :hasMutatedVersionOf ?gene .
Read a good article on the topic (e. g. chapter 5 of this book)
Relevant quote from the aforementioned article:
3.3.2 Query Optimization and Execution
The execution order of query operators significantly influences the overall query evaluation cost.
Besides the important query execution time there are also other
aspects in the federated scenario which are relevant for the query
optimization:
Minimizing communication cost. The number of contacted
data sources directly influences the performance of the query
execution due to the communication overhead. However, reducing the
number of involved data source trades off against completeness of
results.
Optimizing execution localization. The standard query
interfaces of linked data sources are generally only capable of
answering queries on their provided data. Therefore, joins with
other data results usually need to be done at the query issuer. If
possible at all, a better strategy will move parts of the result
merging operations to the data sources, especially if they can be
executed in parallel.
Streaming results. Retrieving a complete result
when evaluating a query on a large dataset may take a while even with
a well optimized execution strategy. Thus one can return results as
soon as they become available, which can be optimized by trying to
return relevant results first.
Long answer
Example data
PREFIX : <http://myURIsNamespace#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
INSERT { ?gene rdf:type owl:Thing }
WHERE {
SERVICE <https://query.wikidata.org/sparql> {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>26000000 && xsd:integer(?start)<30000000)
}
}
The total number of triples is 79. Please note that 26000000 is used instead of 21000000.
Query 1
PREFIX : <http://myURIsNamespace#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
SELECT * WHERE {
?gene rdf:type owl:Thing .
SERVICE <https://query.wikidata.org/sparql> {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>20000000 && xsd:integer(?start)<30000000)
}
}
Query 2
PREFIX : <http://myURIsNamespace#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
SELECT * WHERE {
SERVICE <https://query.wikidata.org/sparql> {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>20000000 && xsd:integer(?start)<30000000)
}
?gene rdf:type owl:Thing
}
Performance
Query 1
Query 2
GraphDB
30 sec
1 sec
Blazegraph
1 sec
1 sec
GraphDB behaviour
Executing Query 1, GraphDB performs 79 distinct GET requests to Wikidata¹:
These requests are queries of this kind:
SELECT ?start ?statement ?end ?statement2 WHERE {
<http://www.wikidata.org/entity/Q18031286> p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
<http://www.wikidata.org/entity/Q18031286> p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>20000000 && xsd:integer(?start)<30000000)
It seems interesting, that on another machine, GraphDB performs GET requests of another kind:
GET /sparql?queryLn="Sparql"&query=<original_query_service_part>&$gene=<http://www.wikidata.org/entity/Q18031286>
In this request, Sesame protocol is used, these bindings in URL are not a part of SPARQL 1.1 Protocol.
Perhaps the exact kind of a request depends on the value of the internal reuse.vars.in.subselects parameter, which default value is presumably different on Windows and on Linux.
Blazegraph behaviour
Executing Query 1, Blazegraph performs single POST request to Wikidata²:
SELECT ?gene ?statement ?start ?statement2 ?end
WHERE {
?gene p:P644 ?statement;
wdt:P31 wd:Q7187 ;
wdt:P703 wd:Q15978631 ;
wdt:P1057 wd:Q430258 .
?statement ps:P644 ?start .
?statement pq:P659 wd:Q20966585 .
?gene p:P645 ?statement2.
?statement2 ps:P645 ?end .
?statement2 pq:P659 wd:Q20966585 .
FILTER (xsd:integer(?start)>20000000 && xsd:integer(?start)<30000000)
}
VALUES ( ?gene) {
( wd:Q14908148 ) ( wd:Q15320063 ) ( wd:Q17861651 ) ( wd:Q17917753 ) ( wd:Q17928333 )
( wd:Q18024923 ) ( wd:Q18026347 ) ( wd:Q18030710 ) ( wd:Q18031220 ) ( wd:Q18031457 )
( wd:Q18031551 ) ( wd:Q18031832 ) ( wd:Q18032918 ) ( wd:Q18033094 ) ( wd:Q18033798 )
( wd:Q18034311 ) ( wd:Q18035006 ) ( wd:Q18035085 ) ( wd:Q18035609 ) ( wd:Q18036516 )
( wd:Q18036676 ) ( wd:Q18037580 ) ( wd:Q18038385 ) ( wd:Q18038459 ) ( wd:Q18038737 )
( wd:Q18038763 ) ( wd:Q18039997 ) ( wd:Q18040291 ) ( wd:Q18041261 ) ( wd:Q18041415 )
( wd:Q18041558 ) ( wd:Q18045881 ) ( wd:Q18047232 ) ( wd:Q18047373 ) ( wd:Q18047918 )
( wd:Q18047966 ) ( wd:Q18048744 ) ( wd:Q18049145 ) ( wd:Q18049164 ) ( wd:Q18053139 )
( wd:Q18056540 ) ( wd:Q18057411 ) ( wd:Q18060804 ) ( wd:Q18060856 ) ( wd:Q18060876 )
( wd:Q18060905 ) ( wd:Q18060958 ) ( wd:Q20773708 ) ( wd:Q15312971 ) ( wd:Q17860819 )
( wd:Q17917713 ) ( wd:Q18026310 ) ( wd:Q18027015 ) ( wd:Q18031286 ) ( wd:Q18032599 )
( wd:Q18032797 ) ( wd:Q18035169 ) ( wd:Q18035627 ) ( wd:Q18039938 ) ( wd:Q18041207 )
( wd:Q18041512 ) ( wd:Q18041930 ) ( wd:Q18045491 ) ( wd:Q18045762 ) ( wd:Q18046301 )
( wd:Q18046472 ) ( wd:Q18046487 ) ( wd:Q18047149 ) ( wd:Q18047491 ) ( wd:Q18047719 )
( wd:Q18048527 ) ( wd:Q18049774 ) ( wd:Q18051886 ) ( wd:Q18053875 ) ( wd:Q18056212 )
( wd:Q18056538 ) ( wd:Q18065866 ) ( wd:Q20766978 ) ( wd:Q20781543 )
}
Conclusion
With federated queries, it is hard to create effective execution plan, since selectivity of remote patterns is unknown.
In your particular case, it should be not very important, whether to join results locally or remotely, because both local and remote resultsets are small. However, in GraphDB, joining results remotely is less effective, because GraphDB does not reduce communication costs.
¹ For screenshots creation, <http://query.wikidata.org/sparql> instead of <https://query.wikidata.org/sparql> was used.
² In Blazegraph, one might write hint:Query hint:optimizer "None" to ensure sequential evaluation.
I would like to get the list of actors in Wikidata and also the number of awards received by each of them. Which query do I have to write ?
I tried this but it doesn't seem to work because I have only a few results :
SELECT ?actor ?actorLabel ?awardsNumber WHERE {
{
SELECT ?actor (COUNT(DISTINCT ?awardsNumber) AS ?awardsNumber)
WHERE {
?actor wdt:P106 wd:Q33999 .
?awardsNumber wdt:P166 ?actor .
}
GROUP BY ?actor
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
ORDER BY DESC (?awardsNumber)
Thank you in advance for your help !
Not sure why you used the property P166 ("award received") as incoming property. Of course the query must be
SELECT ?actor ?actorLabel ?awardsNumber WHERE {
{
SELECT ?actor (COUNT(DISTINCT ?award) AS ?awardsNumber)
WHERE {
?actor wdt:P106 wd:Q33999 .
?actor wdt:P166 ?award.
}
GROUP BY ?actor
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
ORDER BY DESC (?awardsNumber)