Batch copy and reopen itself on new location - batch-file

Question

My batch script can not be run from network source, that's why it's gonna make a copy of itself to the desktop and starts the new copy, on finish it's deleting the copy.
:: Check location
if "%~dp0" == "%userprofile%\Desktop\" goto:eof
xcopy /I /Y "%~dpnx0" "%userprofile%\Desktop\" >nul 2>&1
start "new window" cmd /c %userprofile%\Desktop\batchname.bat
exit
That works fine, my issue is, %cd% or %0 is not updated and is still acting like the original script. Shows the location of the original script.
How can I check the location, make a self-copy to the desktop and start it, like it was double-clicked within windows? Because the script only fails, if it's started through the original script of the share.
What happens:
Starting script XYZ.bat from network share
Script notices not being located on desktop
Script does self-copy to desktop
Script runs copy from desktop
Script ends
Copy launched from original script
Script located on desktop >> fine
Script reads infos of script header:
for /F "tokens=3-8 delims= " %%a in ('findstr /B /C:":: Drive:" "%~dpnx0"') do (
Script fails because %~dpnx0 contains path of original script which is unavailable because all network shares are removed at this point
Any suggestions?
PS: I'm new here, I hope my English is understandable. Cheers
EDIT:
Thanks for the help, the thing with the path is fixed now and the script works fine, as long as I don't turn on the "remove all existing drives" function. If I do so the following happens:
Previous steps taken:
Script checks location and copy itself to the users desktop and starts from there, also all drives are removed, than it fails on the findstr thingy with the error:
[Drive-Mapper:] All map drives removed
[Drive-Mapper:] Mapping drives now:
Das aktuelle Verzeichnis ist ungültig. The current
folder does not exist
[Drive-Mapper:] Successfully finished << I wish..
Drücken Sie eine beliebige Taste . . . Press any key to continue
The Mapping function:
:mapdrives
%say% Mapping drives now:
set errorcount=0
for /F "tokens=3-8 delims= " %%a in ('findstr /B /L /C:":: Drive:" "%~f0"') do (
REM echo Server=%%a User=%%b Letter=%%c drive=%%d nick=%%e
REM if "%%b" == "all" OR if "%%b" == "%username%" (
if "%%b" == "all" (
>nul 2>&1 net use %%c: \\%%a\%%d /persistent:yes
if errorlevel 1 (%say2% Failed %%c: \\%%a\%%d & set /a errorcount=errorcount+1) else (
if "%%e" == "" (
:: Rename without nick
>nul 2>&1 reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%%a#%%d /v _LabelFromReg /d "%%d (%%a)" /f
%say2% Successfully %%c: \\%%a\%%d
) else (
:: Rename with nick
>nul 2>&1 reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%%a#%%d /v _LabelFromReg /d "%%e (%%a)" /f
%say2% Successfully %%c: \\%%a\%%d # %%e
)
)
)
if "%%b" == "%username%" (
>nul 2>&1 net use %%c: \\%%a\%%d /persistent:yes
if errorlevel 1 (%say2% Failed %%c: \\%%a\%%d & set /a errorcount=errorcount+1) else (
if "%%e" == "" (
:: Rename without nick
>nul 2>&1 reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%%a#%%d /v _LabelFromReg /d "%%d (%%a)" /f
%say2% Successfully %%c: \\%%a\%%d
) else (
:: Rename with nick
>nul 2>&1 reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%%a#%%d /v _LabelFromReg /d "%%e (%%a)" /f
%say2% Successfully %%c: \\%%a\%%d # %%e
)
)
)
%sf_wait2%
)
%sf_wait%
if "%errorcount%" == "0" (%say% Successfully finished) else (%say% Warning %errorcount% Errors!!)
%say2% & pause
goto:eof
Script crabs infos from batch header:
:: - Force - Deleting drives (0=No,1=Yes)
set force_del_drives=1
:: - Force - Kill Explorer (0=No,1=Yes)
set force_kill_explorer=1
::----------------------------------------------------------------------------------------
:: HINT SERVER USER LETER DRIVE NICKNAME (IF NOT USING DRIVENAME)
:: Drive: server all H Home My Home
:: Drive: server all V Drive1
:: Drive: server all M Drive2
::----------------------------------------------------------------------------------------
:: -Drive: server user I DisabledDrive
:: Drive: server user K Drive4
:: Drive: server user Z Homes All Homes
PS: If I run the script from c:\ it will copy itself to desktop and runs perfectly, it also works like I said, if I dont remove the network drive the script originaly was executed from.
Any ideas?

Answer 1

#echo off
setlocal
:: Check location
if not exist "%userprofile%\Desktop\" (
>&2 echo Desktop folder not exist
exit /b 1
)
if "%~dp0" == "%userprofile%\Desktop\" goto :main
xcopy /I /Y "%~f0" "%userprofile%\Desktop\" >nul 2>&1
start "new window" "cmd /c "%userprofile%\Desktop\%~nx0""
goto :eof
:main
echo %~f0
pause
goto :eof
Added check for Desktop folder as it is a Shell Folder and may
not exist in that location.
Logic changed to go to :main label if location is Desktop folder.
Command of start modified to handle the script name and extension
without hard coding a name and extension.