Check if file exist and check the first line in the file - batch-file

Question

I have an batch file called cmd.dll. I want to check in my second batch file, if cmd.dll exist. The cmd.dll file is an "security" file.
For example:
# cmd.dll # REM SECURITY! completeLOGIN[198293]
second.bat # // CONVERTED TO .exe
#ECHO OFF GOTO :ifExist
:ifExist
if EXIST "C:\Users\%computername%\AppData\Roaming\cmd.dll" GOTO
:nextCode if NOT EXIST
"C:\Users\%computername%\AppData\Roaming\cmd.dll" GOTO :NOT
:NOT EXIST

Answer 1

This file verification could be done for example with following batch file:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "SecurityFile=%APPDATA%\cmd.dll"
if exist "%SecurityFile%" if not exist "%SecurityFile%\" goto ValidateFile
echo File "%SecurityFile%" does not exist.
rem Insert here more code to handle this use case of not existing file.
goto EndBatch
:ValidateFile
(for /F usebackq^ delims^=^ eol^= %%I in ("%SecurityFile%") do (
if "%%I" == "# cmd.dll # REM SECURITY! completeLOGIN[198293]" goto FileValid
goto FileInvalid
)) 2>nul
:FileInvalid
echo File "%SecurityFile%" exists,
echo but first non-empty line is not as expected.
rem Insert here more code to handle this use case of invalid content.
goto EndBatch
:FileValid
echo File "%SecurityFile%" exists
echo and contains the expected line as first non-empty line.
:EndBatch
echo/
endlocal
pause
The batch file first enables command extensions and disables delayed environment variable expansion as required for this task. This environment is the default on Windows, but batch file execution security comes first.
Next an environment variable is defined with full qualified name of the file to validate.
The first IF conditions checks if there is a file (or folder) with defined name and extension in defined directory and the second IF condition if found directory entry is really a file and not a folder.
A FOR loop is executed to read the first non-empty line from existing file. The command FOR fails and outputs an error message redirected with 2>nul to device NUL to suppress it if opening of the defined file for reading its content fails resulting in a fall through to code below label FileInvalid.
The command FOR on having success opening the text file with read access would read one line after the other, would skip empty lines and lines starting with a semicolon, would split up each line into substrings (tokens) using normal space and horizontal tab as delimiters and would assign for each line first space/tab separated string to specified loop variable I. This default behavior is not wanted here. For that reason an empty list of delimiters and no end of line character are defined in a not double quoted argument string requiring escaping equal sign and space with caret character ^ to be interpreted as literal characters and not as argument separators to get any non-empty line assigned as is to specified loop variable I.
A case-sensitive string comparison is used to validate the first non-empty line in defined file with specified string. On equal strings the file is valid and batch execution continues on line below label FileValid. Otherwise the FOR loop is exited with a jump to line below label FileInvalid because of the remaining lines in defined file are of no interest.
The batch file restores initial environment after showing an appropriate message for all three use cases and outputting an empty line.
Finally the execution of the batch file is halted to give the user the possibility to read the message.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
echo /?
endlocal /?
for /?
goto /?
if /?
pause /?
rem /?
setlocal /?